Happy Hour EXP

/*
        Happy Hour EXP

    Idea:
        Nokia: http://rathena.org/board/topic/57978-happy-hour-exp-event-timer/

    Ver: 26.01.2012 ( with %% )

    By:
        Lilith

    Contacts:
        Gmail: [email protected]
        ICQ: 450327002
*/
prontera,150,180,5  script  Happy Hour EXP  100,{
mes "[Happy Hour EXP]";
if(getgmlevel()>=.Access){
mes "Hello! What would you like to do?";
    switch(select("Start the Floating Rates:Nothing")){
        case 1:
            mes " ";
            if(.Event == 1) { mes "Event already started"; close; }
            mes "Cerrent Base Rate: "+getbattleflag("base_exp_rate")/100;
            mes "How much % you'd like to increase Base Rates?";
            input .@BaseExp;
            next;
            mes "[Happy Hour EXP]";
            mes "Cerrent Job Rate: "+getbattleflag("job_exp_rate")/100;
            mes "How much % you'd like to increase Job Rates?";
            input .@JobExp;
            next;
            mes "[Happy Hour EXP]";
            mes "New rates:";
            mes "Base: "+((getbattleflag("base_exp_rate") / 100 *.@BaseExp + getbattleflag("base_exp_rate"))/100);
            mes "Job: "+((getbattleflag("job_exp_rate") / 100 * .@JobExp + getbattleflag("job_exp_rate"))/100);
            switch(select("Start:Close")){
                case 1:
                    setbattleflag "base_exp_rate",getbattleflag("base_exp_rate") / 100 *.@BaseExp + getbattleflag("base_exp_rate");
                    setbattleflag "job_exp_rate",getbattleflag("job_exp_rate") / 100 * .@JobExp + getbattleflag("job_exp_rate");
                    initnpctimer;
                    set .Event,1;
                    mes "Event started";
                    announce "Happy Hour EXP: Floating rates event started. New rates: Base - "+(getbattleflag("base_exp_rate")/100)+"x, Job - "+(getbattleflag("job_exp_rate")/100)+"x",0;
                    close;
                break;

                default:
                    close;
            }
        break;

        default:
            close;
    }
} else {
    mes "You aren't a GM.";
    close;
}
end;

OnTimer3600000: // After 1 hour
set .Event,0;
setbattleflag "base_exp_rate",.DefaultBaseRates;
setbattleflag "job_exp_rate",.DefaultJobRates;
announce "Happy Hour EXP: The floating rates event have been ended. Rates back to the normal.",0;
end;

OnInit:
set .DefaultBaseRates,getbattleflag("base_exp_rate");
set .DefaultJobRates,getbattleflag("job_exp_rate");
set .Access,80; // GM access lvl
end;
}