Bank System v2

#include <a_samp>
#include <zcmd>
#include <foreach>
#include <YSI/y_ini>

/*      Šo filterskriptu veidoja Eliots[ADT] --- [eliotsrp@inbox.lv]   */

/* CHANGELOG
- Skripta relīze [22.09.2011]
- Skripts pārveidots, lai saglabā naudu uz y_ini. [25.05.2011] */

#define PATH "banka/%s.ini"

//Krāsas
#define     peleeks         0xAFAFAFAA

//Dialogi
#define     DIALOG_BANK     (155)
#define     DIALOG_BALANCE  (255)
#define     DIALOG_WITHDRAW (355)
#define     DIALOG_DEPOSIT  (455)

//Forward's
forward GameTextEntrance();
forward LoadBank_data(playerid, name[], value[]);

//Variables
new entrance;

enum pBank
{
    pBankAccount,
};
new bankVariables[MAX_PLAYERS][pBank];
//==============================================================================
stock BankPath(playerid)
{
    new string[50];
    format(string, sizeof string, PATH, GetName(playerid));
    return string;
}

stock GetName(playerid)
{
    new name[24];
    GetPlayerName(playerid, name, sizeof name);
    return name;
}

public LoadBank_data(playerid, name[], value[])
{
    INI_Int("BankMoney", bankVariables[playerid][pBankAccount]);
    return 1;
}

public OnFilterScriptInit()
{
    print("[BANKA] Bankas sistēma ielādēta veiksmīgi...");
    entrance = SetTimer("GameTextEntrance", 500, 1);

    //Ikonas
    AddStaticPickup(1239, 1, 2303.1074,-15.8666,26.4844); //Bankas ieeja
    AddStaticPickup(1239, 1, 2316.3748,-15.5229,26.7422); //Punkts, kur lietot /bank cmd
    return 1;
}

public OnFilterScriptExit()
{
    KillTimer(entrance);
    return 1;
}

public OnPlayerConnect(playerid)
{
    if(fexist(BankPath(playerid)))
    {
        INI_ParseFile(BankPath(playerid), "LoadBank_%s", .bExtra = true, .extra = playerid);
    }
    else
    {
        new INI:file = INI_Open(BankPath(playerid));
        INI_WriteInt(file, "BankMoney", 0);
        INI_Close(file);
        INI_ParseFile(BankPath(playerid), "LoadBank_%s", .bExtra = true, .extra = playerid);
    }
    return 1;
}

public OnPlayerDisconnect(playerid, reason)
{
    if(fexist(BankPath(playerid)))
    {
        new INI:file = INI_Open(BankPath(playerid));
        INI_WriteInt(file, "BankMoney", bankVariables[playerid][pBankAccount]);
        INI_Close(file);
    }
    return 1;
}

