MA Ribbon R2

//@version=3

study(title="MA Ribbon R2 by JustUncleL", shorttitle="MA_RIBBON R2", overlay = true)

//
// Revision: R2
// Revision Author: JustUncleL
//
// Description:
//
// References:
//
// Modifications:
// R2 - Replaced variant function with more efficient version.
//    - Change bar colouring to Grab candle style.
// R1 - Original
//

// Use Alternate Anchor TF for MAs
anchor     = input(0,minval=0,maxval=1440,title="Use Alternate Anchor TimeFrame (0=none, max=1440mins)")

// Fast MA - type, length
type1   = input(defval="EMA", title="Fast MA Type: SMA, EMA, WMA, VWMA, SMMA, DEMA, TEMA, HullMA, ZEMA, TMA, SSMA ( case sensitive )", type=string)
len1    = input(defval=8, title="Fast - Length", minval=1)
// Medium MA - type, length
type2   = input(defval="EMA", title="Medium MA Type: SMA, EMA, WMA, VWMA, SMMA, DEMA, TEMA, HullMA, ZEMA, TMA, SSMA ( case sensitive )", type=string)
len2    = input(defval=21, title="Medium - Length", minval=2)
//
ma_src  = input(close,title="Source")
sBars   = input(false,title="Show Coloured Bars")
// - INPUTS END

// - FUNCTIONS

// - variant(type, src, len)
// Returns MA input selection variant, default to SMA if blank or typo.

// SuperSmoother filter
// © 2013  John F. Ehlers
variant_supersmoother(src,len) =>
    a1 = exp(-1.414*3.14159 / len)
    b1 = 2*a1*cos(1.414*3.14159 / len)
    c2 = b1
    c3 = (-a1)*a1
    c1 = 1 - c2 - c3
    v9 = 0.0
    v9 := c1*(src + nz(src[1])) / 2 + c2*nz(v9[1]) + c3*nz(v9[2])
    v9

variant_smoothed(src,len) =>
    v5 = 0.0
    v5 := na(v5[1]) ? sma(src, len) : (v5[1] * (len - 1) + src) / len
    v5

variant_zerolagema(src,len) =>
    ema1 = ema(src, len)
    ema2 = ema(ema1, len)
    v10 = ema1+(ema1-ema2)
    v10

variant_doubleema(src,len) =>
    v2 = ema(src, len)
    v6 = 2 * v2 - ema(v2, len)
    v6

variant_tripleema(src,len) =>
    v2 = ema(src, len)
    v7 = 3 * (v2 - ema(v2, len)) + ema(ema(v2, len), len)               // Triple Exponential
    v7

// return variant, defaults to SMA
variant(type, src, len) =>
    type=="EMA"     ? ema(src,len) :
      type=="WMA"   ? wma(src,len):
      type=="VWMA"  ? vwma(src,len) :
      type=="SMMA"  ? variant_smoothed(src,len) :
      type=="DEMA"  ? variant_doubleema(src,len):
      type=="TEMA"  ? variant_tripleema(src,len):
      type=="HullMA"? wma(2 * wma(src, len / 2) - wma(src, len), round(sqrt(len))) :
      type=="SSMA"  ? variant_supersmoother(src,len) :
      type=="ZEMA"  ? variant_zerolagema(src,len) :
      type=="TMA"   ? sma(sma(src,len),len) : sma(src,len)

// - /variant

// - FUNCTIONS END

// Make sure we have minimum channel spread.
Length2_    = (len2-len1)<1?len1+1:len2

// If this is 5min or less Time Frame select EMAs
mult    = not isintraday or anchor==0 or interval<=0 or interval>=anchor? 1 : round(anchor/interval)>1? round(anchor/interval) : 1
Length1 = mult==1 ? len1 : (len1*mult)
Length2 = mult==1 ? Length2_ : (Length2_*mult)


// Get the two MAs
ma1 = variant(type1,ma_src, Length1)
ma2 = variant(type2,ma_src, Length2)

//Plot the Ribbon
ma1_=plot( ma1,color=rising(ma1,2)?green:red,linewidth=2,transp=20,title="ma1")
ma2_=plot( ma2,color=rising(ma2,2)?green:red,linewidth=2,transp=20,title="ma2")
fcolor = ma1>ma2?green:red
fill(ma1_,ma2_,color=fcolor,transp=80)

//bc = not sBars? na : close>ma1 and close>ma2? green: close<ma1 and close<ma2? red : yellow
//barcolor(bc,title="Bar Colours")
// Colour bars according to the close position relative to the PAC selected.
bcol = close>=open? close>ma1 and close>ma2? lime : close<ma1 and close<ma2? red : aqua : close>ma1 and close>ma2? green : close<ma1 and close<ma2? maroon : blue
barcolor(sBars?bcol:na, title = "Bar Colours",transp=0)


//eof