; Nazwa: Leczenie_Menu_v-1.9-w.txt
; Autor: Janusz [Fris]
; Dla postaci Wampir
; Linia 233 gdy zejda pozory w dzien postac nie moze sie leczyc przez 30s i skrypt nie wychodzi z petli
;====================================================
set #lpc 100
set %Ukrywanie 0  ;0 - wylaczone; 1 - wlaczone
set %lczyKogos 0
set %SkilTime #scnt + 9
set %autoLeczenie 1
set %kolor 89 ;38 - czerwony 89 - jasno niebieski
set %CelLeczenia #charid
set %KlawiszLeczenie F1
set #lpc 2000
menu clear
menu window color black
menu show
menu window size 220 170
menu window title Leczenie 1.9
menu font size 10
menu font color white
menu font BGColor black
menu text mtOpisLeczenie 1 1 Czas Leczenia
menu text mtOpisPoziomuHP 120 1 Poziom HP
menu font style b
menu font color red
menu font size 34
menu text mtCzasLeczenie 10 20 0
menu font color white
menu text mtPoziomHP 120 20 #HITS
menu font style ;b
menu font color white
menu font size 10
menu button mbWskrzesWamp 10 80 90 24 Res wamp
menu button mbWskrzesCzlek 120 80 90 24 Res czlek
menu button mb_LeczWampa 10 110 90 25 Lecz wampa
menu button mb_LeczCzleka 120 110 90 25 Lecz czleka
menu button mb_LeczSiebie 10 140 200 25 Lecz Siebie
;menu hideEUO
;====================================================
set #menubutton n/a
;=================== petla ===========================
loop:
set #lpc 200
if #menubutton = mb_LeczWampa
  {
  set #menubutton N/A
  set %lczyKogos 1
  event sysmessage Wskaz Cel
  set #targcurs 1
  repeat
  until #targcurs = 0
  set %RodzajBandaza AMF
  set %CelLeczenia #LTARGETID
  }
if #menubutton = mb_LeczCzleka
  {
  set #menubutton N/A
  set %lczyKogos 1
  event sysmessage Wskaz Cel
  set #targcurs 1
  repeat
  until #targcurs = 0
  set %RodzajBandaza ZLF
  set %CelLeczenia #LTARGETID
  }
if #menubutton = mb_LeczSiebie
  {
  set #menubutton N/A
  set %CelLeczenia #charid
  set %lczyKogos 0
  }
if #menubutton = mbWskrzesWamp
  {
  set #menubutton N/A
  gosub Wskrzeszenie wamp
  }
if #menubutton = mbWskrzesCzlek
  {
  set #menubutton N/A
  gosub Wskrzeszenie czlek
  }
if %lczyKogos = 1
   {
   finditem %RodzajBandaza C_ , #backpackid
   set #lobjectid #findid
   event macro 17
   set %TimeCel #scnt2 + 20
   repeat
      if %TimeCel < #scnt2
         {
         set #lobjectid #findid
         event macro 17
         set %TimeCel #scnt2 + 20
         }
   until #targcurs = 1
   finditem %CelLeczenia G
   wait 2
   set #ltargetid %CelLeczenia
   set #ltargetx #findx
   set #ltargety #findy
   set #ltargetz #findz
   set #ltargetkind 1
   event macro 22
   wait 7
   }
if #menubutton = CLOSED ;wcisnieto przycisk X
  {
  menu hide
  set #menubutton N/A
  halt
  }
if #hits < #maxhits && %autoLeczenie = 1 && %lczyKogos = 0
   gosub Leczenie
if %autoLeczenie = 0 && %lczyKogos = 0
  {
  onhotkey %KlawiszLeczenie
    gosub Leczenie
  }
if %Ukrywanie = 1 && %SkilTime < #scnt
  {
  event macro 13 21 ; ukrywanie
  set %SkilTime #scnt + 11
  }
if #hits < #maxhits && %lczyKogos = 0
   {
   event ExMsg #charid 3 %kolor 0 s [ #HITS / #MAXHITS ]
   }
goto loop










