GetVehicleColor v2.1 - Proper Hooks

/*
    SA-MP "GetVehicleColor v2.1" Include
    Copyright © 2011 RyDeR`
*/

#if defined _Included_GetVehicleColor
    #endinput
#endif

#define _Included_GetVehicleColor

#define PROPERTY_OFFSET(%0) \
    ((((%0) * ((%0) << 1)) << 2) + 65536)

stock n_AddStaticVehicle(modelID, Float: spawn_X, Float: spawn_Y, Float: spawn_Z, Float: z_Angle, color1, color2)
{
    if(color1 < 0 || color2 < 0)
    {
        color1 = random(127);
        color2 = random(127);
    }
    modelID = AddStaticVehicle(modelID, spawn_X, spawn_Y, spawn_Z, z_Angle, color1, color2);

    new
        colorStr[24]
    ;
    format(colorStr, sizeof(colorStr), "%d-%d", color1, color2);
    setproperty(_, "", PROPERTY_OFFSET(modelID), colorStr);

    return modelID;
}
#if defined _ALS_AddStaticVehicle
    #undef AddStaticVehicle
#else
    #define _ALS_AddStaticVehicle
#endif
#define AddStaticVehicle n_AddStaticVehicle

stock n_AddStaticVehicleEx(modelID, Float: spawn_X, Float: spawn_Y, Float: spawn_Z, Float: z_Angle, color1, color2, respawn_Delay)
{
    if(color1 < 0 || color2 < 0)
    {
        color1 = random(127);
        color2 = random(127);
    }
    modelID = AddStaticVehicleEx(modelID, spawn_X, spawn_Y, spawn_Z, z_Angle, color1, color2, respawn_Delay);

    new
        colorStr[24]
    ;
    format(colorStr, sizeof(colorStr), "%d-%d", color1, color2);
    setproperty(_, "", PROPERTY_OFFSET(modelID), colorStr);

    return modelID;
}
#if defined _ALS_AddStaticVehicleEx
    #undef AddStaticVehicleEx
#else
    #define _ALS_AddStaticVehicleEx
#endif
#define AddStaticVehicleEx n_AddStaticVehicleEx

stock n_CreateVehicle(modelID, Float: spawn_X, Float: spawn_Y, Float: spawn_Z, Float: z_Angle, color1, color2, respawn_Delay)
{
    if(color1 < 0 || color2 < 0)
    {
        color1 = random(127);
        color2 = random(127);
    }
    modelID = CreateVehicle(modelID, spawn_X, spawn_Y, spawn_Z, z_Angle, color1, color2, respawn_Delay);

    new
        colorStr[24]
    ;
    format(colorStr, sizeof(colorStr), "%d-%d", color1, color2);
    setproperty(_, "", PROPERTY_OFFSET(modelID), colorStr);

    return modelID;
}
#if defined _ALS_CreateVehicle
    #undef CreateVehicle
#else
    #define _ALS_CreateVehicle
#endif
#define CreateVehicle n_CreateVehicle

stock n_DestroyVehicle(vehicleID)
{
    deleteproperty(_, "", PROPERTY_OFFSET(vehicleID));

    return DestroyVehicle(vehicleID);
}
#if defined _ALS_DestroyVehicle
    #undef DestroyVehicle
#else
    #define _ALS_DestroyVehicle
#endif
#define DestroyVehicle n_DestroyVehicle

stock n_ChangeVehicleColor(vehicleID, color1, color2)
{
    new
        colorStr[24]
    ;
    format(colorStr, sizeof(colorStr), "%d-%d", color1, color2);
    setproperty(_, "", PROPERTY_OFFSET(vehicleID), colorStr);

    return ChangeVehicleColor(vehicleID, color1, color2);
}
#if defined _ALS_ChangeVehicleColor
    #undef ChangeVehicleColor
#else
    #define _ALS_ChangeVehicleColor
#endif
#define ChangeVehicleColor n_ChangeVehicleColor

public OnVehicleRespray(playerid, vehicleid, color1, color2)
{
    new
        colorStr[24]
    ;
    format(colorStr, sizeof(colorStr), "%d-%d", color1, color2);
    setproperty(_, "", PROPERTY_OFFSET(vehicleid), colorStr);

    #if defined n_OnVehicleRespray
        return n_OnVehicleRespray(playerid, vehicleid, color1, color2);
    #else
        return 0;
    #endif
}
#if defined _ALS_OnVehicleRespray
    #undef OnVehicleRespray
#else
    #define _ALS_OnVehicleRespray
#endif
#define OnVehicleRespray n_OnVehicleRespray
#if defined n_OnVehicleRespray
    forward n_OnVehicleRespray(playerid, vehicleid, color1, color2);
#endif

stock GetVehicleColor(vehicleID, &color1, &color2)
{
    vehicleID = PROPERTY_OFFSET(vehicleID);

    if(existproperty(_, "", vehicleID))
    {
        new
            colorStr[24],
            strPos
        ;
        getproperty(_, "", vehicleID, colorStr);
        strunpack(colorStr, colorStr);

        if((strPos = strfind(colorStr, "-")) != -1)
        {
            color1 = strval(colorStr);
            color2 = strval(colorStr[strPos + 1]);
            return 1;
        }
    }
    return 0;
}