Gallerie

@ECHO OFF
setlocal enableDelayedExpansion
COLOR 1F
TITLE ScriptGallery LightBox
SET nospan=
SET span=^<span^>^<br /^>DATE^</span^>

:BEGIN
cls
ECHO [Quel action effectuer]
ECHO       0. Quitter
ECHO       1. Galerie avec Cover (une seule image affichee)
ECHO       2. Galerie sans Cover (miniatures, span)
ECHO       3. Galerie avec Cover (une seule image affichee, no-span et Titre)
ECHO.
ECHO.
SET /p action="     > Tapez le chiffre de l'action a effectuer : "
GOTO %action%

:3
SET type=3
SET nospan=-nospan
SET span=
GOTO next

:1
SET type=1
:next
SET /p dossier1="          > Entrez le nom du Dossier de la section (ex: Activites) : "
SET output="../%dossier1%/!type!/%%A/script.js"
SET code_html="../%dossier1%/!type!/code_html.txt"
>%code_html% (
   ECHO Introduisez ces lignes de code dans votre page HTML : &ECHO. &ECHO.
)
FOR /F "delims=" %%A IN ('DIR /B /A:D "..\%dossier1%\!type!\"') DO (
   SET /a flag=0
   (
      ECHO document^.write^(^"^\
   )>%output%
   (
      ECHO ^<div class^=\"cadre!nospan!\" style^=\"background-image: url('%dossier1%/!type!/%%A/cover.jpg');\"^>\
   )>>%output%
   SET /a count1=1
   FOR /F "delims=" %%B IN ('DIR /B "..\%dossier1%\!type!\%%A\img\*.jpg"') DO (
      IF EXIST "..\%dossier1%\!type!\%%A\meta.txt" (
         FOR /F "delims=," %%x in ('type "..\%dossier1%\!type!\%%A\meta.txt"') do set TITRE=%%x
      ) ELSE (
         SET TITRE=
      )
      SET /a count1=!count1!+1
      IF EXIST "..\%dossier1%\!type!\%%A\img\meta.txt" (
         SET /a count2=1
         FOR /F "delims=" %%y in ('type "..\%dossier1%\!type!\%%A\img\meta.txt"') do (
            SET /a count2=!count2!+1
            IF !count1!==!count2! (
               SET NOM=%%y
            )
         )
      ) ELSE (
         SET NOM=
      )
      IF NOT %%B==cover.jpg (
         IF !flag!==0 (
            (
               ECHO ^<a class^=\"galerie\" href^=\"%dossier1%/!type!/%%A/img/%%B\" data-lightbox^=\"%%A\" data-title^=\"!NOM!\"^>^<h6^>!TITRE!!span!^</h6^>^</a^>\
            )>>%output%
            SET /a flag=1
         ) ELSE (
            (
               ECHO ^<a class^=\"galerie\" href^=\"%dossier1%/!type!/%%A/img/%%B\" data-lightbox^=\"%%A\" data-title^=\"!NOM!\"^>^</a^>\
            )>>%output%
         )
      )
   )
   (
      ECHO ^<script type^="text/javascript" src="%dossier1%/!type!/%%A/script.js"^>^</script^>
   )>> %code_html%
   (
      ECHO ^</div^>\
      ECHO ^"^)
   )>>%output%
)
ECHO.
ECHO                           [ Operation terminee ]
ECHO                      Pressez une touche pour continuer
PAUSE>NUL
GOTO BEGIN

:2
SET /p dossier="          > Entrez le nom du Dossier contenant la galerie d'image (ex: montagne) : "
SET output="../%dossier%/2/%%A/script.js"
SET code_html="../%dossier%/2/code_html.txt"
(
   ECHO Introduisez ces lignes de code dans votre page HTML :
   ECHO.
   ECHO.
   ECHO ^<div class^="img"^>
)>%code_html%
FOR /F "delims=" %%A IN ('DIR /B /A:D "..\%dossier%\2\"') DO (
    (
      ECHO document^.write^(^"^\
   )>%output%
    FOR /F "delims=." %%B IN ('DIR /B "..\%dossier%\2\%%A\img\*.jpg"') DO (
      (
         ECHO ^<a class^=\"gallerie\" href^=\"%dossier%/2/%%A/img/%%B.jpg\" data-lightbox^=\"%%A\" data-title^=\"\"^>^<img src^=\"%dossier%/2/%%A/mini/%%B.jpg\" alt^=\"\"/^>^</a^>\
      )>>%output%
    )
    (
      ECHO ^"^)
   )>>%output%
   (
      ECHO    ^<p^>
      ECHO       ^<h2^>%%A^</h2^>
      ECHO       ^<script type^="text/javascript" src="%dossier%/2/%%A/script.js"^>^</script^>
      ECHO    ^</p^>^<br /^>
   )>>%code_html%
)
(
   ECHO ^</div^>
)>>%code_html%
ECHO.
ECHO                    [ Operation terminee ]
ECHO               Pressez une touche pour continuer
PAUSE>NUL
GOTO BEGIN

:0
EXIT