Lottosystem by ErikSon

//Incldues
#include <a_samp>
#include <dini>
#include <ocmd>

//Farben
#define Rot     0xFF0000FF
#define Blau    0x0091FFFF
#define DBlau   0x0023FFFF

//Sonstiges
forward Lottotimer();
#define lottostart      30              // In wie vielen Minuten Lotto immer starten soll
#define PLAYERS         5               // Slots des Servers
#define Lottotk         50              // Kosten eines Lottotickets
#define lstartgeld      5000            // Wieviel Geld am Anfang in der Lottokasse ist
#define lpgeld          5000            // Wieviel Geld zu dem Jackpot dazu gegeben werden soll, wenn keiner das Lottospiel gewinnt
#define max_lzahl       50              // Maximale Lottozahl die genommen werden kann
new LottoZahl[PLAYERS],
    PlayerText:lTD[PLAYERS];

enum EL{
    lJackpot,
    lTeilnehmer,
    lZeit,
    Text:lBox
}
static Lotto[EL];

ocmd:geld(playerid)return GivePlayerMoney(playerid,5000);

////////////////////////////////////////////////////////////////////////

public OnFilterScriptInit(){
    print("\n--------------------------------------");
    print(" Lottosystem by ErikSon");
    print("--------------------------------------\n");
    SetTimer("Lottotimer",1000,true);
    new Lottodatei[16]; format(Lottodatei,16,"/Lotto.ini");
    if(dini_Exists(Lottodatei))Lotto[lJackpot] = dini_Int(Lottodatei,"Gewinn");
    else if(!dini_Exists(Lottodatei)){
        dini_Create(Lottodatei);
        dini_IntSet(Lottodatei,"Gewinn",lstartgeld);
        Lotto[lJackpot] = lstartgeld;
    }
    Lotto[lBox] = TextDrawCreate(370.000000, 10.000000, "~n~");
    TextDrawBackgroundColor(Lotto[lBox], 255);
    TextDrawFont(Lotto[lBox], 1);
    TextDrawLetterSize(Lotto[lBox], 0.500000, 6.499999);
    TextDrawColor(Lotto[lBox], 35071);
    TextDrawSetOutline(Lotto[lBox], 0);
    TextDrawSetProportional(Lotto[lBox], 1);
    TextDrawSetShadow(Lotto[lBox], 1);
    TextDrawUseBox(Lotto[lBox], 1);
    TextDrawBoxColor(Lotto[lBox], 255);
    TextDrawTextSize(Lotto[lBox], 486.000000, 0.000000);
    TextDrawSetSelectable(Lotto[lBox], 0);

    new str[128];
    for(new i = 0; i<PLAYERS; i++){
        format(str,sizeof(str),"Lotto!~n~Start: %i m / %i s~n~Jackpot: %i$~n~Teilnehmer: %i~n~Deine Lottozahl: %i",(lottostart - (Lotto[lZeit] / 60) -1),(lottostart - (Lotto[lZeit] % 60) +30),
        Lotto[lJackpot],Lotto[lTeilnehmer],LottoZahl[i]);
        lTD[i] = CreatePlayerTextDraw(i,374.000000, 14.000000, str);
        PlayerTextDrawBackgroundColor(i,lTD[i], 255);
        PlayerTextDrawFont(i,lTD[i], 1);
        PlayerTextDrawLetterSize(i,lTD[i], 0.300000, 1.000000);
        PlayerTextDrawColor(i,lTD[i], -1);
        PlayerTextDrawSetOutline(i,lTD[i],0);
        PlayerTextDrawSetProportional(i,lTD[i], 1);
        PlayerTextDrawSetShadow(i,lTD[i], 1);
        PlayerTextDrawSetSelectable(i,lTD[i], 0);
        if(IsPlayerConnected(i)){
            LottoZahl[i] = GetPVarInt(i,"LottoZahl");
            if(LottoZahl[i] > 0)Lotto[lTeilnehmer] ++;
            TextDrawShowForPlayer(i,Lotto[lBox]),
            PlayerTextDrawShow(i,lTD[i]);
        }
    }
    return 1;
}
public OnFilterScriptExit(){
    new Lottodatei[16]; format(Lottodatei,16,"/Lotto.ini");
    dini_IntSet(Lottodatei,"Gewinn",Lotto[lJackpot]);

    for(new i = 0; i<PLAYERS; i++){
        SetPVarInt(i,"LottoZahl",LottoZahl[i]);
        TextDrawHideForPlayer(i,Lotto[lBox]),
        PlayerTextDrawHide(i,lTD[i]);
    }
    return 1;
}

