NEO Scavenger savegame manager batch file

@ECHO OFF

cls

REM Find and set .bat file launch folder.
SET launchdir=%~dp0

REM Look for NEOScavenger.exe and create NEOsave folder in .bat file folder.
IF EXIST "NEOScavenger.exe" (
    IF NOT EXIST "NEOsave" (
        mkdir NEOsave
        ECHO.
        ECHO NEOsave folder created in: %launchdir%NEOsave
        ECHO.
        PAUSE
    )
) ELSE (
    ECHO.
    ECHO ERROR: NEOScavenger.exe not found.
    ECHO.
    PAUSE
    GOTO exitNEOsave
)

REM Menu and save backup management.
:menu
cls
ECHO ==================================
ECHO   NEO Scavenger SAVEGAME BACKUP:
ECHO ==================================
ECHO.
ECHO    1: START NEO Scavenger
ECHO.
ECHO    2: SAVE savegame
ECHO    3: RESTORE savegame
ECHO.
ECHO    4. EXIT
ECHO.
ECHO.

SET /P selection=SELECT:
ECHO.
IF "%selection%"=="1" GOTO startNEO
IF "%selection%"=="2" GOTO saveNEO
IF "%selection%"=="3" GOTO loadNEO
IF "%selection%"=="4" GOTO exitNEOsave



:startNEO
IF NOT EXIST "NEOScavenger.exe" (
    ECHO  ERROR: NEOScavenger.exe not found.
    PAUSE
    GOTO menu
) ELSE (
    NEOScavenger.exe
    GOTO menu
)

:saveNEO
REM Find NEOScavenger Flash Player folder and savegames.
SET p=
FOR /r "%userprofile%\AppData\Roaming\Macromedia\Flash Player\#SharedObjects" %%a IN (*) DO IF "%%~nxa"=="nsTest.sol" SET p=%%~dpa
IF DEFINED p (
    ECHO Savegame found in: %p%
) ELSE (
    ECHO ERROR: No NEO Scavenger savegame found.
    ECHO.
    PAUSE
    GOTO menu
)

REM Copy savegame from NEOScavenger Flash Player folder to backup folder.
XCOPY "%p%*.*" "%launchdir%NEOsave\" /y
ECHO.
ECHO Savegame copied to: %launchdir%NEOsave\
ECHO.
PAUSE
GOTO menu

:loadNEO
REM Look for backed up files in NEOsave.
IF NOT EXIST "%launchdir%NEOsave\nsTest.sol" (
    ECHO ERROR: No NEO Scavenger savegame found in: %launchdir%NEOsave\
    ECHO.
    PAUSE
    GOTO menu
)

REM Find NEOScavenger Flash Player folder.
SET p=
FOR /r "%userprofile%\AppData\Roaming\Macromedia\Flash Player\#SharedObjects" %%a IN (*) DO IF "%%~nxa"=="nsTest.sol" SET p=%%~dpa
IF DEFINED p (
    ECHO NEO Scavenger savegame folder found in: %p%
) ELSE (
    ECHO ERROR: No NEO Scavenger savegame folder found.
    ECHO SOLUTION: Please restart NEO Scavenger, exit the game and run this batch file again.
    ECHO.
    PAUSE
    GOTO menu
)

REM Copy savegame from backup folder to NEOScavenger Flash Player savegame folder.
XCOPY "%launchdir%NEOsave\*.*" "%p%" /y
ECHO.
ECHO NEO Scavenger savegame restored.
ECHO.
PAUSE
GOTO menu

:exitNEOsave
EXIT