[delphi-en] Convert stl of name/value pairs to JSON array.

program Project3;

{$APPTYPE CONSOLE}

uses
  SysUtils, DBXJson, Classes;

function GetJSonObjectFor(stl : TStringList) : TJsonObject;
// Caller is responsible for freeing the returned object!
var RootJsonObj, PairsJsonObj : TJsonObject;
    AJsonArray : TJsonArray;
    AJsonPair : TJsonPair;
    i : Integer;
begin
  AJsonArray := TJsonArray.Create();
  RootJsonObj := TJsonObject.Create(TJSONPair.Create('Array', AJsonArray));

  for i := 0 to stl.Count-1 do
  begin
    PairsJsonObj := TJsonObject.Create();
    PairsJsonObj.AddPair(TJsonPair.Create('ID', stl.Names[i] ));
    PairsJsonObj.AddPair(TJsonPair.Create('Status', stl.ValueFromIndex[i]));
    AJsonArray.AddElement(PairsJsonObj);
  end;

  result := RootJsonObj
end;

var
  Sourcedata : TStringList;
  AJsonObj : TJsonObject;

begin
  try
    SourceData := nil;
    AJsonObj := nil;
    try
      SourceData := TStringList.Create;
      SourceData.Values['14'] := 'AOK';
      SourceData.Values['15'] := 'Bad';
      SourceData.Values['16'] := 'AOK';

      AJsonObj := GetJSonObjectFor(SourceData);

      writeln(AJsonObj.ToString);
      readln;
    finally
      SourceData.Free;
      AJsonObj.Free;
    end;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.