[INC]iScreenFader 1.0 by InstincT

/*

        iScreenFader 1.0
        pabaigta 2012m. Birželio 12d 13:34

        Autorius: InstincT
        Keisti kreditus draudžiama! Pakeitęs kreditus autoriumi netapsi!

        funkcijos
            FadeScreenForPlayer( playerid, mode )
            playerid - žaidėjo ID
            mode - užtemdymo rėžimas. Jų yra du tipai:
                FADE_IN - užtemdyti(po truputį padaryti ekraną juodą)
                FADE_OUT - atitemdyti(po truputį padaryti ekraną matomą)

        callbackai
            OnFadeComplete( playerid, mode )
                playerid - žaidėjo ID
                mode - užtemdymo rėžimas

        changelogas
            2012m. Birželio 12d. - išleista

*/


#define FADE_IN 1
#define FADE_OUT 2

forward OnFadeComplete( playerid, mode );




enum fadeScreenEnumas
{
    fsTD_sukurtas,
    Text:fsTextDraw,
    fsTimer,
    fsSteps,
    fsMode
}

new
    fadeScreen[ MAX_PLAYERS ][ fadeScreenEnumas ]
;


stock FadeScreenForPlayer( playerid, mode )
{
    if( mode != FADE_IN && mode != FADE_OUT ) return 0;
    fadeScreen[ playerid ][ fsSteps ] = 255;
    fadeScreen[ playerid ][ fsMode ] = mode;
    fadeScreen[ playerid ][ fsTimer ] = SetTimerEx( "FadeScreen", 5, true, "d", playerid );
    return 1;
}

forward FadeScreen( playerid );
public FadeScreen( playerid )
{
    if( !fadeScreen[ playerid ][ fsTD_sukurtas ] )
    {
        fadeScreen[ playerid ][ fsTextDraw ] = TextDrawCreate( -159.000000, -288.000000, "iScreenFader by InstincT" );
        TextDrawBackgroundColor( fadeScreen[ playerid ][ fsTextDraw ], 255 );
        TextDrawFont( fadeScreen[ playerid ][ fsTextDraw ], 0 );
        TextDrawLetterSize( fadeScreen[ playerid ][ fsTextDraw ], 0.270000, 88.999687 );
        TextDrawColor( fadeScreen[ playerid ][ fsTextDraw ], -1 );
        TextDrawSetOutline( fadeScreen[ playerid ][ fsTextDraw ], 0 );
        TextDrawSetProportional( fadeScreen[ playerid ][ fsTextDraw ], 1 );
        TextDrawSetShadow( fadeScreen[ playerid ][ fsTextDraw ], 1 );
        TextDrawUseBox( fadeScreen[ playerid ][ fsTextDraw ], 1 );
        TextDrawBoxColor( fadeScreen[ playerid ][ fsTextDraw ], 255 );
        TextDrawTextSize( fadeScreen[ playerid ][ fsTextDraw ], 848.000000, 2.000000 );
        fadeScreen[ playerid ][ fsTD_sukurtas ] = true;
    }
    TextDrawBoxColor( fadeScreen[ playerid ][ fsTextDraw ], GetFadeColor( playerid, fadeScreen[ playerid ][ fsMode ] ) );
    TextDrawShowForPlayer( playerid, fadeScreen[ playerid ][ fsTextDraw ] );
    fadeScreen[ playerid ][ fsSteps ]--;
    if( fadeScreen[ playerid ][ fsSteps ] <= 0 )
    {
        KillTimer( fadeScreen[ playerid ][ fsTimer ] );
        if( fadeScreen[ playerid ][ fsMode ] == FADE_OUT )
        {
            TextDrawHideForPlayer( playerid, fadeScreen[ playerid ][ fsTextDraw ] );
        }
        CallRemoteFunction( "OnFadeComplete", "dd", playerid, fadeScreen[ playerid ][ fsMode ] );
        return 1;
    }
    return 1;
}

stock GetFadeColor( playerid, mode )
{
    if( mode == FADE_IN ) return 255 - fadeScreen[ playerid ][ fsSteps ];
    else return 255 - ( 255 - fadeScreen[ playerid ][ fsSteps ] );
}