MK64 Rom Patch

/*
MK64 ROM Patch 1.1 by abitalive

Includes the following codes:

All players can choose the same character
Anamorphic widescreen
Tempo fix
*/

.org 0x0029F0 // Disable cpu display function (RAM 0x80001DF0)
NOP

// Tempo fix
.org 0x002638 // Two player (RAM 0x80001A38)
ADDIU T1,R0,0x0002
NOP

.org 0x002890 // Three and four player (RAM 0x80001C90)
ADDIU T2,R0,0x0002
NOP

// Anamorphic widescreen
.org 0x10E07C // Hook #1 (RAM 0x802A4A6C)
JAL 0x80003FD4
NOP

.org 0x10F048 // Hook #2 (RAM 0x802A5A38)
JAL 0x80003FD4
NOP

.org 0x10F330 // Hook #3 (RAM 0x802A5D20)
JAL 0x80003FD4
NOP

.org 0x10F628 // Hook #4 (RAM 0x802A6018)
JAL 0x80003FD4
NOP

.org 0x10F93C // Hook #5 (RAM 0x802A632C)
JAL 0x80003FD4
NOP

.org 0x10FC50 // Hook #6 (RAM 0x802A6640)
JAL 0x80003FD4
NOP

.org 0x10FF54 // Hook #7 (RAM 0x802A6944)
JAL 0x80003FD4
NOP

.org 0x110238 // Hook #8 (RAM 0x802A6C28)
JAL 0x80003FD4
NOP

.org 0x11051C // Hook #9 (RAM 0x802A6F0C)
JAL 0x80003FD4
NOP

.org 0x11084C // Hook #10 (RAM 0x802A723C)
JAL 0x80003FD4
NOP

.org 0x004BD4 // Anamorphic widescreen function. Replaces cpu display function (RAM 0x80003FD4)
LUI T1,0x800E
LB T1,0xC53B(T1) // Check players
ORI T2,R0,0x0002
BEQ T1,T2,2_Players
NOP
1_3_4_Players:
LUI A3,0x3FDF
ORI A3,A3,0xAAAB // Return 3FDFAAAB
BEQ R0,R0,Anamorphic_Skip
NOP
2_Players:
LUI A3,0x4060
ORI A3,A3,0xAAAB // Return 4060AAAB
Anamorphic_Skip:
JR RA
NOP

// All players can choose the same character
.org 0x0B4524 // Move selector right (RAM 0x800B3924)
NOP

.org 0x0B45A4 // Move selector left (RAM 0x800B39A4)
NOP

.org 0x0B4638 // Move selector up/down hook (RAM 0x800B3A38)
J 0x80004008

.org 0x004C08 // Move selector up/down function. Replaces cpu display function (RAM 0x80004008)
LUI A0, 0x4900
BEQ V0,R0,Players_Skip
SB S0, 0x0000(T9)
JAL 0x800C8E10 // Play sound
ORI A0, A0, 0x8000 // Volume
Players_Skip:
J 0x800B3A50
NOP