public OnDialogResponse(playerid, dialogid, response, listitem, inputtext[])
{
    new string[128];
    if(dialogid == DIALOG_BANK) {
        if(response) {
            if(listitem==0){
                ShowPlayerDialog(playerid, DIALOG_DEPOSIT, DIALOG_STYLE_INPUT, "Naudas noguldījums", "Ievadiet naudas summu, kuru vēlaties noguldīt.", "Apstiprināt", "Atpakaļ"); }
            else if(listitem==1){
                ShowPlayerDialog(playerid, DIALOG_WITHDRAW, DIALOG_STYLE_INPUT, "Naudas izņemšana", "Ievadiet naudas summu, kuru vēlaties izņemt.", "Apstiprināt", "Atpakaļ"); }
            else if(listitem==2){
                format(string, sizeof(string), "Bankas konta atlikums.\n{ADFF2F}Summa: {FFFFFF}$%d", bankVariables[playerid][pBankAccount]);
                ShowPlayerDialog(playerid, DIALOG_BALANCE, DIALOG_STYLE_MSGBOX, "Konta atlikums", string, "Atpakaļ", ""); }
        }
        return 1;
    }
    if(dialogid==DIALOG_DEPOSIT) {
        if(response) {
            if(strval(inputtext) <= GetPlayerMoney(playerid) && strval(inputtext) > 0) {
                new money = strval(inputtext);
                GivePlayerMoney(playerid, -money);
                bankVariables[playerid][pBankAccount] += money;
            }
            else return ShowPlayerDialog(playerid, DIALOG_DEPOSIT, DIALOG_STYLE_INPUT, "Naudas noguldījums", "Jums nav tik daudz naudas, ko vēlējāties noguldīt.\nIevadiet naudas summu, kuru vēlaties noguldīt.", "Apstiprināt", "Atpakaļ");
        }
        else return ShowPlayerDialog(playerid, DIALOG_BANK, DIALOG_STYLE_LIST, "Bankas izvēlne", "Noguldīt naudu\nIzņemt naudu\nApskatīt atlikumu","Apstiprināt", "Aizvērt");
        return 1;
    }
    if(dialogid==DIALOG_WITHDRAW) {
        if(response) {
            if(strval(inputtext) <= bankVariables[playerid][pBankAccount] && strval(inputtext) > 0){
                new money = strval(inputtext);
                GivePlayerMoney(playerid, money);
                bankVariables[playerid][pBankAccount] -= money;
            }
            else return ShowPlayerDialog(playerid, DIALOG_WITHDRAW, DIALOG_STYLE_INPUT, "Naudas izņemšana", "Jums nav tik daudz naudas uz bankas konta.\nIevadiet naudas summu, kuru vēlaties izņemt.", "Apstiprināt", "Atpakaļ");
        }
        else return ShowPlayerDialog(playerid, DIALOG_BANK, DIALOG_STYLE_LIST, "Bankas izvēlne", "Noguldīt naudu\nIzņemt naudu\nApskatīt atlikumu","Apstiprināt", "Aizvērt");
        return 1;
    }
    if(dialogid==DIALOG_BALANCE) {
        if(response) return ShowPlayerDialog(playerid, DIALOG_BANK, DIALOG_STYLE_LIST, "Bankas izvēlne", "Noguldīt naudu\nIzņemt naudu\nApskatīt atlikumu","Apstiprināt", "Aizvērt");
    }
    return 0;
}

public OnPlayerKeyStateChange(playerid, newkeys, oldkeys)
{
    if(newkeys == KEY_SECONDARY_ATTACK)
    {
        if(IsPlayerInRangeOfPoint(playerid, 1.0, 2303.1074,-15.8666,26.4844) && GetPlayerState(playerid) != (PLAYER_STATE_DRIVER))
        { //Bankas ieeja
            SetPlayerPos(playerid, 2307.9714,-15.4138,26.7496);
            SetPlayerFacingAngle(playerid, 268.0418);
            SetPlayerInterior(playerid, 0);
            GameTextForPlayer(playerid, "~w~Laipni lugts~n~~g~banka!", 3000, 3);
        }
        else if(IsPlayerInRangeOfPoint(playerid, 1.0, 2305.2314,-16.0962,26.7422) && GetPlayerState(playerid) != (PLAYER_STATE_DRIVER))
        { //Bankas izeja
            SetPlayerPos(playerid, 2300.6660,-15.6993,26.4844);
            SetPlayerFacingAngle(playerid, 88.4721);
            SetPlayerInterior(playerid, 0);
        }
        return 1;
    }
    return 0;
}

public GameTextEntrance()
{
    foreach(Player, i)
    {
        if(IsPlayerInRangeOfPoint(i, 1.0, 2303.1074,-15.8666,26.4844))
        {//Bankas ieeja
            GameTextForPlayer(i,"~n~~n~~n~~n~~n~~n~~n~~n~~n~~n~~g~Stata banka~n~~w~Spied ~r~F,~w~ lai ieietu",2000,3);
        }
        else if(IsPlayerInRangeOfPoint(i, 1.0, 2305.2314,-16.0962,26.7422))
        {//Bankas izeja
            GameTextForPlayer(i,"~n~~n~~n~~n~~n~~n~~n~~n~~n~~n~~n~~w~Spied ~r~F,~w~ lai izietu",2000,3);
        }
    }
    return 1;
}

//======================[Komandas]==============================================
COMMAND:bank(playerid, params[])
{
    if(IsPlayerInRangeOfPoint(playerid, 2.0, 2316.3748,-15.5229,26.7422))
    {
        ShowPlayerDialog(playerid, DIALOG_BANK, DIALOG_STYLE_LIST, "Bankas izvēlne", "Noguldīt naudu\nIzņemt naudu\nApskatīt atlikumu","Apstiprināt", "Aizvērt");
    }
    else return SendClientMessage(playerid, peleeks, "KĻŪDA: Tu neatrodies bankā!");
    return 1;
}