trade sign macro ver 1.1

$${

    // Bind to onChat, onSendChatMessage and MIDDLEMOUSE

    STRIP(&chat,%CHAT%)
    // /trade command
    IF(%KEYNAME%="onSendChatMessage")

        IFMATCHES(%&chat%,"^/trade")

            IFMATCHES(%&chat%,"^/trade (.*) ([0-9]+) (.*)")

                MATCH(%&chat%,"^/trade (.*) ([0-9]+) (.*)",{@&price,@#amount,&itemid})
                PLACESIGN("[Trade]","%@&price%","%@#amount% %&itemid%:%@#amount%","",1)

            ELSE
             IFMATCHES(%&chat%,"^/trade (.*) ([0-9]+)")

                MATCH(%&chat%,"^/trade (.*) ([0-9]+)",{@&price,@#amount})
                SET(@#getiteminfo,1)
                ECHO(/dura)

             ELSE

                LOG(&6[&4Trade Signs&6] &aUsage: /trade <price> <amount> [item])
                LOG(&6[&4Trade Signs&6] &aIf you do not specify an item it will use &athe &aitem &ain &ayour &ahand.)
                LOG(&6[&4Trade Signs&6] &aYou must have a trade sign in your hotbar.)

             ENDIF
            ENDIF
            FILTER()
        ENDIF

    // Extract from /dura
    ELSEIF(%KEYNAME%="onChat")
        STRIP(&chat,%CHAT%)

        IF(%@#getiteminfo%=1)

            IFMATCHES(%&chat%,"^Item:(.*) - ([0-9]+):([0-9]+)")
                MATCH(%&chat%,"^Item:(.*) - ([0-9]+):([0-9]+)",{&crap,#itemid,#itemdam})
                SET(@getiteminfo,0)
                IF(%#itemdam% != 0)
                    SET(&itemid,"%#itemid%,%#itemdam%")
                ELSE
                    SET(&itemid,"%#itemid%")
                ENDIF

                PLACESIGN("[Trade]","%@&price%","%@#amount% %&itemid%:%@#amount%","",1)
            ENDIF

        ELSEIF(%@#getiteminfo%=2)

            IFMATCHES(%&chat%,"^Item:(.*) - ([0-9]+):([0-9]+)")
                MATCH(%&chat%,"^Item:(.*) - ([0-9]+):([0-9]+)",{&crap,#item,#itemdama})
                SET(@getiteminfo,0)
                &pick = ITEMNAME(%#item%)
                IF(%#itemdama%!=0)
                    PICK(%&pick%:%#itemdama%)
                ELSE
                    PICK(%&pick%)
                ENDIF
            ENDIF
        ENDIF

        // Select item in trade sign
        // May cause spam if used on signs with non numerical ids
        // Set MIDDLEMOUSE to Always override for convenience
    ELSEIF(%KEYNAME%="MIDDLEMOUSE")
        IFMATCHES(%HITID%,"(wall|standing)_sign")

            STRIP(&signtext,%SIGNTEXT[0]%)
            IF(%&signtext%="[Trade]")
             STRIP(&signtext,%SIGNTEXT[3]%)
             IFMATCHES(%&signtext%,%PLAYER%)


                STRIP(&signtext,%SIGNTEXT[2]%)
                IFMATCHES(%&signtext%,"^([0-9]+) (.*):([0-9]+)")
                    MATCH(%&signtext%,"^([0-9]+) (.*):([0-9]+)",{#uselesscrap,&tradecont})
                        IFMATCHES(%&tradecont%,"(.*),([0-9]+)")
                            MATCH(%&tradecont%,"(.*),([0-9]+)",{&item,@#itemdama})
                            SET(hasdam)
                        ELSE
                            SET(&item,%&tradecont%)
                            UNSET(hasdam)
                        ENDIF
                    IFMATCHES(%&item%,^([0-9]+)$)
                        &pick = ITEMNAME(%&item%)
                        IF(hasdam)
                            PICK(%&pick%:%@#itemdama%)
                        ELSE
                            PICK(%&pick%)
                        ENDIF
                    ELSE
                SET(@#getiteminfo,2)
                ECHO(/dura %&item%)

                    ENDIF

                ELSE
                    LOG(&6[&4Trade Signs&6] &cERROR: This trade sign can't be refilled)

                ENDIF

             ELSE
                PICK(sign)

             ENDIF

            ELSE
                PICK(sign)
            ENDIF
        ELSE
            KEY(pick)
        ENDIF
    ENDIF
}$$