//////////
    //Kaikki//
    //////////

enableSaving [false, false];

//Tfar Config
tf_same_sw_frequencies_for_side = true;
tf_no_auto_long_range_radio = true;
tf_same_lr_frequencies_for_side = true;
TF_give_personal_radio_to_regular_soldier = true;

//AFI safestartti päälle.
[] spawn afi_safestart;

//Muuttujat.
AFI_Merkit_Lontoo = true;
afi_enemy_vehicles_allowed = true;



    ////////////
    //Pelaajat//
    ////////////
if (hasInterface) then {

    CHVD_allowNoGrass = false; // Set 'false' if you want to disable "Low" option for terrain (default: true)
    CHVD_maxView = 2000; // Set maximum view distance (default: 12000)
    CHVD_maxObj = 2000; // Set maximimum object view distance (default: 12000)


    [] call compile preprocessFileLineNumbers "briefing.sqf";

    [] spawn {
        finishMissionInit;
        waitUntil{!isNull player && time > 0};
        openMap [true, true];
        _camera = "camera" camCreate [(getPos player select 0),(getPos player select 1),100];
        _camera cameraEffect ["internal","back"];
        _camera camSetFOV 0.700;
        _camera camSetTarget player;
        _camera camCommit 0;
        waitUntil {camCommitted _camera};
        cutText["Synchronization, please wait...\nSynkronisoidaan, odota...\nSynkroniserar, vänta...", "PLAIN", 10, true];
        waitUntil {time > 20};
        player cameraEffect ["terminate","back"];
        camDestroy _camera;
        cutText["", "BLACK IN", 5];
        openMap [false, false];
    };
};