CMD:addfcar(playerid, params[])
{
    new frakID, vehmodel, Float:x, Float:y, Float:z, Float:a, preis, neon, color1, color2, string[128];
    if(Spieler[playerid][pAdmin] < 6)return SendClientMessage(playerid, COLOR_GREY, ERROR_ADMIN);
    if(sscanf(params, "iiii", frakID, vehmodel, preis, neon))return SendClientMessage(playerid, COLOR_GREY, "**  Benutze: /addfcar [Fraktions-ID] [Vehicle-Model] [Preis] [Neon]");
    if(vehmodel < 400 || vehmodel > 611)return SendClientMessage(playerid, COLOR_GREY, "** Vehicle-Model muss über 400 und unter 611 sein!");
    if(GetMaxFraktionsVehs(frakID) > MAX_OWNED_FRAKVEHICLES)return SendClientMessage(playerid, COLOR_GREY, "** Maximale Anzahl an Fraktionsfahrzeugen erreicht!");
    if(frakID < 1 || frakID > MAX_FRAKS)return SendClientMessage(playerid, COLOR_GREY, "** Falsche Fraktions-ID!");
    GetPlayerPos(playerid, x, y, z);
    GetPlayerFacingAngle(playerid, a);
    color1 = GetFrakColor1(frakID);
    color2 = GetFrakColor2(frakID);
    CreateFraktionsVehicle(frakID, vehmodel, x, y, z, a, preis, neon, color1, color2);
    format(string, sizeof(string), "* %s %s hat ein Fraktionsfahrzeug (%d) für Fraktion %s erstellt.", GetPlayerAdminName(playerid), GetName(playerid), vehmodel, GetFraktionName(frakID));
    SendAdminMessage(COLOR_AM, string);
    return 1;
}

stock CreateFraktionsVehicle(frakID, vehmodel, Float:posx, Float:posy, Float:posz, Float:posa, preis, neon, color1, color2)
{
    new Query[512];
    for(new fV;fV<MAX_FVEHS;fV++)
    {
        if(fVehicle[fV][modelid] == 0)
        {
            fVehicle[fV][vehFraktion] = frakID;
            fVehicle[fV][modelid] = vehmodel;
            fVehicle[fV][vehPosX] = posx;
            fVehicle[fV][vehPosY] = posy;
            fVehicle[fV][vehPosZ] = posz;
            fVehicle[fV][vehPosA] = posa;
            fVehicle[fV][vehInterior] = 0;
            fVehicle[fV][vehWorld] = 0;
            fVehicle[fV][vehColor1] = color1;
            fVehicle[fV][vehColor2] = color2;
            fVehicle[fV][vehPaintjob] = -1;
            fVehicle[fV][vehSpoiler] = 0;
            fVehicle[fV][vehHood] = 0;
            fVehicle[fV][vehRoof] = 0;
            fVehicle[fV][vehSideskirt] = 0;
            fVehicle[fV][vehLamps] = 0;
            fVehicle[fV][vehNitro] = 0;
            fVehicle[fV][vehExhaust] = 0;
            fVehicle[fV][vehWheels] = 0;
            fVehicle[fV][vehStereo] = 0;
            fVehicle[fV][vehHydraulics] = 0;
            fVehicle[fV][vehFrontBumper] = 0;
            fVehicle[fV][vehRearBumper] = 0;
            fVehicle[fV][vehVentRight] = 0;
            fVehicle[fV][vehVentLeft] = 0;
            fVehicle[fV][vehPreis] = preis;
            fVehicle[fV][vehHealth] = 1000.0;
            fVehicle[fV][vehNeonID] = neon;
            fVehicle[fV][vehTankKM] = 0;
            fVehicle[fV][vehKMStandCount] = 0;
            fVehicle[fV][vehKMStand] = 0;
            fVehicle[fV][vehID] = CreateVehicleEx(fVehicle[fV][modelid], fVehicle[fV][vehPosX], fVehicle[fV][vehPosY], fVehicle[fV][vehPosZ], fVehicle[fV][vehPosA], fVehicle[fV][vehColor1], fVehicle[fV][vehColor2], -1, false);
            format(fVehicle[fV][vehNumberPlate], 32, "{B22222}%s %d", GetFraktionNumberPlate(fVehicle[fV][vehFraktion]), fVehicle[fV][vehID]);
            SetVehicleNumberPlate(fVehicle[fV][vehID], fVehicle[fV][vehNumberPlate]);
            SetVehicleHealth(fVehicle[fV][vehID], fVehicle[fV][vehHealth]);
            mysql_format(myCon, Query, sizeof(Query), "INSERT INTO `script_fvehicles` (`vehFraktion`, `modelid`, `vehPosX`, `vehPosY`, `vehPosZ`, `vehPosA`, `vehInterior`, `vehWorld`, `vehHealth`, `vehNumberPlate`, `vehPaintjob`, `vehPreis`, `vehColor1`, `vehColor2`, `vehNeonID`, `vehFuel`) VALUES ('%d', '%d', '%f', '%f', '%f', '%f', '%d', '%d', '%f', '%s', '%d', '%d', '%d', '%d', '%d', '%d')",
            fVehicle[fV][vehFraktion], fVehicle[fV][modelid], fVehicle[fV][vehPosX], fVehicle[fV][vehPosY], fVehicle[fV][vehPosZ], fVehicle[fV][vehPosA], fVehicle[fV][vehInterior], fVehicle[fV][vehWorld], fVehicle[fV][vehHealth], fVehicle[fV][vehNumberPlate], fVehicle[fV][vehPaintjob], fVehicle[fV][vehPreis], fVehicle[fV][vehColor1], fVehicle[fV][vehColor2], fVehicle[fV][vehNeonID], VehicleData[vehmodel-400][vehMaxTank]);
            mysql_tquery(myCon, Query, "insertDB", "d", fV);
            SetVehicleToRespawn(fVehicle[fV][vehID]);
            Vehicle[fVehicle[fV][vehID]][vehFuel] = VehicleData[vehmodel-400][vehMaxTank];
            singleSaveFVehicle(fV);
            return 1;
        }
    }
    return 1;
}