buildscript {
    repositories {
        mavenCentral()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:1.2-SNAPSHOT'
    }
}

apply plugin: 'forge'
group= "com.mightydanp.eot"

ext.configFile = file "build.properties"

configFile.withReader {
    def prop = new Properties()
    prop.load(it)
    project.ext.config = new ConfigSlurper().parse prop
}

ext.dependencies = ['META-INF/eot_at']

version = "${config.mod_version}"

minecraft {
    version = "1.7.10-10.13.4.1448-1.7.10"
    runDir = "eclipse/assets"
}

sourceSets{
    main {
	    java {
            srcDirs = ['src/main/java', 'src/api/java']
        }
        resources {
            srcDirs = ['src/main/resources', 'src/api/resources']
        }
	}
}

ext.coreFiles = ['com/mightydanp/eot/**',
					'tconstruct/**',
					'assets/eot/**',
					'assets/minecraft/**']

ext.coreJar = "build/libs/" + "${config.mod_name}" + "-" + version + ".jar"

jar
{
    manifest {
        attributes 'FMLAT': 'TConstruct_at.cfg'
    }
	// Add necessary files, remove unnecessary ones.
	includes.addAll(project.ext.coreFiles)
	includes.addAll('mcmod.info')
	includes.addAll('LICENSE.txt')
	includes.addAll(project.ext.dependencies)
}

task moveCoreMcmodInfo(type: Copy, dependsOn: "reobf") {
	from 'src/main/resources/assets/eot/mcmod.info'
	from 'LICENSE.txt'
	from(zipTree(project.ext.coreJar))
	into 'temporary'
}

task rePackAllJarCore(type: Jar, dependsOn: "moveCoreMcmodInfo") {
	from 'temporary'
}

task packJar(type: Jar, dependsOn: "rePackAllJarCore") {
	// Jar will always be updated
	outputs.upToDateWhen {false}
	// Set the jar's base name
	baseName = "Essence of Tech"

	from(zipTree(project.ext.coreJar)) {
		// Add necessary files, remove unnecessary ones.
		includes.addAll(project.ext.coreFiles)
		includes.addAll('mcmod.info')
		includes.addAll('LICENSE.txt')
		excludes.addAll(project.ext.dependencies)
	}
}

task packJarDev(type: Jar, dependsOn: "classes") {
	from (sourceSets.main.output) {
		includes.addAll(project.ext.coreFiles)
		includes.addAll('mcmod.info')
		includes.addAll('LICENSE.txt')
		includes.addAll(project.ext.dependencies)
	}

	from (sourceSets.main.allSource) {
		includes.addAll(project.ext.coreFiles)
		includes.addAll('mcmod.info')
		includes.addAll('LICENSE.txt')
		excludes.addAll(project.ext.dependencies)
		excludes.addAll('assets')
		into 'src'
	}

	// Jar will always be updated
	outputs.upToDateWhen {false}
	// Set the jar's base name
	baseName = "Essence of Tech-Dev"
}

task cleanOldJar(type: Delete, dependsOn: "packJar") {
	delete 'temporary', project.ext.coreJar
}

task cleanOldJarDev(type: Delete, dependsOn: "packJarDev") {
	delete 'temporary', project.ext.coreJar
}