MIDI Sans Frontieres - Deerful

//MIDI SANS FRONTIERES
//DEERFUL / EMMA WINSTON
//5 JULY 2016

//turn reverb on
r = {Out.ar([0,1], FreeVerb.ar(In.ar(1, 2), mix: 1, room: 2, mul: 0.2))}.play;


//add all these synthdefs before you begin
(
 SynthDef.new("sinesynth", { arg freq, amp=0.07, filter=2000, pan=1, out=1;
	//env = Env.linen(0, 0.9, 0).kr(doneAction: 2);
	var sig1 = SinOsc.ar(freq*[0.999,1.01], 0.05);
	var sig2 = SinOsc.ar(freq*3,0.05);
	Out.ar(out, Pan2.ar(LPF.ar((sig1)+(sig2), filter,0.5, 0.05), pan))
}, [0.1, 0.4]
).add;
)

(

 SynthDef.new("sawsynth", { arg freq, amp=0.2, filter=2000, pan=1, out=1;
	//env = Env.linen(0, 0.9, 0).kr(doneAction: 2);
	var sig1 = LFSaw.ar(freq*[0.999,1.01], amp/2);
	var sig2 = LFSaw.ar(freq*3,amp/2) + Saw.ar(freq*9,amp/4);
    Out.ar(out, Pan2.ar(RLPF.ar((sig1)+(sig2), filter,0.5, 0.2), pan))
}, [0.1, 0.4]
).add;
)

(
SynthDef("trisynth", { arg freq, amp=0.2, filter=5000, pan=0, out=1;
	var sig1 = LFTri.ar(freq*[0.999,1.01],0.5,amp);
	var sig2 = LFTri.ar(freq*4,amp/2) + LFTri.ar(freq*2,amp/4);
	Out.ar(out, Pan2.ar(LPF.ar((sig1)+(sig2), filter,0.5, 0.2), pan))
}, [0.1, 0.4]
).add;
)

(
SynthDef("squaresynth", { arg freq, amp=0.2, filter=2000, pan=0, out=1;
	var sig1 = LFPulse.ar(freq*[0.999,1.01],0.5,amp);
	var sig2 = LFPulse.ar(freq*4,amp/2) + Pulse.ar(freq*2,amp/4);
	Out.ar(out, Pan2.ar(LPF.ar((sig1)+(sig2), filter,0.5, 0.2), pan))
}, [0.1, 0.4]
).add;
)


// below here is the stuff you need to do live

~picksynth = ["sinesynth", "squaresynth", "trisynth", "sawsynth"];


//background ring - start first one at beginning, then start the other two when it feels right
{ Ringz.ar([WhiteNoise.ar(0.005),WhiteNoise.ar(0.005)], 440, 4) }.play();
{ Ringz.ar([WhiteNoise.ar(0.005),WhiteNoise.ar(0.005)], 298, 4) }.play();
{ Ringz.ar([WhiteNoise.ar(0.005),WhiteNoise.ar(0.005)], 590, 4) }.play();

(
~mel1 = Pmono(
	"sinesynth",
	\degree, Pseq([-1, 1, 4, 3.1, -2, -5, 1, -3, 1, 2], 8),
	\octave, Pseq([4, 5, 5, 5, 5, 4, 5, 4, 4, 4], 8),
	\dur, Pseq([1.5, 1.5, 1, 1.5, 2.5, 1.5, 2.5, 1.5, 2.5, 0], 8),
	\tempo, 100/60
).play(quant: 4);
)

(
~mel1a = Pmono(
	~picksynth.choose,
	\degree, Pseq([-1, 1, 4, 3.1, -2, -5, 1, -3, 1, 2], 4),
	\octave, Pseq([4, 5, 5, 5, 5, 4, 5, 4, 4, 4], 4),
	\dur, Pseq([1.5, 1.5, 1, 1.5, 2.5, 1.5, 2.5, 1.5, 2.5, 0], 4),
	\tempo, 100/60
).play(quant: 1);
)

(
~mel2 = Pmono(
	~picksynth.choose,
	\degree, Pseq([1, -2, 4, 3.1, 0.1, 1, -1, 1, -2, 1], 4),
	\octave, Pseq([4, 5, 6, 6, 6, 6, 5, 6, 5, 6], 4),
	\dur, Pseq([1.5, 1.5, 1, 1.5, 1.5, 1, 1.5, 2.5, 1.5, 2.5], 4),
	\tempo, 100/60
).play(quant: 1);
)

(
~mel3 = Pmono(
	~picksynth.choose,
	\degree, Pseq([-5, -2, 4, 3.1, 0.1, 1, -1, 1, -3, 1], 4),
	\octave, Pseq([4, 5, 6, 6, 6, 6, 5, 6, 5, 5], 4),
	\dur, Pseq([1.5, 1.5, 1, 1.5, 1.5, 1, 1.5, 2.5, 1.5, 2.5], 4),
	\tempo, 100/60
).play(quant: 1);
)


// melody goes up

(
~mel4 = Pmono(
	~picksynth.choose,
	\degree, Pseq([1, -2, 4, 3.1, 7.1, 8, -3, 1, -2, 1], 4),
	\octave, Pseq([4, 5, 6, 6, 6, 6, 5, 6, 5, 6], 4),
	\dur, Pseq([1.5, 1.5, 1, 1.5, 1.5, 1, 1.5, 2.5, 1.5, 2.5], 4),
	\tempo, 100/60
).play(quant: 4);
)

// highest melody

(
~mel5 = Pmono(
	~picksynth.choose,
	\degree, Pseq([2, 2, 3.1, 5, 4, 1, 2, -2, -1, -3], 4),
	\octave, Pseq([4, 6, 5, 5, 6, 6, 5, 6, 5, 6], 4),
	\dur, 1.5,
	\tempo, 100/60
).play(quant: 4); //live-change quant number to smaller number to build piece
)


//second part
(
~mel6 = Pmono(
	~picksynth.choose,
	\degree, Pseq([3.1, 5, 2, 3.1, 5, 4, 3.1, 2, 6, 5, 3.1], 2),
	\octave, Pseq([5,   4, 5, 4,   3, 4, 4,   5, 4, 4, 4], 2),
	\dur, 4,
	\tempo, 100/60
).play(quant: 4); //live-change quant number to smaller number to build piece
)

//bass
(
~mel7 = Pmono(
	~picksynth.choose,
	\degree, Pseq([4, 1, \rest, 4, 3.1, 6, \rest, 2, 4, 1, \rest, 6, 5, 2, \rest], 1),
	\octave, 2,
	\dur, 4,
	\tempo, 100/60
).play(quant: 4); //live-change quant number to smaller number to build piece
)