In the top level directory create the file sort.vbs.  Add the text:
'=======================
set objFSO = CreateObject("Scripting.FileSystemObject")
set objFolder = objFSO.GetFolder(".")
set colSubfolders = objFolder.Subfolders

strStartChar = "("
strEndChar   = ")"

for each objSubfolder in colSubfolders
    strNameOfFolder = objSubfolder.Name

    if instr(strNameOfFolder, strStartChar) > 0 then

	    intStartCharacter = instr(strNameOfFolder,strStartChar) +1
	    intEndCharacter   = instr(strNameOfFolder,strEndChar)
	    intLength         = intEndCharacter - intStartCharacter
	    strNewFolderName  = mid(strNameOfFolder, intStartCharacter, intLength )

        wscript.echo "Processing: " & strNameOfFolder & ", extracted text for new folder: " & strNewFolderName

	    if not objFSO.FolderExists(strNewFolderName) then
		  objFSO.CreateFolder strNewFolderName
	    end if

	    if objFSO.FolderExists(strNewFolderName) then
		    set ExistingFolder = objFSO.GetFolder(strNameOfFolder)
		    objFSO.MoveFolder ExistingFolder.name, strNewFolderName & "\"
	    end if

    else
        wscript.echo strNameOfFolder & " not for processing.  No " & strStartChar & " character in directory."
    end if

next
'=======================

Then open a command prompt in the same directory.  You can run:
cscript.exe sort.vbs.

Here is an example folder tree before and after:

tree /f

│   sort.vbs
│
├───(01-15)Mom
├───(01-15)Son
│       New Bitmap Image.bmp
│
├───1(01-15)Brother
│       New Bitmap Image.bmp
│
├───a(a)test
│       New Bitmap Image.bmp
│
└───test(01-16)Dad
        New Bitmap Image (2).bmp
        New Bitmap Image.bmp


cscript sort.vbs

Processing: (01-15)Mom, extracted text for new folder: 01-15
Processing: (01-15)Son, extracted text for new folder: 01-15
Processing: 1(01-15)Brother, extracted text for new folder: 01-15
Processing: a(a)test, extracted text for new folder: a
Processing: test(01-16)Dad, extracted text for new folder: 01-16

Outcome:


│   sort.vbs
│
├───01-15
│   ├───(01-15)Mom
│   ├───(01-15)Son
│   │       New Bitmap Image.bmp
│   │
│   └───1(01-15)Brother
│           New Bitmap Image.bmp
│
├───01-16
│   └───test(01-16)Dad
│           New Bitmap Image (2).bmp
│           New Bitmap Image.bmp
│
└───a
    └───a(a)test
            New Bitmap Image.bmp

As you can see it takes the string between the ( and the ) to form the new directory and move the contents of the original directory to it.