qgis pkgbuild

# Maintainer: SaultDon <sault.don gmail>
# Contributor: Lantald < lantald at gmx.com
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: dibblethewrecker dibblethewrecker.at.jiwe.dot.org
# Contributor: Gerardo Exequiel Pozzi <vmlinuz386@yahoo.com.ar>
# Contributor: Eric Forgeot < http://esclinux.tk >
pkgname=qgis
pkgver=2.0.1
pkgrel=5
pkgdesc='Quantum GIS is a Geographic Information System (GIS) that supports vector, raster & database formats'
url='http://qgis.org/'
license=('GPL')
arch=('i686' 'x86_64')
# update to http://www.qgis.org/wiki/Building_QGIS_from_Source#Overview
depends=('libmysqlclient'
         'postgresql-libs'
         'sqlite3'
         'jasper'
         'curl'
         'pyqt'
         'python2'
         'python2-pyqt>=4.10.4dev'
         'python2-qscintilla'
         'python2-psycopg2'
         'giflib'
         'cfitsio'
         'qwt'
         'proj'
         'gdal'
         'geos'
         'flex'
         'bison'
         'libspatialite'
         'spatialindex')
makedepends=('cmake'
             'grass'
             'gsl'
             'postgis'
             'netcdf'
             'fcgi'
             'python2-sip>=4.15.3')
optdepends=('osgearth: OpenSceneGraph')
install=${pkgname}.install
source=("http://qgis.org/downloads/${pkgname}-${pkgver}.tar.bz2"
        "qgis.sh"
        "rev-349a4c97.diff::https://hub.qgis.org/projects/quantum-gis/repository/revisions/349a4c974fab88fdda0d612dea8defe037ec50ba/diff.diff"
        "http://hub.qgis.org/attachments/download/6230/QgsFieldValidator.diff"
        "https://github.com/geometeor/QGIS/commit/e4835fb42b914327192e87f9f8ede970d82bdc50.patch"
        "rev-99cee10c.diff::http://hub.qgis.org/projects/quantum-gis/repository/revisions/99cee10cf96314ae911a6d8b99d6a43015a3cf83/diff.diff"
        "rev-4a75a95a.diff::http://hub.qgis.org/projects/quantum-gis/repository/revisions/4a75a95a3602c9d87e6976210c819e8564c77c39/diff.diff")
md5sums=('3822c7dd70e2d893a0f1baa9c72316d2'
         '488a57456d9f3ca5965e0aed617cd8fa'
         '4d66e5546feb08157ed5794b58891b01'
         '775176bb6b9a600e9428a9a34bd88825'
         'fa3ce11866ccab36b2e73771b04e7b53'
         'dc06a0d065e74b5c373544c2435fa589'
         'b0d65d59b5c2a5ff9234cd535e76b73b')

prepare() {
        cd "$srcdir/$pkgname-$pkgver"
        patch -Np1 -i "${srcdir}/rev-349a4c97.diff"      # http://hub.qgis.org/issues/8507
        patch -Np1 -i "${srcdir}/QgsFieldValidator.diff" # http://hub.qgis.org/issues/8601
        patch -Np1 -i "${srcdir}/e4835fb42b914327192e87f9f8ede970d82bdc50.patch" # https://github.com/geometeor/QGIS/commit/master
        patch -Np1 -i "${srcdir}/rev-99cee10c.diff"  # http://hub.qgis.org/issues/9011
        patch -Np1 -i "${srcdir}/rev-4a75a95a.diff"      # http://hub.qgis.org/issues/6369
}
build() {
  # Fix insecure RPATH is weird, but just works ;)
  # echo "os.system(\"sed -i '/^LFLAGS/s|-Wl,-rpath,.\+ ||g' gui/Makefile core/Makefile\")" >> python/configure.py.in

  cd "${srcdir}"
  rm -rf build
  mkdir build
  cd build

  cmake ../${pkgname}-${pkgver} \
    -DENABLE_TESTS=OFF \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_SKIP_RPATH=ON \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DGRASS_PREFIX=/opt/grass \
    -DQGIS_MANUAL_SUBDIR=share/man \
    -DPYTHON_LIBRARY=/usr/lib/libpython2.7.so \
    -DPYTHON_EXECUTABLE=/usr/bin/python2 \
    -DPYTHON_SITE_PACKAGES_DIR=/usr/lib/python2.7/site-packages \
    -DPYTHON_INCLUDE_PATH=/usr/include/python2.7 \
    -DQT_QMAKE_EXECUTABLE=qmake4 \
    -DWITH_MAPSERVER=TRUE

  make
}

package() {
  cd build

  make DESTDIR=${pkgdir} install

  # create a more user-friendly application name link
  ln -s /usr/bin/qgis $pkgdir/usr/bin/quantum-gis

  # install some freedesktop.org compatibility
  install -D -m644 "$srcdir"/"${pkgname}-${pkgver}"/debian/qgis.desktop \
                      "$pkgdir"/usr/share/applications/qgis.desktop
  install -D -m644 "$srcdir"/"${pkgname}-${pkgver}"/debian/qbrowser.desktop \
                      "$pkgdir"/usr/share/applications/qbrowser.desktop
  install -dm755 $pkgdir/usr/share/pixmaps \
                      "$pkgdir"/usr/share/mimelnk/application
  for mime in $srcdir/${pkgname}-${pkgver}/debian/mime/application/*.desktop
    do install -m644 ${mime} \
                      "$pkgdir"/usr/share/mimelnk/application
  done
  ln -s /usr/share/qgis/images/icons/qgis-icon.png $pkgdir/usr/share/pixmaps/qgis-icon.png
  ln -s /usr/share/qgis/images/icons/qgis-mime-icon.png $pkgdir/usr/share/pixmaps/qgis-mime-icon.png

  # enable qgis for python by setting PYTHONPATH
  install -Dm644 ${srcdir}/qgis.sh \
                      "${pkgdir}"/etc/profile.d/qgis.sh
}