SA-MP Teleportsystem v2

#include <a_samp>
#include <zcmd>

#define FILE_NAME "teleports.txt"

#define COLOR_GREEN 0x33AA33AA
#define COLOR_RED 0xAA3333AA

new Line[32][144];
new str[1024];

enum tp_Info
{
    Float:tp_x,
    Float:tp_y,
    Float:tp_z,
    tp_interior,
    tp_world,
    tp_name[32],
    bool:tp_created
}

new TP[32][tp_Info];

public OnFilterScriptInit()
{
    print("Teleport-Filterscript gestartet.");

    LoadTeleports();
    return 1;
}

/* Sonstige Funktionen */

stock SetFileLine(filename[],ln,text[])
{
    if(!fexist(filename)) return 0;

    new File:file = fopen(filename,io_read), lines;

    while(fread(file,Line[lines]))
    {
        lines ++;
    }

    fclose(file);

    if(!text[0])
    {
        Line[ln][0] = '\0';
    }
    else
    {
        format(Line[ln],144,text);
    }

    file = fopen(filename,io_write);

    for(new i=0;i<lines;i++)
    {
        if(Line[i][0] != '\0')
        {
            fwrite(file,Line[i]);
        }
        else
        {
            continue;
        }
    }

    fclose(file);
    return 1;
}

