[RO] KOE

-	script	KoE	-1,{
OnInit:
	disablenpc "The King#KoE";
	disablenpc "Exit#KoE";
	bindatcmd "koe", strnpcinfo(0)+"::Oncommand", 99,99;
	end;

Oncommand:
	if ( compare( .@atcmd_parameters$, "on" ) ) goto L_start;
	else if ( compare( .@atcmd_parameters$, "off" ) ) goto L_end;
	else {
		dispbottom "type - '@koe on' to start the event";
		dispbottom "type - '@koe off' to end the event";
	}
	end;

OnHour04:
L_start:
	gvgon "koe";
	announce "The King of Emperium Hill has begun!", bc_all;
	.start = 1;
	enablenpc "The King#KoE";
	disablenpc "Exit#KoE";
	$koegid = 0;
	donpcevent "::OnRevKoE";
	maprespawnguildid "koe", $koegid, 7;
	monster "koe",49,49,"EMPERIUM",1288,1,"KoE::OnEmpDead";
	end;

OnHour08:
L_end:
	gvgoff "koe";
	announce "The King of Emperium Hill is over!", bc_all;
	.start = 0;
	enablenpc "Exit#KoE";
	disablenpc "The King#KoE";
	killmonsterall "koe";
	// maprespawnguildid "koe", $koegid, 6;
	end;
OnEmpDead:
	$koegid = getcharid(2);
	announce "The current King of Emperium Hill is the ["+ strcharinfo(2) +"] guild.", bc_all;
	donpcevent "::OnRevKoE";
	maprespawnguildid "koe", $koegid, 6;
	sleep 500;
	if ( .start )
		monster "koe",49,49,"EMPERIUM",1288,1,"KoE::OnEmpDead";
	end;
}

// KoE Entrance
prontera,155,183,4	script	The King#KoE	487,{
	mes "[The King]";
	if ( !getcharid(2) ) {
		mes "You must have a guild to participate in the ^FF0000King of Emperium Hill Tournament^000000.";
		close;
	}
	mes "Hello.";
	mes "Would you like to participate in the ^FF0000King of Emperium Hill Tournament^000000?";
	if ( select ( "Yes", "No" ) == 2 ) close;
	switch( rand(1,4) ){
		case 1:    warp "guild_vs1", 50, 88; end;
		case 2:    warp "guild_vs1", 88, 50; end;
		case 3:    warp "guild_vs1", 50, 11; end;
		case 4:    warp "guild_vs1", 11, 50; end;
	}
	close;
}

// KoE Exit
koe,49,56,5	script	Exit#KoE	51,{
	mes "[Exit]";
	mes "See ya.";
	if ( getcharid(2) == $koegid )
		getitem 671, 2; // configure prize here
	close2;
	warp "Save",0,0;
	end;
}

// Flags
koe,49,38,4	script	King of Emperium Hill#1::koe_flag	722,{
	if ( !$koegid ) end;
	mes "[King of Emperium Hill]";
	mes "The Current King of Emperium Hill is the ["+ getguildname($koegid) +"] guild.";
	close;

OnRevKoE:
	flagemblem $koegid;
	end;
}
guild_vs1,61,49,6	duplicate(koe_flag)	King of Emperium Hill#2	722
guild_vs1,38,49,2	duplicate(koe_flag)	King of Emperium Hill#3	722
guild_vs1,49,61,0	duplicate(koe_flag)	King of Emperium Hill#4	722

koe	mapflag	nobranch
koe	mapflag	nomemo
koe	mapflag	nopenalty
koe	mapflag	noreturn
koe	mapflag	nosave    SavePoint
koe	mapflag	noteleport
koe	mapflag	gvg_noparty
koe	mapflag	nowarp
koe	mapflag	nowarpto
koe	mapflag	guildlock