[PMT] Hit Indicator

{$CLEO .cs}
{$NOSOURCE}
0000: NOP
0662: "PopandauL"

thread '$/*hiti'

if
    8AF7: get_samp_base_to 33@
then
    0A93: end_custom_thread
end
repeat
    wait 400
until 0AFA: is_samp_structures_available

wait 0
0BE1: raknet setup_outcoming_RPC_hook @rpcHook

wait 0
    if 0AAB:   file_exists "CLEO\HitIndicator.ini"
    then
    0AF0: 10@ = get_int_from_ini_file "cleo\HitIndicator.ini" section "Texture" key "ID"
    0AF2: 11@ = get_float_from_ini_file "cleo\HitIndicator.ini" section "Texture" key "SizeX"
    0AF2: 12@ = get_float_from_ini_file "cleo\HitIndicator.ini" section "Texture" key "SizeY"
    0AF0: 13@ = get_int_from_ini_file "cleo\HitIndicator.ini" section "Texture" key "TimeMS"
    0AF0: 30@ = get_int_from_ini_file "cleo\HitIndicator.ini" section "Toggle" key "Startup"
    0AF0: 16@ = get_int_from_ini_file "cleo\HitIndicator.ini" section "Toggle" key "Key1"
    0AF0: 17@ = get_int_from_ini_file "cleo\HitIndicator.ini" section "Toggle" key "Key2"
    else
    0A93: end_custom_thread
    end

wait 0
03F0: enable_text_draw 1
Player.Defined($PLAYER_ACTOR)

wait 0
14@ = -1
15@ = -1
0085: 32@ = 13@
0085: 33@ = 13@

wait 0
0390: load_txd_dictionary 'HitI'
038F: load_texture "arrow" as 10@

while true
wait 0
    if 8AAB:   file_exists "CLEO\HitIndicator.cs"
    then
    0A93: end_custom_thread
    end
    if and
    0AB0: 16@
    0AB0: 17@
    then
        if 30@ == 1
        then
        30@ = 0
        0AD1: show_formatted_text_highpriority "~w~HitIndicator ~r~disabled~w~." time 1200
        else
        30@ = 1
        0AD1: show_formatted_text_highpriority "~w~HitIndicator ~g~enabled~w~." time 1200
        end
    wait 250
    end
    if and
    30@ == 1
    002D: 13@ >= 32@
    8118:   actor $PLAYER_ACTOR dead
    then
        if and
        14@ >= 0
        1000 >= 14@
        then
        0AB1: call_scm_func @getCameraAngle 0 angle_to 6@
            if 0B20: samp 7@ = actor_handle_by_samp_player_id 14@
            then
            0AB1: call_scm_func @getAngleBetweenPeds 1 7@ angle_to 8@
            0063: 6@ -= 8@
            0085: 9@ = 13@
            0062: 9@ -= 32@
            0016: 9@ /= 10
            074B: draw_texture 10@ position 320.0 224.0 scale 11@ 12@ angle 6@ color_RGBA 255 255 255 9@
            end
        end
    else
    14@ = -1
    end

    if and
    30@ == 1
    002D: 13@ >= 33@
    8118:   actor $PLAYER_ACTOR dead
    then
        if and
        15@ >= 0
        1000 >= 15@
        then
        0AB1: call_scm_func @getCameraAngle 0 angle_to 6@
            if 0B20: samp 7@ = actor_handle_by_samp_player_id 15@
            then
            0AB1: call_scm_func @getAngleBetweenPeds 1 7@ angle_to 8@
            0063: 6@ -= 8@
            0085: 9@ = 13@
            0062: 9@ -= 33@
            0016: 9@ /= 10
            074B: draw_texture 10@ position 320.0 224.0 scale 11@ 12@ angle 6@ color_RGBA 255 255 255 9@
            end
        end
    else
    15@ = -1
    end
end

:getCameraAngle
//0AB1: call_scm_func @getCameraAngle 0 angle_to 6@
068D: get_camera_position_to 2@ 3@ 4@
068E: get_camera_target_point_to 5@ 6@ 7@
0063: 5@ -= 2@ // (float)
0063: 6@ -= 3@ // (float)
0604: get_Z_angle_for_point 5@ 6@ store_to 7@
0AB2: ret 1 7@

:getAngleBetweenPeds
04C4: store_coords_to 1@ 2@ 3@ from_actor 0@ with_offset 0.0 0.0 0.0
04C4: store_coords_to 4@ 5@ 6@ from_actor $PLAYER_ACTOR with_offset 0.0 0.0 0.0
0063: 1@ -= 4@
0063: 2@ -= 5@
0604: get_Z_angle_for_point 1@ 2@ store_to 6@
6@ += 180.0
0AB2: ret 1 6@


:rpcHook
0BE5: raknet 0@ = get_hook_param 0
0BE5: raknet 1@ = get_hook_param 1
if
1@ == 115
then
    3@ = BitStream.Read(0@, 1)
    4@ = BitStream.Read(0@, 2)
    5@ = BitStream.Read(0@, 4)
    if 3@ == 1
    then
        if 003B: 4@ == 14@
        then
        0085: 14@ = 4@
        32@ = 0
        else
            if 003B: 4@ == 15@
            then
            0085: 15@ = 4@
            33@ = 0
            else
                if 14@ == -1
                then
                0085: 14@ = 4@
                32@ = 0
                else
                    if 15@ == -1
                    then
                    0085: 15@ = 4@
                    33@ = 0
                    else
                        if 002D: 32@ >= 33@
                        then
                        0085: 14@ = 4@
                        32@ = 0
                        else
                        0085: 15@ = 4@
                        33@ = 0
                        end
                    end
                end
            end
        end
    end
end
0BE0: raknet hook_ret 1