stock sscanf(string[], format[], {Float,_}:...)
{
    #if defined isnull
        if (isnull(string))
    #else
        if (string[0] == 0 || (string[0] == 1 && string[1] == 0))
    #endif
        {
            return format[0];
        }
    #pragma tabsize 4
    new
        formatPos = 0,
        stringPos = 0,
        paramPos = 2,
        paramCount = numargs(),
        delim = ' ';
    while (string[stringPos] && string[stringPos] <= ' ')
    {
        stringPos++;
    }
    while (paramPos < paramCount && string[stringPos])
    {
        switch (format[formatPos++])
        {
            case '\0':
            {
                return 0;
            }
            case 'i', 'd':
            {
                new
                    neg = 1,
                    num = 0,
                    ch = string[stringPos];
                if (ch == '-')
                {
                    neg = -1;
                    ch = string[++stringPos];
                }
                do
                {
                    stringPos++;
                    if ('0' <= ch <= '9')
                    {
                        num = (num * 10) + (ch - '0');
                    }
                    else
                    {
                        return -1;
                    }
                }
                while ((ch = string[stringPos]) > ' ' && ch != delim);
                setarg(paramPos, 0, num * neg);
            }
            case 'h', 'x':
            {
                new
                    num = 0,
                    ch = string[stringPos];
                do
                {
                    stringPos++;
                    switch (ch)
                    {
                        case 'x', 'X':
                        {
                            num = 0;
                            continue;
                        }
                        case '0' .. '9':
                        {
                            num = (num << 4) | (ch - '0');
                        }
                        case 'a' .. 'f':
                        {
                            num = (num << 4) | (ch - ('a' - 10));
                        }
                        case 'A' .. 'F':
                        {
                            num = (num << 4) | (ch - ('A' - 10));
                        }
                        default:
                        {
                            return -1;
                        }
                    }
                }
                while ((ch = string[stringPos]) > ' ' && ch != delim);
                setarg(paramPos, 0, num);
            }
            case 'c':
            {
                setarg(paramPos, 0, string[stringPos++]);
            }
            case 'f':
            {

                new changestr[16], changepos = 0, strpos = stringPos;
                while(changepos < 16 && string[strpos] && string[strpos] != delim)
                {
                    changestr[changepos++] = string[strpos++];
                    }
                changestr[changepos] = '\0';
                setarg(paramPos,0,_:floatstr(changestr));
            }
            case 'p':
            {
                delim = format[formatPos++];
                continue;
            }
            case '\'':
            {
                new
                    end = formatPos - 1,
                    ch;
                while ((ch = format[++end]) && ch != '\'') {}
                if (!ch)
                {
                    return -1;
                }
                format[end] = '\0';
                if ((ch = strfind(string, format[formatPos], false, stringPos)) == -1)
                {
                    if (format[end + 1])
                    {
                        return -1;
                    }
                    return 0;
                }
                format[end] = '\'';
                stringPos = ch + (end - formatPos);
                formatPos = end + 1;
            }
            case 'u':
            {
                new
                    end = stringPos - 1,
                    id = 0,
                    bool:num = true,
                    ch;
                while ((ch = string[++end]) && ch != delim)
                {
                    if (num)
                    {
                        if ('0' <= ch <= '9')
                        {
                            id = (id * 10) + (ch - '0');
                        }
                        else
                        {
                            num = false;
                        }
                    }
                }
                if (num && IsPlayerConnected(id))
                {
                    setarg(paramPos, 0, id);
                }
                else
                {
                    #if !defined foreach
                        #define foreach(%1,%2) for (new %2 = 0; %2 < MAX_PLAYERS; %2++) if (IsPlayerConnected(%2))
                        #define __SSCANF_FOREACH__
                    #endif
                    string[end] = '\0';
                    num = false;
                    new
                        name[MAX_PLAYER_NAME];
                    id = end - stringPos;
                    foreach (Player, playerid)
                    {
                        GetPlayerName(playerid, name, sizeof (name));
                        if (!strcmp(name, string[stringPos], true, id))
                        {
                            setarg(paramPos, 0, playerid);
                            num = true;
                            break;
                        }
                    }
                    if (!num)
                    {
                        setarg(paramPos, 0, INVALID_PLAYER_ID);
                    }
                    string[end] = ch;
                    #if defined __SSCANF_FOREACH__
                        #undef foreach
                        #undef __SSCANF_FOREACH__
                    #endif
                }
                stringPos = end;
            }
            case 's', 'z':
            {
                new
                    i = 0,
                    ch;
                if (format[formatPos])
                {
                    while ((ch = string[stringPos++]) && ch != delim)
                    {
                        setarg(paramPos, i++, ch);
                    }
                    if (!i)
                    {
                        return -1;
                    }
                }
                else
                {
                    while ((ch = string[stringPos++]))
                    {
                        setarg(paramPos, i++, ch);
                    }
                }
                stringPos--;
                setarg(paramPos, i, '\0');
            }
            default:
            {
                continue;
            }
        }
        while (string[stringPos] && string[stringPos] != delim && string[stringPos] > ' ')
        {
            stringPos++;
        }
        while (string[stringPos] && (string[stringPos] == delim || string[stringPos] <= ' '))
        {
            stringPos++;
        }
        paramPos++;
    }
    do
    {
        if ((delim = format[formatPos++]) > ' ')
        {
            if (delim == '\'')
            {
                while ((delim = format[formatPos++]) && delim != '\'') {}
            }
            else if (delim != 'z')
            {
                return delim;
            }
        }
    }
    while (delim > ' ');
    return 0;
}

/* Teleportfunktionen */

stock CreateTeleport(Float:x,Float:y,Float:z,interior,world,name[])
{
    new File:file = fopen(FILE_NAME,io_append);
    format(str,144,"%f|%f|%f|%d|%d|%s\r\n",x,y,z,interior,world,name);
    fwrite(file,str);
    fclose(file);
    LoadTeleports();
    return 1;
}

stock LoadTeleports()
{
    if(!fexist(FILE_NAME)) return 0;

    new File:file = fopen(FILE_NAME,io_read), index;

    while(fread(file,str))
    {
        sscanf(str,"p|fffdds",TP[index][tp_x],TP[index][tp_y],TP[index][tp_z],TP[index][tp_interior],TP[index][tp_world],TP[index][tp_name]);
        TP[index][tp_created] = true;
        index ++;
    }

    if(index < 32)
    {
        for(new i=index;i<32;i++)
        {
            TP[i][tp_created] = false;
        }
    }

    fclose(file);
    printf("%d Teleport(s) geladen.",index);
    return index;
}

stock DeleteTeleport(id)
{
    if(TP[id][tp_created] == false) return 0;

    SetFileLine(FILE_NAME,id,"");
    LoadTeleports();
    return 1;
}

