AFK-System1.1 by K4biX

/*
AFK-System by K4biX. 23.10.2011 | Update1.1 24.10.2011
< http://forum.sa-mp.de/index.php?page=User&userID=15070 >
Credits müssen drinnen bleiben.
Editieren sowie verwenden dieses scriptes ist natürlich erlaubt.
*/
#include <a_samp>

new string[128];
new bool:SpielerIstAFK[MAX_PLAYERS];
new bool:IstSpielerGespawnt[MAX_PLAYERS];
new AFKTimer[MAX_PLAYERS];
new TextDrawUpdate[MAX_PLAYERS];
new Text:Textdraw0[MAX_PLAYERS];
new Text3D:AFK3DTextLabel[MAX_PLAYERS];
new Float:AlteSpielerPos[MAX_PLAYERS][3];

#define COLOR_WHITE 0xFFFFFFFF
#define COLOR_GRAU 0xBEBEBEFF
#define COLOR_ROT 0xFF6347AA
#define AFK_3DTextLabel 0x00FF00FF // <-- Farbcode des 3DTextLabel's über dem Spieler.

#define AntiAFK_Timer 60000*30 // <-- Timer wann Spieler gekickt werden sollen, wenn sie nicht mehr am Spiel teilnehmen.

main()
{
    print("\n-----------------------------------");
    print("    -----------------------------    ");
    print("    | K4biX's AFK-System Loaded |    ");
    print("    -----------------------------    ");
    print("             VERSION 1.0             ");
    print("    -----------------------------    ");
    print("------------------------------------\n");
}

public OnFilterScriptInit()
{
    SetTimer("AlleSpielerKontrollieren", AntiAFK_Timer, 0);
    return 1;
}

public OnFilterScriptExit()
{
    return 1;
}

public OnPlayerConnect(playerid)
{
    AFKTimer[playerid] = 0;
    SpielerIstAFK[playerid] = false;
    IstSpielerGespawnt[playerid] = false;

    Textdraw0[playerid] = TextDrawCreate(502.000000,121.000000," ");
    TextDrawAlignment(Textdraw0[playerid],0);
    TextDrawBackgroundColor(Textdraw0[playerid],0x00000066);
    TextDrawFont(Textdraw0[playerid],2);
    TextDrawLetterSize(Textdraw0[playerid],0.199999,1.000000);
    TextDrawColor(Textdraw0[playerid],0xffff00ff);
    TextDrawSetOutline(Textdraw0[playerid],1);
    TextDrawSetProportional(Textdraw0[playerid],1);
    TextDrawSetShadow(Textdraw0[playerid],10);
    return 1;
}

public OnPlayerDisconnect(playerid, reason)
{
    KillTimer(TextDrawUpdate[playerid]);
    TextDrawDestroy(Textdraw0[playerid]);
    return 1;
}

public OnPlayerSpawn(playerid)
{
    IstSpielerGespawnt[playerid] = true;
    return 1;
}

public OnPlayerDeath(playerid)
{
    IstSpielerGespawnt[playerid] = false;
    return 1;
}

public OnPlayerText(playerid, text[])
{
    if(SpielerIstAFK[playerid] == true)
    {
        SendClientMessage(playerid,COLOR_GRAU,"Im AFK-Modus kannst du den Chat nicht verwenden!");
        return 0;
    }
    return 1;
}

