mkvtoolnix-PKGBUILD

# $Id: PKGBUILD 246729 2015-09-20 07:01:02Z giovanni $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: xduugu <xduugu@gmx.com>

pkgbase=mkvtoolnix
pkgname=('mkvtoolnix-cli' 'mkvtoolnix-qt')
pkgver=8.4.0
pkgrel=2
arch=('i686' 'x86_64')
license=('GPL')
url="http://www.bunkus.org/videotools/mkvtoolnix/index.html"
makedepends=('libmatroska' 'flac' 'libvorbis' 'file' 'qt5-base'
             'boost-libs' 'lzo' 'xdg-utils' 'boost' 'ruby')
source=("http://www.bunkus.org/videotools/${pkgbase}/sources/${pkgbase}-${pkgver}.tar.xz")
md5sums=('773eb42b7887bd20c4ce65cdf667976b')

prepare() {
  cd "${srcdir}/${pkgbase}-${pkgver}"

  # Disable automagic curl dep used for online update checking
  #sed -i -e '/curl/d' configure.in
  export CURL_CFLAGS="" CURL_LIBS=""

  # Sets number of threads for a parallel build
  export DRAKETHREADS=`nproc`

  autoreconf -vfi
}

build() {
  cd "${srcdir}/${pkgbase}-${pkgver}"

  ./configure --prefix=/usr --without-curl --disable-gui
  ./drake apps:mkvinfo

  mv src/mkvinfo{,-cli}

  ./configure --prefix=/usr --without-curl

  ./drake

  mv src/mkvinfo{,-qt}
  mv src/mkvinfo{-cli,}
}

package_mkvtoolnix-cli() {
  pkgdesc="Set of tools to create, edit and inspect Matroska files - CLI version"
  depends=('libmatroska' 'expat' 'flac' 'libvorbis' 'file' 'boost-libs' 'lzo')
  provides=('mkvtoolnix')
  conflicts=('mkvtoolnix')
  replaces=('mkvtoolnix')

  cd "${srcdir}/${pkgbase}-${pkgver}"

  ./drake DESTDIR="${pkgdir}" install

  cd "${pkgdir}"

  find usr/share/man -name 'mkvtoolnix-gui.1*' -delete
  rm -f usr/bin/mkvtoolnix-gui
  rm -rf usr/share/applications
  rm -rf usr/share/icons
  rm -rf usr/share/mime
}

package_mkvtoolnix-qt() {
  pkgdesc="Set of tools to create, edit and inspect Matroska files - Qt GUI"
  depends=("mkvtoolnix-cli=${pkgver}" 'qt5-base' 'xdg-utils' 'desktop-file-utils')
  replaces=('mkvtoolnix-gtk')
  install=mkvtoolnix.install

  cd "${srcdir}/${pkgbase}-${pkgver}"

  ./drake DESTDIR="${pkgdir}" install
  install -Dm755 src/mkvinfo-qt "${pkgdir}"/usr/bin/

  cd "${pkgdir}"

  sed -i "s/Exec=mkvinfo/Exec=mkvinfo-qt/" usr/share/applications/mkvinfo.desktop

  rm -f usr/bin/mkv{extract,info,merge,propedit}
  rm -rf usr/share/locale
  find usr/share/man -name 'mkvextract.1*' -delete
  find usr/share/man -name 'mkvinfo.1*' -delete
  find usr/share/man -name 'mkvmerge.1*' -delete
  find usr/share/man -name 'mkvpropedit.1*' -delete
}