nukeod.cmd

@echo off
SETLOCAL

SET x86="%SYSTEMROOT%\System32\OneDriveSetup.exe"
SET x64="%SYSTEMROOT%\SysWOW64\OneDriveSetup.exe"

echo Kill OneDrive.exe process if it's running.
echo.

tasklist /FI "IMAGENAME eq OneDrive.exe" | find /I "OneDrive.exe" >NUL
IF NOT ERRORLEVEL 1 (
  echo "OneDrive.exe" is running, killing it now..."
  echo.
  start /B /WAIT taskkill /F /IM "OneDrive.exe"
  echo.
) ELSE (
  echo "OneDrive.exe" is not running..."
  echo.
)

echo Uninstalling OneDrive if installed.
echo.

IF EXIST %x64% (
  start /B /WAIT /HIGH "" %x64% /uninstall
) ELSE IF EXIST %x86% (
  start /B /WAIT /HIGH "" %x86% /uninstall
) ELSE (
  echo Neither %x64% nor %x86% exists...
  goto END
)

echo Removing OneDrive leftovers.
echo.
IF EXIST "%USERPROFILE%\OneDrive"            rd "%USERPROFILE%\OneDrive" /Q /S
IF EXIST "%SystemDrive%\OneDriveTemp"        rd "%SystemDrive%\OneDriveTemp" /Q /S
IF EXIST "%LOCALAPPDATA%\Microsoft\OneDrive" rd "%LOCALAPPDATA%\Microsoft\OneDrive" /Q /S
IF EXIST "%PROGRAMDATA%\Microsoft OneDrive"  rd "%PROGRAMDATA%\Microsoft OneDrive" /Q /S

echo Removing OneDrive from the Explorer Side Panel.
echo.

REG QUERY "HKCR\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" >NUL 2>&1
IF NOT ERRORLEVEL 1 REG DELETE "HKCR\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f

REG QUERY "HKCR\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" >NUL 2>&1
IF NOT ERRORLEVEL 1 REG DELETE "HKCR\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f

:END
ENDLOCAL