# Maintainer: Alex Forencich <alex@alexforencich.com>

pkgname=linux-gpib
pkgver=3.2.21
pkgrel=1
pkgdesc="Linux GPIB support"
arch=('i686' 'x86_64')
license=('GPL')
url="http://linux-gpib.sourceforge.net/"
depends=('bash' 'linux>=3.0')
makedepends=('linux-headers' 'automake' 'autoconf' 'libtool')
options=()
optdepends=('gpib-firmware: firmware for USB GPIB cables')
source=(http://downloads.sourceforge.net/project/${pkgname}/linux-gpib%20for%203.x.x%20and%202.6.x%20kernels/${pkgver}/${pkgname}-${pkgver}.tar.gz
    'gpib_build.patch'
    'gpib.rules')
install='linux-gpib.install'
md5sums=('91e15d1a30c6e3fd79fc6762e8c1120e'
         'c2cd38e8179f8fdf8ac9157b2ef18f98'
         '3d09fb5b7975cd8c22edce80b30ea821')

_kernver=$(uname -r)
_extramodules=/usr/lib/modules/extramodules-${_kernver%.*}-${_kernver##*[0-9]-}/

build() {
   cd "${srcdir}/${pkgname}-${pkgver}"

   patch -Np0 -i "${srcdir}/../gpib_build.patch" || return 1

   ./bootstrap
   ./configure \
      --prefix=/usr \
      --sbindir=/usr/bin
   make || return 1
}

package() {
   cd "${srcdir}/${pkgname}-${pkgver}"

   make INSTALL_MOD_PATH="${pkgdir}/usr" DESTDIR="${pkgdir}" install

   mkdir -p ${pkgdir}/${_extramodules}
   mv ${pkgdir}/usr/lib/modules/${_kernver}/gpib ${pkgdir}/${_extramodules}/

   find ${pkgdir} -depth -type d -empty -exec rmdir {} \;

   mkdir -p ${pkgdir}/etc/udev/rules.d/
   cp ${srcdir}/gpib.rules ${pkgdir}/etc/udev/rules.d/30-gpib.rules
}