API tools faq
paste
Advertisement
Guest User

Untitled

a guest
Sep 29th, 2010
226
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
text 28.11 KB | None | 0 0
raw download clone embed print report
  1. #include common_scripts\utility;
  2. #include maps\mp\_utility;
  3. #include maps\mp\gametypes\_hud_util;
  4.  
  5. /*
  6. Action SAB/SD = DD
  7. Attackers objective: Bomb both of 2 positions
  8. Defenders objective: Defend these 2 positions / Defuse planted bombs
  9. Round ends: When one team defends for duration of match, both sites are destroyed.
  10. Map ends: When one team reaches the score limit, or time limit or round limit is reached
  11. Respawning: Players respawn indefinetly and immediately
  12.  
  13. Level requirements
  14. ------------------
  15. Allied Spawnpoints:
  16. classname mp_sd_spawn_attacker
  17. Allied players spawn from these. Place at least 16 of these relatively close together.
  18.  
  19. Axis Spawnpoints:
  20. classname mp_sd_spawn_defender
  21. Axis players spawn from these. Place at least 16 of these relatively close together.
  22.  
  23. Spectator Spawnpoints:
  24. classname mp_global_intermission
  25. Spectators spawn from these and intermission is viewed from these positions.
  26. Atleast one is required, any more and they are randomly chosen between.
  27.  
  28. Bombzones:
  29. classname trigger_multiple
  30. targetname bombzone
  31. script_gameobjectname bombzone
  32. script_bombmode_original <if defined this bombzone will be used in the original bomb mode>
  33. script_bombmode_single <if defined this bombzone will be used in the single bomb mode>
  34. script_bombmode_dual <if defined this bombzone will be used in the dual bomb mode>
  35. script_team Set to allies or axis. This is used to set which team a bombzone is used by in dual bomb mode.
  36. script_label Set to A or B. This sets the letter shown on the compass in original mode.
  37. This is a volume of space in which the bomb can planted. Must contain an origin brush.
  38.  
  39. Bomb:
  40. classname trigger_lookat
  41. targetname bombtrigger
  42. script_gameobjectname bombzone
  43. This should be a 16x16 unit trigger with an origin brush placed so that it's center lies on the bottom plane of the trigger.
  44. Must be in the level somewhere. This is the trigger that is used when defusing a bomb.
  45. It gets moved to the position of the planted bomb model.
  46.  
  47. Level script requirements
  48. -------------------------
  49. Team Definitions:
  50. game["attackers"] = "allies";
  51. game["defenders"] = "axis";
  52. This sets which team is attacking and which team is defending. Attackers plant the bombs. Defenders protect the targets.
  53.  
  54. Exploder Effects:
  55. Setting script_noteworthy on a bombzone trigger to an exploder group can be used to trigger additional effects.
  56.  
  57. multiple bombs
  58. multiple targets
  59. spawning
  60. round handling when both sites are destroyed
  61.  
  62. */
  63.  
  64. /*QUAKED mp_dd_spawn_attacker_a (0.75 0.0 0.5) (-16 -16 0) (16 16 72)
  65. Axis players spawn near bomb a.*/
  66.  
  67. /*QUAKED mp_dd_spawn_attacker_b (0.75 0.0 0.5) (-16 -16 0) (16 16 72)
  68. Axis players spawn near bomb b.*/
  69.  
  70. /*QUAKED mp_dd_spawn_attacker (0.75 0.0 0.5) (-16 -16 0) (16 16 72)
  71. Axis players spawn away from enemies and near their team at one of these positions.*/
  72.  
  73. /*QUAKED mp_dd_spawn_defender (0.0 0.75 0.5) (-16 -16 0) (16 16 72)
  74. Allied players spawn away from enemies and near their team at one of these positions.*/
  75.  
  76. /*QUAKED mp_dd_spawn_defender_a (0.0 0.75 0.5) (-16 -16 0) (16 16 72)
  77. Allied players spawn near bomb site a.*/
  78.  
  79. /*QUAKED mp_dd_spawn_defender_b (0.0 0.75 0.5) (-16 -16 0) (16 16 72)
  80. Allied players spawn near bomb site b.*/
  81.  
  82. /*QUAKED mp_dd_spawn_attacker_start (0.0 1.0 0.0) (-16 -16 0) (16 16 72)
  83. Attacking players spawn randomly at one of these positions at the beginning of a round.*/
  84.  
  85. /*QUAKED mp_dd_spawn_defender_start (1.0 0.0 0.0) (-16 -16 0) (16 16 72)
  86. Defending players spawn randomly at one of these positions at the beginning of a round.*/
  87.  
  88. main()
  89. {
  90. if(getdvar("mapname") == "mp_background")
  91. return;
  92.  
  93. maps\mp\gametypes\_globallogic::init();
  94. maps\mp\gametypes\_callbacksetup::SetupCallbacks();
  95. maps\mp\gametypes\_globallogic::SetupCallbacks();
  96.  
  97. registerRoundSwitchDvar( level.gameType, 1, 0, 9 );
  98. registerTimeLimitDvar( level.gameType, 3, 0, 1440 );
  99. registerScoreLimitDvar( level.gameType, 0, 0, 500 );
  100. registerRoundLimitDvar( level.gameType, 3, 0, 12 );
  101. registerWinLimitDvar( level.gameType, 2, 0, 12 );
  102. registerNumLivesDvar( level.gameType, 0, 0, 10 );
  103. registerHalfTimeDvar( level.gameType, 0, 0, 1 );
  104.  
  105. level.objectiveBased = true;
  106. level.teamBased = true;
  107. level.onPrecacheGameType = ::onPrecacheGameType;
  108. level.onStartGameType = ::onStartGameType;
  109. level.getSpawnPoint = ::getSpawnPoint;
  110. level.onSpawnPlayer = ::onSpawnPlayer;
  111. level.onDeadEvent = ::onDeadEvent;
  112. level.onTimeLimit = ::onTimeLimit;
  113. level.onNormalDeath = ::onNormalDeath;
  114. level.initGametypeAwards = ::initGametypeAwards;
  115. level.dd = true;
  116. level.bombsPlanted = 0;
  117. level.ddBombModel = []
  118.  
  119. setBombTimerDvar();
  120.  
  121. makeDvarServerInfo( "ui_bombtimer_a", -1 );
  122. makeDvarServerInfo( "ui_bombtimer_b", -1 );
  123.  
  124. game["dialog"]["gametype"] = "demolition";
  125.  
  126. if ( getDvarInt( "g_hardcore" ) )
  127. game["dialog"]["gametype"] = "hc_" + game["dialog"]["gametype"];
  128. else if ( getDvarInt( "camera_thirdPerson" ) )
  129. game["dialog"]["gametype"] = "thirdp_" + game["dialog"]["gametype"];
  130. else if ( getDvarInt( "scr_diehard" ) )
  131. game["dialog"]["gametype"] = "dh_" + game["dialog"]["gametype"];
  132. else if (getDvarInt( "scr_" + level.gameType + "_promode" ) )
  133. game["dialog"]["gametype"] = game["dialog"]["gametype"] + "_pro";
  134.  
  135. game["dialog"]["offense_obj"] = "obj_destroy";
  136. game["dialog"]["defense_obj"] = "obj_defend";
  137. }
  138.  
  139.  
  140. onPrecacheGameType()
  141. {
  142. game["bomb_dropped_sound"] = "mp_war_objective_lost";
  143. game["bomb_recovered_sound"] = "mp_war_objective_taken";
  144.  
  145. precacheShader("waypoint_bomb");
  146. precacheShader("hud_suitcase_bomb");
  147. precacheShader("waypoint_target");
  148. precacheShader("waypoint_target_a");
  149. precacheShader("waypoint_target_b");
  150. precacheShader("waypoint_defend");
  151. precacheShader("waypoint_defend_a");
  152. precacheShader("waypoint_defend_b");
  153. precacheShader("waypoint_defuse_a");
  154. precacheShader("waypoint_defuse_b");
  155. precacheShader("waypoint_target");
  156. precacheShader("waypoint_target_a");
  157. precacheShader("waypoint_target_b");
  158. precacheShader("waypoint_defend");
  159. precacheShader("waypoint_defend_a");
  160. precacheShader("waypoint_defend_b");
  161. precacheShader("waypoint_defuse");
  162. precacheShader("waypoint_defuse_a");
  163. precacheShader("waypoint_defuse_b");
  164.  
  165. precacheString( &"MP_EXPLOSIVES_RECOVERED_BY" );
  166. precacheString( &"MP_EXPLOSIVES_DROPPED_BY" );
  167. precacheString( &"MP_EXPLOSIVES_PLANTED_BY" );
  168. precacheString( &"MP_EXPLOSIVES_DEFUSED_BY" );
  169. precacheString( &"PLATFORM_HOLD_TO_PLANT_EXPLOSIVES" );
  170. precacheString( &"PLATFORM_HOLD_TO_DEFUSE_EXPLOSIVES" );
  171. precacheString( &"MP_CANT_PLANT_WITHOUT_BOMB" );
  172. precacheString( &"MP_PLANTING_EXPLOSIVE" );
  173. precacheString( &"MP_DEFUSING_EXPLOSIVE" );
  174. precacheString( &"MP_BOMB_A_TIMER" );
  175. precacheString( &"MP_BOMB_B_TIMER" );
  176. precacheString( &"MP_BOMBSITE_IN_USE" );
  177. }
  178.  
  179. onStartGameType()
  180. {
  181. if ( !isDefined( game["switchedsides"] ) )
  182. game["switchedsides"] = false;
  183.  
  184. if ( game["switchedsides"] )
  185. {
  186. oldAttackers = game["attackers"];
  187. oldDefenders = game["defenders"];
  188. game["attackers"] = oldDefenders;
  189. game["defenders"] = oldAttackers;
  190. }
  191.  
  192. level.useStartSpawns = true;
  193.  
  194. setClientNameMode( "manual_change" );
  195.  
  196. game["strings"]["target_destroyed"] = &"MP_TARGET_DESTROYED";
  197. game["strings"]["bomb_defused"] = &"MP_BOMB_DEFUSED";
  198.  
  199. precacheString( game["strings"]["target_destroyed"] );
  200. precacheString( game["strings"]["bomb_defused"] );
  201.  
  202. level._effect["bombexplosion"] = loadfx("explosions/tanker_explosion");
  203.  
  204. setObjectiveText( game["attackers"], &"OBJECTIVES_DD_ATTACKER" );
  205. setObjectiveText( game["defenders"], &"OBJECTIVES_DD_DEFENDER" );
  206.  
  207. if ( level.splitscreen )
  208. {
  209. setObjectiveScoreText( game["attackers"], &"OBJECTIVES_DD_ATTACKER" );
  210. setObjectiveScoreText( game["defenders"], &"OBJECTIVES_DD_DEFENDER" );
  211. }
  212. else
  213. {
  214. setObjectiveScoreText( game["attackers"], &"OBJECTIVES_DD_ATTACKER_SCORE" );
  215. setObjectiveScoreText( game["defenders"], &"OBJECTIVES_DD_DEFENDER_SCORE" );
  216. }
  217. setObjectiveHintText( game["attackers"], &"OBJECTIVES_DD_ATTACKER_HINT" );
  218. setObjectiveHintText( game["defenders"], &"OBJECTIVES_DD_DEFENDER_HINT" );
  219.  
  220. level.spawnMins = ( 0, 0, 0 );
  221. level.spawnMaxs = ( 0, 0, 0 );
  222.  
  223.  
  224. maps\mp\gametypes\_spawnlogic::addSpawnPoints( game["defenders"], "mp_dd_spawn_defender" );
  225. maps\mp\gametypes\_spawnlogic::addSpawnPoints( game["defenders"], "mp_dd_spawn_defender_a", true );
  226. maps\mp\gametypes\_spawnlogic::addSpawnPoints( game["defenders"], "mp_dd_spawn_defender_b", true );
  227.  
  228. maps\mp\gametypes\_spawnlogic::placeSpawnPoints( "mp_dd_spawn_defender_start" );
  229.  
  230. maps\mp\gametypes\_spawnlogic::addSpawnPoints( game["attackers"], "mp_dd_spawn_attacker" );
  231. maps\mp\gametypes\_spawnlogic::addSpawnPoints( game["attackers"], "mp_dd_spawn_attacker_a", true );
  232. maps\mp\gametypes\_spawnlogic::addSpawnPoints( game["attackers"], "mp_dd_spawn_attacker_b", true );
  233.  
  234. maps\mp\gametypes\_spawnlogic::placeSpawnPoints( "mp_dd_spawn_attacker_start" );
  235.  
  236. level.spawn_defenders = maps\mp\gametypes\_spawnlogic::getSpawnpointArray( "mp_dd_spawn_defender" );
  237. level.spawn_defenders_a = maps\mp\gametypes\_spawnlogic::getSpawnpointArray( "mp_dd_spawn_defender_a" );
  238. level.spawn_defenders_a = array_combine( level.spawn_defenders, level.spawn_defenders_a );
  239. level.spawn_defenders_b = maps\mp\gametypes\_spawnlogic::getSpawnpointArray( "mp_dd_spawn_defender_b" );
  240. level.spawn_defenders_b = array_combine( level.spawn_defenders, level.spawn_defenders_b );
  241.  
  242. level.spawn_attackers = maps\mp\gametypes\_spawnlogic::getSpawnpointArray( "mp_dd_spawn_attacker" );
  243. level.spawn_attackers_a = maps\mp\gametypes\_spawnlogic::getSpawnpointArray( "mp_dd_spawn_attacker_a" );
  244. level.spawn_attackers_a = array_combine( level.spawn_attackers, level.spawn_attackers_a );
  245. level.spawn_attackers_b = maps\mp\gametypes\_spawnlogic::getSpawnpointArray( "mp_dd_spawn_attacker_b" );
  246. level.spawn_attackers_b = array_combine( level.spawn_attackers, level.spawn_attackers_b );
  247.  
  248. level.spawn_defenders_start = maps\mp\gametypes\_spawnlogic::getSpawnpointArray( "mp_dd_spawn_defender_start" );
  249. level.spawn_attackers_start = maps\mp\gametypes\_spawnlogic::getSpawnpointArray( "mp_dd_spawn_attacker_start" );
  250.  
  251. level.mapCenter = maps\mp\gametypes\_spawnlogic::findBoxCenter( level.spawnMins, level.spawnMaxs );
  252. level.aPlanted = false;
  253. level.bPlanted = false;
  254.  
  255. setMapCenter( level.mapCenter );
  256.  
  257. maps\mp\gametypes\_rank::registerScoreInfo( "win", 2 );
  258. maps\mp\gametypes\_rank::registerScoreInfo( "loss", 1 );
  259. maps\mp\gametypes\_rank::registerScoreInfo( "tie", 1.5 );
  260.  
  261. maps\mp\gametypes\_rank::registerScoreInfo( "kill", 50 );
  262. maps\mp\gametypes\_rank::registerScoreInfo( "headshot", 50 );
  263. maps\mp\gametypes\_rank::registerScoreInfo( "assist", 20 );
  264. maps\mp\gametypes\_rank::registerScoreInfo( "plant", 100 );
  265. maps\mp\gametypes\_rank::registerScoreInfo( "defuse", 100 );
  266.  
  267. thread updateGametypeDvars();
  268. thread waitToProcess();
  269.  
  270. winlimit = getWatchedDvar("winlimit");
  271.  
  272. allowed[0] = "dd";
  273. allowed[1] = "bombzone";
  274. allowed[2] = "blocker";
  275. maps\mp\gametypes\_gameobjects::main(allowed);
  276.  
  277. thread bombs();
  278. }
  279.  
  280. waitToProcess()
  281. {
  282. level endon( "game_end" );
  283.  
  284. for ( ;; )
  285. {
  286. if ( level.inGracePeriod == 0 )
  287. break;
  288.  
  289. wait ( 0.05 );
  290. }
  291.  
  292. level.useStartSpawns = false;
  293.  
  294. }
  295.  
  296. getSpawnPoint()
  297. {
  298. spawnteam = self.pers["team"];
  299.  
  300. if ( level.useStartSpawns )
  301. {
  302. if ( spawnteam == game["attackers"] )
  303. spawnpoint = maps\mp\gametypes\_spawnlogic::getSpawnpoint_Random(level.spawn_attackers_start);
  304. else
  305. spawnpoint = maps\mp\gametypes\_spawnlogic::getSpawnpoint_Random(level.spawn_defenders_start);
  306. }
  307. else
  308. {
  309. if (spawnteam == game["attackers"] )
  310. {
  311. if ( (!level.aPlanted && !level.bPlanted) )
  312. spawnPoints = maps\mp\gametypes\_spawnlogic::getTeamSpawnPoints( spawnteam );
  313. else if ( level.aPlanted && !level.bPlanted )
  314. spawnPoints = level.spawn_attackers_a;
  315. else if ( level.bPlanted && !level.aPlanted )
  316. spawnPoints = level.spawn_attackers_b;
  317. else
  318. spawnPoints = maps\mp\gametypes\_spawnlogic::getTeamSpawnPoints( spawnteam );
  319.  
  320. spawnpoint = maps\mp\gametypes\_spawnlogic::getSpawnpoint_NearTeam( spawnPoints );
  321. }
  322. else
  323. {
  324. if ( (!level.aPlanted && !level.bPlanted) )
  325. spawnPoints = maps\mp\gametypes\_spawnlogic::getTeamSpawnPoints( spawnteam );
  326. else if ( level.aPlanted && !level.bPlanted )
  327. spawnPoints = level.spawn_defenders_a;
  328. else if ( level.bPlanted && !level.aPlanted )
  329. spawnPoints = level.spawn_defenders_b;
  330. else
  331. spawnPoints = maps\mp\gametypes\_spawnlogic::getTeamSpawnPoints( spawnteam );
  332.  
  333. spawnpoint = maps\mp\gametypes\_spawnlogic::getSpawnpoint_NearTeam( spawnPoints );
  334. }
  335. }
  336.  
  337. assert( isDefined(spawnpoint) );
  338.  
  339. return spawnpoint;
  340. }
  341.  
  342. onSpawnPlayer()
  343. {
  344.  
  345. if ( self.pers["team"] == game["attackers"] )
  346. {
  347. self.isPlanting = false;
  348. self.isDefusing = false;
  349. self.isBombCarrier = true;
  350.  
  351. if ( level.splitscreen )
  352. {
  353. self.carryIcon = createIcon( "hud_suitcase_bomb", 33, 33 );
  354. self.carryIcon setPoint( "BOTTOM RIGHT", "BOTTOM RIGHT", 0, -78 );
  355. self.carryIcon.alpha = 0.75;
  356. }
  357. else
  358. {
  359. self.carryIcon = createIcon( "hud_suitcase_bomb", 50, 50 );
  360. self.carryIcon setPoint( "BOTTOM RIGHT", "BOTTOM RIGHT", -90, -65 );
  361. self.carryIcon.alpha = 0.75;
  362. }
  363. }
  364. else
  365. {
  366. self.isPlanting = false;
  367. self.isDefusing = false;
  368. self.isBombCarrier = false;
  369.  
  370. if ( isDefined( self.carryIcon ) )
  371. {
  372. self.carryIcon Destroy();
  373. }
  374. }
  375.  
  376. level notify ( "spawned_player" );
  377. }
  378.  
  379.  
  380. dd_endGame( winningTeam, endReasonText )
  381. {
  382. thread maps\mp\gametypes\_gamelogic::endGame( winningTeam, endReasonText );
  383. }
  384.  
  385.  
  386. onDeadEvent( team )
  387. {
  388. if ( level.bombExploded || level.bombDefused )
  389. return;
  390.  
  391. if ( team == "all" )
  392. {
  393. if ( level.bombPlanted )
  394. dd_endGame( game["attackers"], game["strings"][game["defenders"]+"_eliminated"] );
  395. else
  396. dd_endGame( game["defenders"], game["strings"][game["attackers"]+"_eliminated"] );
  397. }
  398. else if ( team == game["attackers"] )
  399. {
  400. if ( level.bombPlanted )
  401. return;
  402.  
  403. level thread dd_endGame( game["defenders"], game["strings"][game["attackers"]+"_eliminated"] );
  404. }
  405. else if ( team == game["defenders"] )
  406. {
  407. level thread dd_endGame( game["attackers"], game["strings"][game["defenders"]+"_eliminated"] );
  408. }
  409. }
  410.  
  411.  
  412. onNormalDeath( victim, attacker, lifeId )
  413. {
  414. score = maps\mp\gametypes\_rank::getScoreInfoValue( "kill" );
  415. assert( isDefined( score ) );
  416.  
  417. team = victim.team;
  418.  
  419. if ( game["state"] == "postgame" && (victim.team == game["defenders"] || !level.bombPlanted) )
  420. attacker.finalKill = true;
  421.  
  422. if ( victim.isPlanting )
  423. {
  424. thread maps\mp\_matchdata::logKillEvent( lifeId, "planting" );
  425. }
  426. else if ( victim.isDefusing )
  427. {
  428. thread maps\mp\_matchdata::logKillEvent( lifeId, "defusing" );
  429. }
  430. }
  431.  
  432.  
  433. onTimeLimit()
  434. {
  435. dd_endGame( game["defenders"], game["strings"]["time_limit_reached"] );
  436. }
  437.  
  438.  
  439. updateGametypeDvars()
  440. {
  441. level.plantTime = dvarFloatValue( "planttime", 5, 0, 20 );
  442. level.defuseTime = dvarFloatValue( "defusetime", 5, 0, 20 );
  443. level.bombTimer = dvarIntValue( "bombtimer", 45, 1, 300 );
  444. level.ddTimeToAdd = dvarFloatValue( "addtime", 2, 0, 5 );; //how much time is added to the match when a target is destroyed
  445. }
  446.  
  447.  
  448. bombs()
  449. {
  450. level.bombPlanted = false;
  451. level.bombDefused = false;
  452. level.bombExploded = 0;
  453.  
  454. level.bombZones = [];
  455.  
  456. bombZones = getEntArray( "bombzone", "targetname" );
  457.  
  458. for ( index = 0; index < bombZones.size; index++ )
  459. {
  460. trigger = bombZones[index];
  461. visuals = getEntArray( bombZones[index].target, "targetname" );
  462.  
  463. bombZone = maps\mp\gametypes\_gameobjects::createUseObject( game["defenders"], trigger, visuals, (0,0,64) );
  464. bombZone maps\mp\gametypes\_gameobjects::allowUse( "enemy" );
  465. bombZone maps\mp\gametypes\_gameobjects::setUseTime( level.plantTime );
  466. bombZone maps\mp\gametypes\_gameobjects::setUseText( &"MP_PLANTING_EXPLOSIVE" );
  467. bombZone maps\mp\gametypes\_gameobjects::setUseHintText( &"PLATFORM_HOLD_TO_PLANT_EXPLOSIVES" );
  468. bombZone maps\mp\gametypes\_gameobjects::setKeyObject( level.ddBomb );
  469.  
  470. label = bombZone maps\mp\gametypes\_gameobjects::getLabel();
  471. bombZone.label = label;
  472. bombZone.index = index;
  473. bombZone maps\mp\gametypes\_gameobjects::set2DIcon( "friendly", "waypoint_defend" + label );
  474. bombZone maps\mp\gametypes\_gameobjects::set3DIcon( "friendly", "waypoint_defend" + label );
  475. bombZone maps\mp\gametypes\_gameobjects::set2DIcon( "enemy", "waypoint_target" + label );
  476. bombZone maps\mp\gametypes\_gameobjects::set3DIcon( "enemy", "waypoint_target" + label );
  477. bombZone maps\mp\gametypes\_gameobjects::setVisibleTeam( "any" );
  478. bombZone.onBeginUse = ::onBeginUse;
  479. bombZone.onEndUse = ::onEndUse;
  480. bombZone.onUse = ::onUseObject;
  481. bombZone.onCantUse = ::onCantUse;
  482. bombZone.useWeapon = "briefcase_bomb_mp";
  483. bombZone.visuals[0].killCamEnt = spawn( "script_model", bombZone.visuals[0].origin + (0,0,128) );
  484.  
  485. for ( i = 0; i < visuals.size; i++ )
  486. {
  487. if ( isDefined( visuals[i].script_exploder ) )
  488. {
  489. bombZone.exploderIndex = visuals[i].script_exploder;
  490. break;
  491. }
  492. }
  493.  
  494. level.bombZones[level.bombZones.size] = bombZone;
  495.  
  496. bombZone.bombDefuseTrig = getent( visuals[0].target, "targetname" );
  497. assert( isdefined( bombZone.bombDefuseTrig ) );
  498. bombZone.bombDefuseTrig.origin += (0,0,-10000);
  499. bombZone.bombDefuseTrig.label = label;
  500. }
  501.  
  502. for ( index = 0; index < level.bombZones.size; index++ )
  503. {
  504. array = [];
  505. for ( otherindex = 0; otherindex < level.bombZones.size; otherindex++ )
  506. {
  507. if ( otherindex != index )
  508. array[ array.size ] = level.bombZones[otherindex];
  509. }
  510. level.bombZones[index].otherBombZones = array;
  511. }
  512. }
  513.  
  514. onUseObject( player )
  515. {
  516. team = player.pers["team"];
  517. otherTeam = level.otherTeam[team];
  518.  
  519. if ( !self maps\mp\gametypes\_gameobjects::isFriendlyTeam( player.pers["team"] ) )
  520. {
  521. player notify ( "bomb_planted" );
  522. player playSound( "mp_bomb_plant" );
  523.  
  524. thread teamPlayerCardSplash( "callout_bombplanted", player );
  525. //iPrintLn( &"MP_EXPLOSIVES_PLANTED_BY", player );
  526. leaderDialog( "bomb_planted" );
  527.  
  528. player thread maps\mp\gametypes\_hud_message::SplashNotify( "plant", maps\mp\gametypes\_rank::getScoreInfoValue( "plant" ) );
  529. player thread maps\mp\gametypes\_rank::giveRankXP( "plant" );
  530. maps\mp\gametypes\_gamescore::givePlayerScore( "plant", player );
  531. player incPlayerStat( "bombsplanted", 1 );
  532. player thread maps\mp\_matchdata::logGameEvent( "plant", player.origin );
  533. player.bombPlantedTime = getTime();
  534.  
  535. level thread bombPlanted( self, player );
  536.  
  537. level.bombOwner = player;
  538. self.useWeapon = "briefcase_bomb_defuse_mp";
  539. self setUpForDefusing();
  540. }
  541. else // defused the bomb
  542. {
  543. self thread bombHandler( player, "defused" );
  544. }
  545. }
  546.  
  547.  
  548. resetBombZone()
  549. {
  550. self maps\mp\gametypes\_gameobjects::allowUse( "enemy" );
  551. self maps\mp\gametypes\_gameobjects::setUseTime( level.plantTime );
  552. self maps\mp\gametypes\_gameobjects::setUseText( &"MP_PLANTING_EXPLOSIVE" );
  553. self maps\mp\gametypes\_gameobjects::setUseHintText( &"PLATFORM_HOLD_TO_PLANT_EXPLOSIVES" );
  554. self maps\mp\gametypes\_gameobjects::setKeyObject( level.ddBomb );
  555. self maps\mp\gametypes\_gameobjects::set2DIcon( "friendly", "waypoint_defend" + self.label );
  556. self maps\mp\gametypes\_gameobjects::set3DIcon( "friendly", "waypoint_defend" + self.label );
  557. self maps\mp\gametypes\_gameobjects::set2DIcon( "enemy", "waypoint_target" + self.label );
  558. self maps\mp\gametypes\_gameobjects::set3DIcon( "enemy", "waypoint_target" + self.label );
  559. self maps\mp\gametypes\_gameobjects::setVisibleTeam( "any" );
  560. self.useWeapon = "briefcase_bomb_mp";
  561. }
  562.  
  563. setUpForDefusing()
  564. {
  565. self maps\mp\gametypes\_gameobjects::allowUse( "friendly" );
  566. self maps\mp\gametypes\_gameobjects::setUseTime( level.defuseTime );
  567. self maps\mp\gametypes\_gameobjects::setUseText( &"MP_DEFUSING_EXPLOSIVE" );
  568. self maps\mp\gametypes\_gameobjects::setUseHintText( &"PLATFORM_HOLD_TO_DEFUSE_EXPLOSIVES" );
  569. self maps\mp\gametypes\_gameobjects::setKeyObject( undefined );
  570. self maps\mp\gametypes\_gameobjects::set2DIcon( "friendly", "waypoint_defuse" + self.label );
  571. self maps\mp\gametypes\_gameobjects::set3DIcon( "friendly", "waypoint_defuse" + self.label );
  572. self maps\mp\gametypes\_gameobjects::set2DIcon( "enemy", "waypoint_defend" + self.label );
  573. self maps\mp\gametypes\_gameobjects::set3DIcon( "enemy", "waypoint_defend" + self.label );
  574. self maps\mp\gametypes\_gameobjects::setVisibleTeam( "any" );
  575. }
  576.  
  577. onBeginUse( player )
  578. {
  579. if ( self maps\mp\gametypes\_gameobjects::isFriendlyTeam( player.pers["team"] ) )
  580. {
  581. player playSound( "mp_bomb_defuse" );
  582. player.isDefusing = true;
  583.  
  584. bestDistance = 9000000;
  585. closestBomb = undefined;
  586.  
  587. if ( isDefined( level.ddBombModel ) )
  588. {
  589. foreach ( bomb in level.ddBombModel )
  590. {
  591. if ( !isDefined( bomb ) )
  592. continue;
  593.  
  594. dist = distanceSquared( player.origin, bomb.origin );
  595.  
  596. if ( dist < bestDistance )
  597. {
  598. bestDistance = dist;
  599. closestBomb = bomb;
  600. }
  601. }
  602.  
  603. assert( isDefined(closestBomb) );
  604. player.defusing = closestBomb;
  605. closestBomb hide();
  606. }
  607. }
  608. else
  609. {
  610. player.isPlanting = true;
  611. }
  612. }
  613.  
  614. onEndUse( team, player, result )
  615. {
  616. if ( !isDefined( player ) )
  617. return;
  618.  
  619. if ( isAlive( player ) )
  620. {
  621. player.isDefusing = false;
  622. player.isPlanting = false;
  623. }
  624.  
  625. if ( self maps\mp\gametypes\_gameobjects::isFriendlyTeam( player.pers["team"] ) )
  626. {
  627. if ( isDefined( player.defusing ) && !result )
  628. {
  629. player.defusing show();
  630. }
  631. }
  632. }
  633.  
  634. onCantUse( player )
  635. {
  636. player iPrintLnBold( &"MP_BOMBSITE_IN_USE" );
  637. }
  638.  
  639. onReset()
  640. {
  641. }
  642.  
  643. bombPlanted( destroyedObj, player )
  644. {
  645. destroyedObj endon( "defused" );
  646.  
  647. level.bombsPlanted += 1;
  648. self setBombTimerDvar();
  649. maps\mp\gametypes\_gamelogic::pauseTimer();
  650. level.timePauseStart = getTime();
  651. level.timeLimitOverride = true;
  652.  
  653. level.bombPlanted = true;
  654. level.destroyedObject = destroyedObj;
  655.  
  656. if ( level.destroyedObject.label == "_a" )
  657. level.aPlanted = true;
  658. else
  659. level.bPlanted = true;
  660.  
  661. level.destroyedObject.bombPlanted = true;
  662.  
  663. destroyedObj.visuals[0] thread playDemolitionTickingSound(destroyedObj);
  664. level.tickingObject = destroyedObj.visuals[0];
  665.  
  666. self dropBombModel( player, destroyedObj.label );
  667. destroyedObj.bombDefused = false;
  668. destroyedObj maps\mp\gametypes\_gameobjects::allowUse( "none" );
  669. destroyedObj maps\mp\gametypes\_gameobjects::setVisibleTeam( "none" );
  670. destroyedObj setUpForDefusing();
  671.  
  672. destroyedObj BombTimerWait(destroyedObj); //waits for bomb to explode!
  673.  
  674. destroyedObj thread bombHandler( player ,"explode" );
  675.  
  676. }
  677.  
  678. bombHandler( player, destType )
  679. {
  680. self.visuals[0] notify( "stopTicking" );
  681. level.bombsPlanted -= 1;
  682.  
  683. if ( self.label == "_a" )
  684. level.aPlanted = false;
  685. else
  686. level.bPlanted = false;
  687.  
  688. self.bombPlanted = 0;
  689.  
  690. self restartTimer();
  691. self setBombTimerDvar();
  692.  
  693. setDvar( "ui_bombtimer" + self.label, -1 );
  694. //self maps\mp\gametypes\_gameobjects::updateTimer( 0, false );
  695.  
  696. if ( level.gameEnded )
  697. return;
  698.  
  699. if ( destType == "explode" )
  700. {
  701. level.bombExploded += 1;
  702.  
  703. explosionOrigin = self.curorigin;
  704. level.ddBombModel[ self.label ] Delete();
  705.  
  706. if ( isdefined( player ) )
  707. {
  708. self.visuals[0] radiusDamage( explosionOrigin, 512, 200, 20, player );
  709. player incPlayerStat( "targetsdestroyed", 1 );
  710. }
  711. else
  712. {
  713. self.visuals[0] radiusDamage( explosionOrigin, 512, 200, 20 );
  714. }
  715.  
  716. rot = randomfloat(360);
  717. explosionEffect = spawnFx( level._effect["bombexplosion"], explosionOrigin + (0,0,50), (0,0,1), (cos(rot),sin(rot),0) );
  718. triggerFx( explosionEffect );
  719.  
  720. PlayRumbleOnPosition( "grenade_rumble", explosionOrigin );
  721. earthquake( 0.75, 2.0, explosionOrigin, 2000 );
  722.  
  723. thread playSoundinSpace( "exp_suitcase_bomb_main", explosionOrigin );
  724.  
  725. if ( isDefined( self.exploderIndex ) )
  726. exploder( self.exploderIndex );
  727.  
  728. self maps\mp\gametypes\_gameobjects::disableObject();
  729.  
  730. if ( level.bombExploded < 2 )
  731. {
  732. foreach ( splashPlayer in level.players )
  733. splashPlayer thread maps\mp\gametypes\_hud_message::SplashNotify( "time_added" );
  734. }
  735.  
  736. wait 2;
  737.  
  738. if ( level.bombExploded > 1 )
  739. dd_endGame( game["attackers"], game["strings"]["target_destroyed"] );
  740. else
  741. level thread teamPlayerCardSplash( "callout_time_added", player );
  742. }
  743. else //defused
  744. {
  745. player notify ( "bomb_defused" );
  746. self notify( "defused" );
  747.  
  748. // if ( !level.hardcoreMode )
  749. // iPrintLn( &"MP_EXPLOSIVES_DEFUSED_BY", player );
  750.  
  751. leaderDialog( "bomb_defused" );
  752.  
  753. level thread teamPlayerCardSplash( "callout_bombdefused", player );
  754.  
  755. level thread bombDefused( self );
  756. self resetBombzone();
  757.  
  758. if ( isDefined( level.bombOwner ) && ( level.bombOwner.bombPlantedTime + 4000 + (level.defuseTime*1000) ) > getTime() && isReallyAlive( level.bombOwner ) )
  759. player thread maps\mp\gametypes\_hud_message::SplashNotify( "ninja_defuse", ( maps\mp\gametypes\_rank::getScoreInfoValue( "defuse" ) ) );
  760. else
  761. player thread maps\mp\gametypes\_hud_message::SplashNotify( "defuse", maps\mp\gametypes\_rank::getScoreInfoValue( "defuse" ) );
  762.  
  763. player thread maps\mp\gametypes\_rank::giveRankXP( "defuse" );
  764. maps\mp\gametypes\_gamescore::givePlayerScore( "defuse", player );
  765. player incPlayerStat( "bombsdefused", 1 );
  766. player thread maps\mp\_matchdata::logGameEvent( "defuse", player.origIn );
  767. }
  768.  
  769. }
  770.  
  771. playDemolitionTickingSound( site )
  772. {
  773. self endon("death");
  774. self endon("stopTicking");
  775. level endon("game_ended");
  776.  
  777. while(1)
  778. {
  779. self playSound( "ui_mp_suitcasebomb_timer" );
  780.  
  781. if ( !isDefined( site.waitTime ) || site.waitTime > 10 )
  782. wait 1.0;
  783. else if ( isDefined( site.waitTime ) && site.waitTime > 5 )
  784. wait 0.5;
  785. else
  786. wait 0.25;
  787. maps\mp\gametypes\_hostmigration::waitTillHostMigrationDone();
  788. }
  789. }
  790.  
  791. setBombTimerDvar()
  792. {
  793. println( "BOMBS PLANTED: " + level.bombsPlanted );
  794.  
  795. if ( level.bombsPlanted == 1 )
  796. setDvar( "ui_bomb_timer", 2 );
  797. else if ( level.bombsPlanted == 2 )
  798. setDvar( "ui_bomb_timer", 3 );
  799. else
  800. setDvar( "ui_bomb_timer", 0 );
  801. }
  802.  
  803.  
  804. dropBombModel( player, site )
  805. {
  806. trace = bulletTrace( player.origin + (0,0,20), player.origin - (0,0,2000), false, player );
  807.  
  808. tempAngle = randomfloat( 360 );
  809. forward = (cos( tempAngle ), sin( tempAngle ), 0);
  810. forward = vectornormalize( forward - common_scripts\utility::vector_multiply( trace["normal"], vectordot( forward, trace["normal"] ) ) );
  811. dropAngles = vectortoangles( forward );
  812.  
  813. level.ddBombModel[ site ] = spawn( "script_model", trace["position"] );
  814. level.ddBombModel[ site ].angles = dropAngles;
  815. level.ddBombModel[ site ] setModel( "prop_suitcase_bomb" );
  816. }
  817.  
  818.  
  819. restartTimer()
  820. {
  821. if ( level.bombsPlanted <= 0 )
  822. {
  823. maps\mp\gametypes\_gamelogic::resumeTimer();
  824. level.timePaused = ( getTime() - level.timePauseStart ) ;
  825. level.timeLimitOverride = false;
  826. }
  827. }
  828.  
  829.  
  830. BombTimerWait(siteLoc)
  831. {
  832. level endon("game_ended");
  833. level endon("bomb_defused" + siteLoc.label );
  834.  
  835. siteLoc.waitTime = level.bombTimer;
  836.  
  837. while ( siteLoc.waitTime >= 0 )
  838. {
  839. siteLoc.waitTime--;
  840. setDvar( "ui_bombtimer" + siteLoc.label, siteLoc.waitTime );
  841.  
  842. //self maps\mp\gametypes\_gameobjects::updateTimer( waitTime, true );
  843.  
  844. if ( siteLoc.waitTime >= 0 )
  845. wait( 1 );
  846.  
  847. maps\mp\gametypes\_hostmigration::waitTillHostMigrationDone();
  848. }
  849. }
  850.  
  851. bombDefused( siteDefused )
  852. {
  853. level.tickingObject maps\mp\gametypes\_gamelogic::stopTickingSound();
  854. siteDefused.bombDefused = true;
  855. self setBombTimerDvar();
  856.  
  857. setDvar( "ui_bombtimer" + siteDefused.label, -1 );
  858.  
  859. level notify("bomb_defused" + siteDefused.label);
  860. }
  861.  
  862. initGametypeAwards()
  863. {
  864. maps\mp\_awards::initStatAward( "targetsdestroyed", 0, maps\mp\_awards::highestWins );
  865. maps\mp\_awards::initStatAward( "bombsplanted", 0, maps\mp\_awards::highestWins );
  866. maps\mp\_awards::initStatAward( "bombsdefused", 0, maps\mp\_awards::highestWins );
  867. maps\mp\_awards::initStatAward( "bombcarrierkills", 0, maps\mp\_awards::highestWins );
  868. maps\mp\_awards::initStatAward( "bombscarried", 0, maps\mp\_awards::highestWins );
  869. maps\mp\_awards::initStatAward( "killsasbombcarrier", 0, maps\mp\_awards::highestWins );
  870. }
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!