public OnPlayerCommandText(playerid, cmdtext[])
{
    if(!strcmp(cmdtext, "/AFK", true))
    {
        if(IsPlayerConnected(playerid))
        {
            if(SpielerIstAFK[playerid] == false)
            {
                new str[MAX_PLAYER_NAME+25];
                SpielerIstAFK[playerid] = true;
                TogglePlayerControllable(playerid,0);
                AFK3DTextLabel[playerid] = Create3DTextLabel("Spieler ist AFK\nSekunden: 0", AFK_3DTextLabel, 30.0, 40.0, 50.0, 40.0, 0);
                Attach3DTextLabelToPlayer(AFK3DTextLabel[playerid], playerid, 0.0, 0.0, 0.7);
                format(string,sizeof(string),"~y~AFK Status~w~: ~w~Aktiviert~n~~y~Sekunden~w~: 0");
                TextDrawSetString(Textdraw0[playerid], string);
                TextDrawShowForPlayer(playerid,Textdraw0[playerid]);
                TextDrawUpdate[playerid] = SetTimerEx("AFKTextDraw", 1000, 1, "i", playerid);
                SendClientMessage(playerid,COLOR_GRAU,"Du hast dich in den AFK-Modus begeben!");
                format(str, sizeof(str), "** %s ist nun abwesend. **", SpielerName(playerid));
                SendClientMessageToAll(COLOR_WHITE, str);
            }
            else
            {
                SendClientMessage(playerid,COLOR_GRAU,"Du befindest dich schon im AFK-Modus!");
                return 1;
            }
        }
        return 1;
    }
    if(!strcmp(cmdtext, "/BACK", true))
    {
        if(IsPlayerConnected(playerid))
        {
            if(SpielerIstAFK[playerid] == true)
            {
                new str[MAX_PLAYER_NAME+25];
                SpielerIstAFK[playerid] = false;
                AFKTimer[playerid] = 0;
                TogglePlayerControllable(playerid,1);
                TextDrawHideForPlayer(playerid,Textdraw0[playerid]);
                KillTimer(TextDrawUpdate[playerid]);
                Delete3DTextLabel(AFK3DTextLabel[playerid]);
                SendClientMessage(playerid,COLOR_GRAU,"Du bist aus dem AFK-Modus zurückgekehrt!");
                format(str, sizeof(str), "** %s ist nun wieder anwesend. **", SpielerName(playerid));
                SendClientMessageToAll(COLOR_WHITE, str);
            }
            else
            {
                SendClientMessage(playerid,COLOR_GRAU,"Du befindest dich nicht im AFK-Modus!");
                return 1;
            }
        }
        return 1;
    }
    return 0;
}

forward AFKTextDraw(playerid);
public AFKTextDraw(playerid)
{
    new Text3D[40];
    AFKTimer[playerid] ++;
    format(string,sizeof(string),"~y~AFK Status~w~: ~w~Aktiviert~n~~y~Sekunden~w~: %d", AFKTimer[playerid]);
    TextDrawSetString(Textdraw0[playerid], string);
    format(Text3D, sizeof(Text3D), "Spieler ist AFK\nSekunden: {FFFFFF}%d", AFKTimer[playerid]);
    Update3DTextLabelText(AFK3DTextLabel[playerid], AFK_3DTextLabel, Text3D);
}

forward AlleSpielerKontrollieren();
public AlleSpielerKontrollieren()
{
    for(new i = 0; i < MAX_PLAYERS; i++)
    {
        if(IsPlayerConnected(i) && IstSpielerGespawnt[i] == true)
        {
            if(!IsPlayerNPC(i))
            {
                new Float:PositionX, Float:PositionY, Float:PositionZ;
                GetPlayerPos(i, PositionX, PositionY, PositionZ);
                if(PositionX == AlteSpielerPos[i][0] && PositionY == AlteSpielerPos[i][1] && PositionZ == AlteSpielerPos[i][2])
                {
                    SendClientMessage(i, COLOR_ROT, "AntiAFK: Du wirst in 10 Sekunden gekickt, wenn du nicht wieder am Spiel teilnimmst."); // Rot
                    SetTimerEx("SpielerKontrollieren", 10000, 0, "i", i); //10000 ms = 10 Sekunden
                }
                AlteSpielerPos[i][0] = PositionX;
                AlteSpielerPos[i][1] = PositionY;
                AlteSpielerPos[i][2] = PositionZ;
            }
        }
    }
    return 1;
}

forward SpielerKontrollieren(playerid);
public SpielerKontrollieren(playerid)
{
    if(IsPlayerConnected(playerid) && IstSpielerGespawnt[playerid] == true)
    {
        if(!IsPlayerNPC(playerid))
        {
            new AntiAFKMessage[128];
            new Float:PositionX, Float:PositionY, Float:PositionZ;
            GetPlayerPos(playerid, PositionX, PositionY, PositionZ);
            if(PositionX == AlteSpielerPos[playerid][0] && PositionY == AlteSpielerPos[playerid][1] && PositionZ == AlteSpielerPos[playerid][2])
            {
                SendClientMessage(playerid, COLOR_ROT, "AntiAFK: Wegen Untätigkeit gekickt!");
                format(AntiAFKMessage, sizeof(AntiAFKMessage), "AntiAFK: %s wurde wegen Untätigkeit gekickt!", SpielerName(playerid));
                SendClientMessageToAll(COLOR_ROT, AntiAFKMessage);
                Kick(playerid);
            }
        }
    }
    return 1;
}

forward SpielerName(id);
SpielerName(id)
{
    new Name[MAX_PLAYER_NAME];
    GetPlayerName(id, Name, sizeof(Name));
    return Name;
}