#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

xOffset = 0
iconWidth = 64
grabToggle = 0
runToggle = 0
clicking = 0

Gui +LastFound
    hWnd := WinExist()
    DllCall("RegisterShellHookWindow", UInt, hWnd)
    MsgNum := DllCall("RegisterWindowMessage", Str, "SHELLHOOK")
    OnMessage(MsgNum, "ShellMessage")
return

ShellMessage(wParam, lParam)
{
    global
    if (wParam=4) or (wParam=32772)
    {
        grabToggle := 0
        SetTimer, grab, delete
        runToggle := 0
        RedrawIcons()
    }
}

RedrawIcons()
{
    global
    return ; comment out this line for icons (won't work in fullscreen)
    if (grabToggle = 1)
    {
        SplashImage, 1:grabbing.png, b x0 y0
        xOffset := iconWidth
    }
    else
    {
        SplashImage, 1:off
        xOffset := 0
    }
    if (runToggle = 1)
    {
        SplashImage, 2:running.png, b x%xOffset% y0
        xOffset := (xOffset + iconWidth)
    }
    else
    {
        SplashImage, 2:off
    }
    if (clicking = 1)
    {
        SplashImage, 3:clicking.png, b x%xOffset% y0
    }
    else
    {
        SplashImage, 3:off
    }
    return
}

ARKRunning()
{
    return WinActive("ARK: Survival Evolved")
}

grab:
    Send e
Return

F1::
    if (ARKRunning())
    {
        grabToggle := (1 - grabToggle)
        if (grabToggle = 1)
        {
            SetTimer, grab, 100
        }
        else
        {
            SetTimer, grab, delete
        }
        RedrawIcons()
    }
Return

F2::
    if (ARKRunning())
    {
        runToggle := (1 - runToggle)
        if (runToggle = 1)
        {
            SendInput {w down}
        }
        else
        {
            SendInput {w up}
        }
        RedrawIcons()
    }
Return

F3::
    if (ARKRunning())
    {
        clicking := 1
        RedrawIcons()
        Loop 20
        {
            if (!ARKRunning())
            {
                clicking := 0
                RedrawIcons()
                return
            }
            Click
            Sleep 100
        }
        clicking := 0
        RedrawIcons()
    }
Return