weaponHudInit()
{
    level.weaponicon = [];
	// precache
	precacheShader("hud_us_grenade");
	precacheShader("hud_us_semtex");
	precacheShader("hud_icon_claymore");
	precacheShader("hud_icon_c4");
	precacheShader("weapon_attachment_tactical");
	// equipment
	level.weaponicon["frag"] = "hud_us_grenade";
	level.weaponicon["semtex"] = "hud_us_semtex";
	level.weaponicon["claymore"] = "hud_icon_claymore";
	level.weaponicon["c4"] = "hud_icon_c4";
	level.weaponicon["throwingknife"] = "weapon_attachment_tactical";
}

getWeaponIcon(name)
{
	base = strtok(name , "_")[0];
	ret = level.weaponicon[base];
	if(!isDefined(ret))
		return "None";
	return ret;
}

AmmoHud()
{
	self endon("disconnect");
	self endon("death");
	if(!isDefined(self.ammoBoard))
	{
		self.ammoBoard = self createFontString( "default", 1.7 );
		self.ammoBoard setPoint( "BOTTOMRIGHT", "BOTTOMRIGHT", -55, -40);
		self.ammoBoard.HideWhenInMenu = true;
	}
	if(!isDefined(self.stockBoard))
	{
		self.stockBoard = self createFontString( "default", 2 );
		self.stockBoard setPoint( "BOTTOMRIGHT", "BOTTOMRIGHT", -18, -40);
		self.stockBoard.HideWhenInMenu = true;
	}
	if(!isDefined(self.slash))
	{
		self.slash = self createFontString( "default", 1.9 );
		self.slash setPoint( "BOTTOMRIGHT", "BOTTOMRIGHT", -45, -40);
		self.slash.HideWhenInMenu = true;
	}

	if(!isDefined(self.nadeseperator))
	{
		self.nadeseperator = self createFontString( "default", 1.9 );
		self.nadeseperator setPoint( "BOTTOMRIGHT", "BOTTOMRIGHT", -43, -60);
		self.nadeseperator.HideWhenInMenu = true;
		self.nadeseperator.sort = -9999999;
	}
	if(!isDefined(self.equipmentcount))
	{
		self.equipmentcount = self createFontString( "default" , 1.9);
		self.equipmentcount setPoint( "BOTTOMRIGHT", "BOTTOMRIGHT", -30, -60);
		self.equipmentcount.HideWhenInMenu = true;
		self.equipmentcount.sort = -9999999;
	}

	// do every time you spawn to make sure it resets
	self.nadeicon destroy();
	self.grenade = level.nadetypes[self.nadetype];
	self.nadeicon = self createIcon(getWeaponIcon(self.grenade), 16, 16);
	self.nadeicon setPoint("BOTTOMRIGHT", "BOTTOMRIGHT", -55, -60);
	self.nadeicon.alpha = 1;
	self.nadeicon.sort = -9999999;
	self.nadeicon.HideWhenInMenu = true;
	lastequipment = self.grenade;

	while(1)
	{
		self.grenade = level.nadetypes[self.nadetype];
		if(self.team == "axis")
		{
			self.grenade = "throwingknife_mp";
			self.nades = 0;
		}
		self.Clip = self getWeaponAmmoClip(self getCurrentWeapon());
		self.Stock = self getWeaponAmmoStock(self getCurrentWeapon());
		if(self.Stock >= 100)
		{
			self.stockBoard.fontscale = 1.7;
		}
		else
		{
			self.stockBoard.fontscale = 2;
		}
		self.ammoBoard setValue(self.Clip);
		self.stockBoard setValue(self.Stock);
		//self.slash setText("/");
		self.nadeseperator setText("x\n/");

		nadeclip = self getWeaponAmmoClip(self.grenade);
		if(!isDefined(self.nades))
			self.equipmentcount setValue(0);
		else if (!isDefined(nadeclip))
			self.equipmentcount setValue(self.nades);
		else
			self.equipmentcount setValue(self.nades + nadeclip);

		if(lastequipment != self.grenade)
		{
			self.nadeicon destroy();
			self.nadeicon = self createIcon(getWeaponIcon(self.grenade), 16, 16);
			self.nadeicon setPoint("BOTTOMRIGHT", "BOTTOMRIGHT", -55, -60);
			self.nadeicon.alpha = 1;
			self.nadeicon.sort = -9999999;
			self.nadeicon.HideWhenInMenu = true;
		}

		wait 0.1;
	}
}