VHD_set_over.bat

echo VHD Diff Resetter created by Wolfgang Unger and modified by ZiroKyl http://9b.asoiu.com/?p=2793

REM #########################
REM Variables
REM #########################
set VHD_Drive=D:
set VHD_Parent=VHD\PROJECTOR_PC.VHD
set VHD_OverFile1=VHD\PROJECTOR_PC_over1.VHD
set VHD_OverFile2=VHD\PROJECTOR_PC_over2.VHD
set VHD_OverGUID1={e3ccf964-9152-11e2-ad48-829adb767c32}
set VHD_OverGUID2={e3ccf965-9152-11e2-ad48-829adb767c32}

set TempFile=D:\VHD\diskpart.log
set LogFile=D:\VHD\diskpart_log.log
REM #########################

setlocal enableextensions enabledelayedexpansion

SET _RUN=1

for /f "tokens=2* usebackq" %%i in (`bcdedit /enum {current} /v`) do (
    if "%%i" == "{e3ccf963-9152-11e2-ad48-829adb767c32}" SET _RUN=0
)

if %_RUN%==1 (

REM Try to delete both over file.
del %VHD_Drive%\%VHD_OverFile1%
del %VHD_Drive%\%VHD_OverFile2%

REM Cheack: if successful image 1 is bootet.
if exist "%VHD_Drive%\%VHD_OverFile1%" (

 echo create vdisk file=%VHD_Drive%\%VHD_OverFile2% parent=%VHD_Drive%\%VHD_Parent% > %TempFile%
 echo exit >> %TempFile%

REM Error code: https://technet.microsoft.com/en-us/library/cc766465(v=ws.10).aspx
 diskpart /s %TempFile% >> %LogFile% && ( timeout /t 15 && bcdedit /default %VHD_OverGUID2% )

) else (

 echo create vdisk file=%VHD_Drive%\%VHD_OverFile1% parent=%VHD_Drive%\%VHD_Parent% > %TempFile%
 echo exit >> %TempFile%

REM Error code: https://technet.microsoft.com/en-us/library/cc766465(v=ws.10).aspx
 diskpart /s %TempFile% >> %LogFile% && ( timeout /t 15 && bcdedit /default %VHD_OverGUID1% )

)

del %TempFile%
echo Done.
) else (
echo No needed.
)

endlocal