Flydraw (pour dessiner)

#include <GUIConstantsEx.au3>
#include <Misc.au3>
#include <WindowsConstants.au3>

Opt("GUIOnEventMode", 1)
Opt("MustDeclareVars", 1)
Opt("MouseCoordMode", 2)

Dim $Gui
Dim $TailleFenetre[2] = [800, 600]

$Gui = GUICreate("Flyboard", $TailleFenetre[0], $TailleFenetre[1], -1, -1, -1, $WS_EX_CLIENTEDGE)
GUISetOnEvent($GUI_EVENT_CLOSE, "quit")
GUISetBkColor(0xFFFFFF)
GUISetState()

While(True)
    If(_IsPressed("01")) Then
        Dessiner()
    EndIf
    Sleep(10)
WEnd

Func Dessiner()
    ; On commence à dessiner
    Local $Dessiner[2]
    Local $BordureCote
    Local $AnciennePos[2] = [-1, -1]
    ; On récupère le DC de la gui
    Local $MyHDC = DLLCall("user32.dll","int","GetDC","hwnd",$Gui)
    If(Not(@error)) Then
        $Dessiner = MouseGetPos()
        If(Not(@error)) Then
            ; On se déplace sous la souris
            DLLCall ("gdi32.dll", "int", "MoveToEx", "ptr", $MyHDC[0], "int", $Dessiner[0], "int", $Dessiner[1], 'ptr', 0)
            While(_IsPressed("01"))
                $Dessiner = MouseGetPos()
                If($Dessiner[0] <> $AnciennePos[0] Or $Dessiner[1] <> $AnciennePos[1])Then
                    If($AnciennePos[0] = -1 And $AnciennePos[1] = -1) Then
                        $AnciennePos[0] = $Dessiner[0]
                        $AnciennePos[1] = $Dessiner[1]
                    EndIf
                    ; On trace une ligne qui part de l'ancienne position jusqu'à la nouvelle
                    DLLCall ("gdi32.dll", "int", "LineTo", "int", $MyHDC[0], "int", $Dessiner[0], "int", $Dessiner[1])
                    $AnciennePos[0] = $Dessiner[0]
                    $AnciennePos[1] = $Dessiner[1]
                EndIf
                Sleep(10)
            WEnd
        EndIf
    EndIf
    ;~ On libère la mémoire
    DLLCall("user32.dll","int","ReleaseDC","int",$MyHDC[0],"hwnd",0)
EndFunc

Func quit()
    Exit
EndFunc