;------------------------------------------------------------
sub Wskrzeszenie
  if wamp in %1
     set %JakieBandaze AMF
  if czlek in %1
     set %JakieBandaze ZLF
  set #menubutton N/A
  finditem %JakieBandaze C_ . #backpackid
  for #findindex 1 #findcnt
     {
     if #findstack < 10
        event sysmessage Koncza Ci sie bandaze. Zostalo #findstack bandazy!!!
     set #lobjectid #findid
     event macro 17
     set %cel_time #scnt2 + 20
     repeat
        if %cel_time < #scnt2
           {
           set #lobjectid #findid
           event macro 17
           set %cel_time #scnt2 + 20
           }
        if #charghost = yes
           halt
        if A in #charstatus
           {
           event sysmessage Zostales unieruchomiony
           return
           }
     until #targcurs = 1
     }
  event sysmessage WCISNIJ PRZYCKISK "LECZ SIEBIE" PO WSKRZESZENIU

  repeat
  until #menubutton = mb_LeczSiebie ;wskrzesil in #journal
  goto loop
return wskrzeszony
;------------------------------------------------------------
sub Leczenie
  if #hits = #maxhits || HG in #CHARSTATUS
     return
  finditem AMF C_ , #backpackid
  for #findindex 1 #findcnt
    {
     if #findstack < 10
        event sysmessage Koncza Ci sie bandaze. Zostalo #findstack bandazy!!!
     set #lobjectid #findid
     event macro 17
     set %cel_time #scnt2 + 20
     repeat
        if %cel_time < #scnt2
           {
           set #lobjectid #findid
           event macro 17
           set %cel_time #scnt2 + 20
           }
        if #charghost = yes
           halt
     until #targcurs = 1
    }
     event macro 23
     set %cel_time2 #scnt2 + 20
     repeat
        if %cel_time2 < #scnt2
           {
           set #lobjectid #findid
           event macro 23
           set %cel_time2 #scnt2 + 20
           }
        if #charghost = yes
           halt
     until #targcurs = 0

     repeat
        if #hits = #maxhits
           return
        if #menubutton = mbWskrzesWamp
          {
          ;set #menubutton N/A
          gosub Wskrzeszenie wamp
          if #RESULT = wskrzeszony
             return
          }
        if #menubutton = mbWskrzesCzlek
          {
          ;set #menubutton N/A
          gosub Wskrzeszenie czlek
          if #RESULT = wskrzeszony
             return
          }
        if #charghost = yes
           halt
     until Zaczynasz in #sysmsg
     event ExMsg #charid 3 %kolor 0 s [ #HITS / #MAXHITS ]
     set %licznik 0
     set %czas #scnt2 + 9
     set %jindex #jindex
     set #lpc 1000
     set %czas_hp #scnt + 1
     repeat
        set #sysmsgcol 1088
        if %czas < #scnt2
           {
           set %licznik %licznik + 1
           if %licznik > 15 || #hits = #maxhits
              {
              menu Set mtCzasLeczenie 0
              menu Set mtPoziomHP #HITS
              event ExMsg #charid 3 %kolor %licznik s [ #HITS / #MAXHITS ]
              return
              }
           menu Set mtCzasLeczenie %licznik
           menu Set mtPoziomHP #HITS
           event ExMsg #charid 3 %kolor %licznik s [ #HITS / #MAXHITS ]
           if #menubutton = mbWskrzesWamp
             {
             ;set #menubutton N/A
             gosub Wskrzeszenie wamp
             if #RESULT = wskrzeszony
                return
             }
          if #menubutton = mbWskrzesCzlek
             {
             ;set #menubutton N/A
             gosub Wskrzeszenie czlek
             if #RESULT = wskrzeszony
                return
             }
           set %czas #scnt2 + 9
           }
       set %ji #jindex - %jindex
       for %i 1 %ji
           {
           scanjournal %i
           if Wyleczyl in #journal || palec in #journal || Nie_udalo in #journal || przestal in #journal || Anulowano. in #journal || Ta_osoba in #journal
              {
              menu Set mtCzasLeczenie 0
              menu Set mtPoziomHP #HITS
              return
              }
           }
        if #hits < 20 && #charghost = no && %czas_hp < #scnt
           {
           set #sysmsgcol 1080
           event sysmessage MASZ #hits HP!!!
           set %czas_hp #scnt + 1
           }
        if #charghost = yes
           halt
     until Wyleczyl in #sysmsg || palec in #sysmsg || Nie_udalo in #sysmsg || przestal in #sysmsg || Anulowano. in #sysmsg || Ta_osoba in #journal

  menu Set mtCzasLeczenie 0
  menu Set mtPoziomHP #HITS
return