public OnPlayerConnect(playerid){
    LottoZahl[playerid] = GetPVarInt(playerid,"LottoZahl");
    TextDrawShowForPlayer(playerid,Lotto[lBox]),
    PlayerTextDrawShow(playerid,lTD[playerid]);
    if(LottoZahl[playerid] > 0)Lotto[lTeilnehmer] ++;
    return 1;
}
public OnPlayerDisconnect(playerid, reason){
    SetPVarInt(playerid,"LottoZahl",LottoZahl[playerid]);
    if(LottoZahl[playerid] > 0)Lotto[lTeilnehmer] --;
    PlayerTextDrawHide(playerid,lTD[playerid]),
    TextDrawHideForPlayer(playerid,Lotto[lBox]);
    return 1;
}

stock Name(playerid){
   new name[MAX_PLAYER_NAME];
   GetPlayerName(playerid,name,sizeof(name));
   return name;
}

public Lottotimer(){
    Lotto[lZeit] ++;
    if((Lotto[lZeit] / 60) >= lottostart){
        new lzahl = random(max_lzahl) +1, bool:won, string[128];
        for(new i = 0; i<PLAYERS; i++){
            if(!IsPlayerConnected(i))continue;
            if(LottoZahl[i] < 1)continue;
            if(LottoZahl[i] == lzahl){
                won = true;
                format(string,128,"Spieler %s hat das Lottospiel gewonnen und $%d gewonnen! (Lottozahl: %d)",Name(i),Lotto[lJackpot],lzahl);
                SendClientMessageToAll(Blau,string);
                GivePlayerMoney(i,Lotto[lJackpot]);
            }
            LottoZahl[i] = 0;
        }
        if(!won){
            format(string,128,"Diesmal hat niemand das Lottospiel gewonnen. (Lottozahl: %d)",lzahl);
            SendClientMessageToAll(Rot,string);
            Lotto[lJackpot] += lpgeld;
            format(string,128,"Der Jackpot steigt auf $%d.",Lotto[lJackpot]);
            SendClientMessageToAll(-1,string);
        }
        else if(won){
            Lotto[lJackpot] = lstartgeld;
            format(string,128,"Der Jackpot steht nun auf $%d.",lstartgeld);
            SendClientMessageToAll(-1,string);
        }
        Lotto[lZeit] = 0;
        Lotto[lTeilnehmer] = 0;
    }
    new str[128];
    for(new i = 0; i<PLAYERS; i++){
        if(!IsPlayerConnected(i))continue;
        format(str,sizeof(str),"Lotto!~n~Start: %i m / %i s~n~Jackpot: %i$~n~Teilnehmer: %i~n~Deine Lottozahl: %i",(lottostart - (Lotto[lZeit] / 60) -1),(lottostart - (Lotto[lZeit] % 60) +30),
        Lotto[lJackpot],Lotto[lTeilnehmer],LottoZahl[i]);
        PlayerTextDrawSetString(i,lTD[i],str);
    }
    return 1;
}

ocmd:lotto(playerid,params[]){
    new lz,string[128];
    if(LottoZahl[playerid] > 0)return SendClientMessage(playerid,Rot,"*Du hast bereits ein Lottoticket gekauft!");
    if(GetPlayerMoney(playerid) < Lottotk)return format(string,64,"*Du hast nicht genug Geld! ($%d)",Lottotk),SendClientMessage(playerid,Rot,string);
    if(sscanf(params,"d",lz))return format(string,64,"*Benutze: /lotto [Zahl (1-%d)",max_lzahl),SendClientMessage(playerid,Rot,string);
    if(lz > max_lzahl || lz < 1)return format(string,64,"*Die Lottozahl muss mindestens 1 und höchstens %d sein!",max_lzahl),SendClientMessage(playerid,Rot,string);
    LottoZahl[playerid] = lz;
    Lotto[lTeilnehmer] ++;
    return GivePlayerMoney(playerid,-Lottotk);
}

ocmd:startelotto(playerid){
    new string[64];
    if(!IsPlayerAdmin(playerid))return 1;
    format(string,64,"Admin %s hat eine extra Lottorunde gestartet!",Name(playerid));
    SendClientMessageToAll(Blau,string);
    return Lotto[lZeit] = (lottostart*60);
}

ocmd:make(playerid){
    return Lotto[lZeit] = 1731;
}
ocmd:makeit(playerid){
    return Lotto[lZeit] = 1790;
}

ocmd:clear(){
    for(new i = 0; i<123; i++){
        SendClientMessageToAll(-1,"");
    }
    return 1;
}


