Spawn No SF

{$CLEO}
IF 8AA2: NOT {SAMPBASE}0@ = load_library "SAMP.DLL"
THEN 0A93:
END
0AA3: free_library 0@ {Желательно выгрузить ранее загруженную библиотеку}
0001: WAIT 5000 MS {Ждём 5 секунд, чтобы структуры SA:MP'а прогрузились}
0AB1: _call_scm_func @SAMP_Get__stSAMP params 1 | {SAMPBASE}0@ | {stSAMP}1@ | {Получаем структуру: stSAMP}
0AB1: _call_scm_func @SAMP_Get__stSAMPPools params 1 | {stSAMP}1@ | {stSAMPPools}1@ | {Получаем структуру: stSAMPPools}
0AB1: _call_scm_func @SAMP_Get__stPlayerPool params 1 | {stSAMPPools}1@ | {stPlayerPool}1@ | {Получаем структуру: stPlayerPool}
0AB1: _call_scm_func @SAMP_Get__stLocalPlayer params 1 | {stPlayerPool}1@ | {stLocalPlayer}1@ | {Получаем структуру: stLocalPlayer}


WHILE TRUE
0001: WAIT 0 MS

    IF 0AB0:   key__pressed {VK_F2}0x71
    THEN
        REPEAT
        0001: WAIT 0 MS
        UNTIL 8AB0:   NOT key__pressed {VK_F2}0x71
    0AB1: _call_scm_func @SAMP_REQUESTSpawn params 2 | {SAMPBASE}0@ {stLocalPlayer}1@ || // 0BD0: samp send_request_spawn
    0AB1: _call_scm_func @SAMP_Spawn params 2 | {SAMPBASE}0@ {stLocalPlayer}1@ || // 0AF6: samp spawn_player
    0ACD: show_text_highpriority "~G~Spawned~S~~N~NO SAMPFuncs :)" time 1000
    END

END

:SAMP_Get__stSAMP
000A: {SAMPBASE}0@ += {SAMP_INFO_OFFSET}0x21A0F8 {Смещение на SAMP_INFO_OFFSET}
0A8D: {stSAMP}0@ = read_memory 0@ size {Pointer}4 virtual_protect TRUE {При считывание смещения на SAMP_INFO_OFFSET получаем структуру: stSAMP}
0AB2: RET 1 | {stSAMP}0@ |

:SAMP_Get__stSAMPPools
000A: {stSAMP}0@ += {pPools}0x3CD {Смещение на pPools}
0A8D: {stSAMPPools}0@ = read_memory 0@ size {Pointer}4 virtual_protect TRUE {При считывание смещения на pPools получаем структуру: stSAMPPools}
0AB2: RET 1 | {stSAMPPools}0@ |

:SAMP_Get__stPlayerPool
000A: {stSAMPPools}0@ += {pPlayer}0x18 {Смещение на pPlayer}
0A8D: {stPlayerPool}0@ = read_memory 0@ size {Pointer}4 virtual_protect TRUE {При считывание смещения на pPlayer получаем структуру: stPlayerPool}
0AB2: RET 1 | {stPlayerPool}0@ |

:SAMP_Get__stLocalPlayer
000A: {stPlayerPool}0@ += {pLocalPlayer}0x22 {Смещение на pLocalPlayer}
0A8D: {stLocalPlayer}0@ = read_memory 0@ size {Pointer}4 virtual_protect TRUE {При считывание смещения на pLocalPlayer получаем структуру: stLocalPlayer}
0AB2: RET 1 | {stLocalPlayer}0@ |

:SAMP_REQUESTSpawn
000A: {SAMPBASE}0@ += {SAMP_FUNC_REQUEST_SPAWN}0x3EC0 {Смещение на SAMP_FUNC_REQUEST_SPAWN}
0AA6: call_method {SAMP_FUNC_REQUEST_SPAWN}0@ struct {stLocalPlayer}1@ num_params 0 pop 0 || {Вызываем SAMP_FUNC_REQUEST_SPAWN}
0AB2: RET 0 ||

:SAMP_Spawn
000A: {SAMPBASE}0@ += {SAMP_FUNC_SPAWN}0x3AD0 {Смещение на SAMP_FUNC_SPAWN}
0AA6: call_method {SAMP_FUNC_SPAWN}0@ struct {stLocalPlayer}1@ num_params 0 pop 0 || {Вызываем SAMP_FUNC_SPAWN}
0AB2: RET 0 ||