/* Befehle */

COMMAND:teleports(playerid,params[])
{
    if(!IsPlayerAdmin(playerid)) return SendClientMessage(playerid,COLOR_RED,"Du bist kein RCON-Admin!");

    ShowPlayerDialog(playerid,1336,DIALOG_STYLE_LIST,"Teleportverwaltung","{33AA33}Teleports anzeigen\n{33AA33}Teleports löschen\n{33AA33}Teleports erstellen","Okay!","Abbrechen");
    return 1;
}

/* Callbacks */

public OnDialogResponse(playerid, dialogid, response, listitem, inputtext[])
{
    if(response)
    {
        switch(dialogid)
        {
            case 1336:
            {
                switch(listitem)
                {
                    case 0:
                    {
                        if(LoadTeleports() == 0) return SendClientMessage(playerid,COLOR_RED,"Bisher wurden keine Teleports erstellt!");

                        for(new i=0;i<32;i++)
                        {
                            if(TP[i][tp_created] == true)
                            {
                                format(str,1024,"%s\n{33AA33}%s",str,TP[i][tp_name]);
                            }
                        }

                        ShowPlayerDialog(playerid,1337,DIALOG_STYLE_LIST,"Teleports",str,"Los!","Zurück");
                    }
                    case 1:
                    {
                        if(LoadTeleports() == 0) return SendClientMessage(playerid,COLOR_RED,"Bisher wurden keine Teleports erstellt!");

                        for(new i=0;i<32;i++)
                        {
                            if(TP[i][tp_created] == true)
                            {
                                format(str,1024,"%s\n{33AA33}%s",str,TP[i][tp_name]);
                            }
                        }

                        ShowPlayerDialog(playerid,1338,DIALOG_STYLE_LIST,"Teleports löschen",str,"Löschen!","Zurück");
                    }
                    case 2:
                    {
                        ShowPlayerDialog(playerid,1339,DIALOG_STYLE_INPUT,"Teleports erstellen","Gib einen Namen für diesen Ort ein:","Erstellen!","Zurück");
                    }
                }
            }
            case 1337:
            {
                SetPlayerPos(playerid,TP[listitem][tp_x],TP[listitem][tp_y],TP[listitem][tp_z]);
                SetPlayerInterior(playerid,TP[listitem][tp_interior]);
                SetPlayerVirtualWorld(playerid,TP[listitem][tp_world]);
                format(str,144,"Du hast dich zum Teleport \"%s\" teleportiert.",TP[listitem][tp_name]);
                SendClientMessage(playerid,COLOR_GREEN,str);
            }
            case 1338:
            {
                format(str,144,"Teleport \"%s\" gelöscht.",TP[listitem][tp_name]);
                SendClientMessage(playerid,COLOR_GREEN,str);
                DeleteTeleport(listitem);
            }
            case 1339:
            {
                if(!inputtext[0]) return SendClientMessage(playerid,COLOR_RED,"Du musst einen Namen eingeben!");
                if(strlen(inputtext) > 32) return SendClientMessage(playerid,COLOR_RED,"Der Name darf nicht mehr als 32 Zeichen lang sein!");

                new Float:x, Float:y, Float:z;
                GetPlayerPos(playerid,x,y,z);
                CreateTeleport(x,y,z,GetPlayerInterior(playerid),GetPlayerVirtualWorld(playerid),inputtext);
                format(str,144,"Teleport \"%s\" erstellt. Tippe /teleports um die Teleportverwaltung aufzurufen.",inputtext);
                SendClientMessage(playerid,COLOR_GREEN,str);
            }
        }
    }
    else if(!response)
    {
        if(dialogid == 1337 || dialogid == 1338 || dialogid == 1339)
        {
            ShowPlayerDialog(playerid,1336,DIALOG_STYLE_LIST,"Teleportverwaltung","{33AA33}Teleports anzeigen\n{33AA33}Teleports löschen\n{33AA33}Teleports erstellen","Okay!","Abbrechen");
        }
    }
    return 1;
}