stock sscanf(string[], format[], {Float,_}:...)
{
    #if defined isnull
        if (isnull(string))
    #else
        if (string[0] == 0 || (string[0] == 1 && string[1] == 0))
    #endif
        {
            return format[0];
        }
    #pragma tabsize 4
    new
        formatPos = 0,
        stringPos = 0,
        paramPos = 2,
        paramCount = numargs(),
        delim = ' ';
    while (string[stringPos] && string[stringPos] <= ' ')
    {
        stringPos++;
    }
    while (paramPos < paramCount && string[stringPos])
    {
        switch (format[formatPos++])
        {
            case '\0':
            {
                return 0;
            }
            case 'i', 'd':
            {
                new
                    neg = 1,
                    num = 0,
                    ch = string[stringPos];
                if (ch == '-')
                {
                    neg = -1;
                    ch = string[++stringPos];
                }
                do
                {
                    stringPos++;
                    if ('0' <= ch <= '9')
                    {
                        num = (num * 10) + (ch - '0');
                    }
                    else
                    {
                        return -1;
                    }
                }
                while ((ch = string[stringPos]) > ' ' && ch != delim);
                setarg(paramPos, 0, num * neg);
            }
            case 'h', 'x':
            {
                new
                    num = 0,
                    ch = string[stringPos];
                do
                {
                    stringPos++;
                    switch (ch)
                    {
                        case 'x', 'X':
                        {
                            num = 0;
                            continue;
                        }
                        case '0' .. '9':
                        {
                            num = (num << 4) | (ch - '0');
                        }
                        case 'a' .. 'f':
                        {
                            num = (num << 4) | (ch - ('a' - 10));
                        }
                        case 'A' .. 'F':
                        {
                            num = (num << 4) | (ch - ('A' - 10));
                        }
                        default:
                        {
                            return -1;
                        }
                    }
                }
                while ((ch = string[stringPos]) > ' ' && ch != delim);
                setarg(paramPos, 0, num);
            }
            case 'c':
            {
                setarg(paramPos, 0, string[stringPos++]);
            }
            case 'f':
            {

                new changestr[16], changepos = 0, strpos = stringPos;
                while(changepos < 16 && string[strpos] && string[strpos] != delim)
                {
                    changestr[changepos++] = string[strpos++];
                    }
                changestr[changepos] = '\0';
                setarg(paramPos,0,_:floatstr(changestr));
            }
            case 'p':
            {
                delim = format[formatPos++];
                continue;
            }
            case '\'':
            {
                new
                    end = formatPos - 1,
                    ch;
                while ((ch = format[++end]) && ch != '\'') {}
                if (!ch)
                {
                    return -1;
                }
                format[end] = '\0';
                if ((ch = strfind(string, format[formatPos], false, stringPos)) == -1)
                {
                    if (format[end + 1])
                    {
                        return -1;
                    }
                    return 0;
                }
                format[end] = '\'';
                stringPos = ch + (end - formatPos);
                formatPos = end + 1;
            }
            case 'u':
            {
                new
                    end = stringPos - 1,
                    id = 0,
                    bool:num = true,
                    ch;
                while ((ch = string[++end]) && ch != delim)
                {
                    if (num)
                    {
                        if ('0' <= ch <= '9')
                        {
                            id = (id * 10) + (ch - '0');
                        }
                        else
                        {
                            num = false;
                        }
                    }
                }
                if (num && IsPlayerConnected(id))
                {
                    setarg(paramPos, 0, id);
                }
                else
                {
                    #if !defined foreach
                        #define foreach(%1,%2) for (new %2 = 0; %2 < MAX_PLAYERS; %2++) if (IsPlayerConnected(%2))
                        #define __SSCANF_FOREACH__
                    #endif
                    string[end] = '\0';
                    num = false;
                    new
                        name[MAX_PLAYER_NAME];
                    id = end - stringPos;
                    foreach (Player, playerid)
                    {
                        GetPlayerName(playerid, name, sizeof (name));
                        if (!strcmp(name, string[stringPos], true, id))
                        {
                            setarg(paramPos, 0, playerid);
                            num = true;
                            break;
                        }
                    }
                    if (!num)
                    {
                        setarg(paramPos, 0, INVALID_PLAYER_ID);
                    }
                    string[end] = ch;
                    #if defined __SSCANF_FOREACH__
                        #undef foreach
                        #undef __SSCANF_FOREACH__
                    #endif
                }
                stringPos = end;
            }
            case 's', 'z':
            {
                new
                    i = 0,
                    ch;
                if (format[formatPos])
                {
                    while ((ch = string[stringPos++]) && ch != delim)
                    {
                        setarg(paramPos, i++, ch);
                    }
                    if (!i)
                    {
                        return -1;
                    }
                }
                else
                {
                    while ((ch = string[stringPos++]))
                    {
                        setarg(paramPos, i++, ch);
                    }
                }
                stringPos--;
                setarg(paramPos, i, '\0');
            }
            default:
            {
                continue;
            }
        }
        while (string[stringPos] && string[stringPos] != delim && string[stringPos] > ' ')
        {
            stringPos++;
        }
        while (string[stringPos] && (string[stringPos] == delim || string[stringPos] <= ' '))
        {
            stringPos++;
        }
        paramPos++;
    }
    do
    {
        if ((delim = format[formatPos++]) > ' ')
        {
            if (delim == '\'')
            {
                while ((delim = format[formatPos++]) && delim != '\'') {}
            }
            else if (delim != 'z')
            {
                return delim;
            }
        }
    }
    while (delim > ' ');
    return 0;
}