wxgtk-light

# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>
# Contributor: megadriver <megadriver at gmx dot com>, Janek Bevendorff <janek at refining-linux dot org>
# Based on wxgtk from [extra]

pkgname=wxgtk-light
pkgver=2.8.12
pkgrel=2
pkgdesc="GTK+ implementation of wxWidgets API for GUI (GNOME/GStreamer free!)"
arch=('i686' 'x86_64')
url="http://wxwidgets.org"
license=('custom:wxWindows')
depends=('gtk2' 'libgl' 'libxxf86vm' 'libsm' 'sdl')
makedepends=('mesa' 'ccache' 'glu' 'libxt')
provides=('wxgtk')
conflicts=('wxgtk')
source=(http://downloads.sourceforge.net/wxwindows/wxWidgets-${pkgver}.tar.bz2)

sha1sums=('c1a3c25de3ab43e2d722c2b7c4048e999c57ef21')

options=('ccache')  # Required to build libwx_gtk2u_mmedia

build() {
  rm -fr "${srcdir}/wxWidgets-build"
  cp -R "${srcdir}/wxWidgets-${pkgver}" "${srcdir}/wxWidgets-build"
  cd "${srcdir}/wxWidgets-build"

  sed -i 's,/usr/$wx_cv_std_libpath,& /usr/lib,' configure
  ./configure --prefix=/usr \
          --libdir=/usr/lib \
          --with-gtk=2 \
          --with-opengl \
          --enable-unicode \
          --enable-graphics_ctx  \
          --disable-optimize \
          --disable-mediactrl \
          --with-regex=builtin \
          --with-libpng=sys \
          --with-libxpm=sys \
          --with-libjpeg=sys \
          --with-libtiff=sys \
          --with-sdl \
          --disable-precomp-headers
  make
  make -C locale allmo
  cd contrib/src
  make
}

package() {
  cd "${srcdir}/wxWidgets-build"
  make DESTDIR="${pkgdir}" install
  cd contrib/src
  make DESTDIR="${pkgdir}" install
  install -D -m644 ../../docs/licence.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}