openjk PKGBUILD

pkgname=openjk-git
_gitname=OpenJK
pkgver=d0b9a77
pkgrel=1
pkgdesc="Open Source Jedi Knight III Engine. Needs original media files."
arch=('i686' 'x86_64')
url="https://github.com/Razish/OpenJK"
license=('GPL2')
depends=('openal' 'sdl2-hg' 'libxext' 'glu' 'libsm')
[ "$CARCH" == "x86_64" ] && depends=('lib32-openal' 'lib32-sdl2-hg' 'lib32-libxext' 'lib32-glu' 'lib32-libsm')
makedepends=('git' 'cmake' 'yasm')
install=openjk.install
conflicts=('openjk')
provides=('openjk')
#source=('git+https://github.com/Razish/OpenJK.git'
source=('git://github.com/Razish/OpenJK.git'
        'openjksp.png'
    'openjkmp.png'
    'openjksp.desktop'
    'openjkmp.desktop'
    'openjk'
    'openjksp'
    'openjkded'
    'openjk.install')
# Because the sources are not static, skip Git checksum:
md5sums=('SKIP'
         'ca7a0aae3edf8deb828ebeeaad6f61fa'
     'b1017078d96f413372d051f9d0b2ea9a'
     'f6c14708e1c6b5ba9cea3f142905cede'
     'c479c3e77f600602ed94d1b31066fb51'
     'ab3608be06403ef9a1398eea9549ac7c'
     'c0a4e1a0b70e388eb26e82131661ad35'
     'e7aa000fdab0a95d81b87ba913e3f1c0'
     '2070030c5a9c94cdc5870bbe09fedd91')

pkgver() {
  cd $_gitname
  # Use the tag of the last commit
  git describe --always | sed 's|-|.|g'
}

build() {
  cd $_gitname
  if [ "$CARCH" == "x86_64" ]; then
    cmake . -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_CXX_FLAGS=-m32 -DCMAKE_C_FLAGS=-m32 -DCMAKE_SHARED_LINKER_FLAGS=-m32 -DCMAKE_SIZEOF_VOID_P=4
  else
    cmake . -DCMAKE_INSTALL_PREFIX=/usr
  fi
  make
}

package() {
  cd $_gitname
  make PREFIX=/usr DESTDIR="$pkgdir" install

  # move files to correct places
  mkdir -p $pkgdir/usr/share/openjk
  mv $pkgdir/usr/OpenJK $pkgdir/usr/share/openjk/base
  mv $pkgdir/usr/*.{i386,so} $pkgdir/usr/share/openjk/

  install -Dm755 "$srcdir/openjk" "$pkgdir/usr/bin/openjk"
  install -Dm755 "$srcdir/openjksp" "$pkgdir/usr/bin/openjksp"
  install -Dm755 "$srcdir/openjkded" "$pkgdir/usr/bin/openjkded"

  install -Dm755 "$srcdir/openjksp.desktop" "$pkgdir/usr/share/applications/openjksp.desktop"
  install -Dm755 "$srcdir/openjkmp.desktop" "$pkgdir/usr/share/applications/openjkmp.desktop"

  install -Dm644 "$srcdir/openjksp.png" "$pkgdir/usr/share/pixmaps/openjksp.png"
  install -Dm644 "$srcdir/openjkmp.png" "$pkgdir/usr/share/pixmaps/openjkmp.png"
}