Ragnarok Online Smart Cast - Source

; Language:       Autohotkey
; Name:     Ragnarok Online Smart Cast
; Description:  Smart cast for any games really, but this script was specifically made for Ragnarok Online
; Author:         Recca
; READ ME - https://autohotkey.com/boards/viewtopic.php?f=19&t=13162
; BLOG - http://ragindex.blogspot.com
/* ------------------------------ROSC.ini----------------------------- READ ME
120         // SPEED        : Skill Delay (in millisecond)
100         // SPEED        : Usable Delay (in millisecond)
!p          // Alt + P      ; Pause Script Hotkey
!Esc            // Alt + Esc        ; Exit Hotkey
            //  "//" = comment start
            // Empty lines will be ignore
//s         // Put '//' infront to disable a hotkey
z           // Hotkey Z, Use Z and CLick
a,u         // Hotkey A, Use A ; ",u" for usable, for Spamming pots without click
            // Anything behind '//' will be ignore
            // NEED TO RESTART FOR CHANGE TO TAKE EFFECT

//F1=F1,170,u|F2,170,u|F1,170,u|F3,250,u    //Working Asura Combo
// DO NOT OVERLAP HOTKEYS, OR ELSE... idk
// F1 - F9 Macro
F1
F2
F3
F4
F5
F6
F7
F8
F9
*/
; Nam: Ragnarok Onlin Smart Cast ( Self-Cast / Macro / Chain Macro )
; AutoHotkey Version:  Autohotkey_L
; Platform:       Windows Only
; Author:        Recca
; Description: A self-cast script for Ragnarok Online
; /camera to turn off CAMERA SMOOTH for more accurate Self-Cast
; See "HTTP://RAGINDEX.BLOGSPOT.COM" for more information

#NoEnv
SendMode Input
SetWorkingDir %A_ScriptDir%
#Persistent
#SingleInstance force
;SetBatchLines -1
if not A_IsAdmin
{
   Run *RunAs "%A_ScriptFullPath%"  ; Requires v1.0.92.01+
   ExitApp
}

configName = ROSC.ini

IfNotExist, %configName%
{
    MsgBox There is no '%configName%' within this folder, app will exit now.
    ExitApp
}
ToolTip, SPAM ON
Sleep 1000
x := 0
x1 := 0
s := 0
Loop, read, %configName%
{
    IfInString, A_Loopreadline, //
    {
        StringSplit, fix_, A_Loopreadline, //
        fix := fix_1
        StringReplace, fix, fix, %A_Tab%,,all
        StringReplace, fix, fix, %A_Space%,,all
    }
    else
    {
        fix := A_LoopReadLine
        StringReplace, fix, fix, %A_Tab%,,all
        StringReplace, fix, fix, %A_Space%,,all
    }
    if fix =
        continue
    if A_Index = 1
    {
        lagrate = %fix%
        continue
    }
    if A_Index = 2
    {
        lagrate1 = %fix%
        continue
    }
    if A_Index = 3
    {
        Hotkey, %fix%, Suspend1
        continue
    }
    if A_Index = 4
    {
        Hotkey, %fix%, Exit1
        continue
    }
    IfInString, fix, =
    {
        StringSplit, Hotk_, fix, =
        %Hotk_1%sequence = %Hotk_2%
        Hotkey, %Hotk_1%, sequenceStart
        Hotkey, %Hotk_1% Up, sequenceStop
    }
    else  IfInString, fix, ,u
    {
        StringTrimRight, nowHotk, fix, 2
        Hotkey, %nowHotk%, start1
        Hotkey, %nowHotk% Up, stop1
    }
    else
    {
        Hotkey, %fix%, start
        Hotkey, %fix% Up, stop
    }
}
ToolTip
return

sequenceStart:
StringSplit, sequence_, %A_ThisHotkey%sequence, |
s := 1
while s = 1
{
    Loop %sequence_0%
    {
        temp := sequence_%A_Index%
                StringSplit, temp_, temp, `,
                if temp_0 = 3
                {
                    Send {%temp_1%}
                    Sleep %temp_2%
                }
                else
                {
                    Send {%temp_1%}
                    Sleep %temp_2%
                    Send {LButton Down}
                    Sleep 55
                    Send {Lbutton Up}
                    Sleep %temp_2%
                }
    }
        if s = 0
            break
}
return

sequenceStop:
s := 0
return

start:
x := 1
while x = 1
{
    Send {%A_ThisHotkey%}
    Sleep %lagrate%
    Click
    Sleep %lagrate%
    If x = 0
        Break
}
return

stop:
x := 0
return

start1:
x1 := 1
while x1 = 1
{
    Send {%A_ThisHotkey%}
    Sleep %lagrate1%
    If x1 = 0
        Break
}
return

stop1:
x1 := 0
return

Exit1:
ExitApp
return

Suspend1:
Suspend
toggle := !toggle
if toggle = 1
{
ToolTip, SCRIPT PAUSED
Sleep 1000
ToolTip
}
else
{
ToolTip, SCRIPT STARTED
Sleep 1000
ToolTip
}
return