on *:LOAD:kagSetPath

alias -l kagrx { return /(?:kag:\/\/)([0-9a-zA-Z\.\:]+):([0-9]+)\/([0-9a-zA-Z])/ }
on $^*:HOTLINK:$($kagrx):*:{ return }
on $*:HOTLINK:$($kagrx):*:{
  if (!$isfile(%kag_executable)) { kagSetPath }
  if ($isfile(%kag_executable)) {
    %kag_address = $regml(1)
    %kag_port = $regml(2)
    %kag_password = $regml(3)
    run $+(", %kag_executable, ") -join $+(kag://, %kag_address, :, %kag_port, /, %kag_password)
  }
}

alias -l kagSetPath {
  var %path, %dir, %full_path
  if ($isdir($nofile(%kag_executable))) { %dir = $nofile(%kag_executable) }
  else { %dir = $mircdir }
  %path = $sdir(%dir, Path to kag Directory)
  if ($isdir(%path)) {
    %full_path = %path $+ kag.exe
    if (!$isfile(%full_path)) {
      if ($?!="File %full_path does not exist. $crlf $+ If your kag executable is named differently, choose 'Yes' to select the file manually.") {
        %full_path = $sfile(%path, kag Executable)
        if ($isfile(%full_path)) { set %kag_executable %full_path }
      }
    }
    else { set %kag_executable %full_path }
  }
}