;------------------------------------------------------
;  Price lookup script via www.cardhoarder.com
;  Usage /price card name
;  or !price card name
;  Includes 3 second flood spam protection
;-----------------------------------------------------

alias noHTML return $regsubex($1, /<[^>]+(?:>|$)|^[^<>]+>/g, $null)


on *:text:!price*:#: {
  if ($1 == !price) {
    if ((%floodprice) || ($($+(%,floodprice.,$nick),2))) { return }
    set -u3 %floodprice On
    set -u6 %floodprice. $+ $nick On
    set %channel #
    $iif($2,price $2-,msg # Specify a card to look up)
  }
}

alias price {
  sockclose price
  unset %price.*
  set %price.card $replace($1-,$chr(32),$chr(43))
  set %price.Pricecounter 0
  set %price.Setcounter 0
  sockopen price cardhoarder.com 80
}

on *:SOCKOPEN:price:{
  if $sockerr { return }
  sockwrite -n $sockname GET /cards?data[search]= $+ %price.card HTTP/1.1
  sockwrite -n $sockname Host: www.cardhoarder.com
  sockwrite -n $sockname $crlf
}

on *:SOCKREAD:price:{
  if $sockerr { return }
  var %data
  sockread %data
  if (<strong><a href isin %data) { set %price.settarget 1 }
  if (%price.settarget == 1) { inc %price.setcounter }
  if (%price.setcounter == 3) && (!%price.set) { set %price.set %data }
  if (add-to-cart btn btn isin %data) { set %price.pricetarget 1 }
  if (%price.pricetarget == 1 ) { inc %price.pricecounter }
  if (%price.pricecounter == 6) {
    tokenize 32 %data
    if (%price.foundprice) { return }
    else set %price.foundprice $1
    if ($noHTML(%price.set) == promotional) || ($noHTML(%price.set) == Jace vs. Chandra) {
      unset %price.set
      unset %price.foundprice
      unset %price.pricetarget
      unset %price.settarget
      set %price.setcounter 0
      set %price.pricecounter 0
      return
    }
    else set %price.link http://www.cardhoarder.com/cards?data $+ $chr(37) $+ 5Bsearch $+ $chr(37) $+ 5D $+ $chr(61) $+ %price.card
    msg %channel $uppercase($replace(%price.card,$chr(43),$chr(32))) - $noHTML(%price.set) - %price.foundprice TIX - %price.link
    sockclose price
  }
  elseif (No cards were found for your query. isin %data) {
    msg %channel No card found
    sockclose price
  }

}

;------------------------------------------------------
;  Automatic capitalization
;-----------------------------------------------------

alias uppercase {

  var %i = 1
  while (%i <= $numtok($1-,32)) {
    if ($gettok($1-,%i,32) == of) || ($gettok($1-,%i,32) == the) || ($gettok($1-,%i,32) == and) || ($gettok($1-,%i,32) == from) || ($gettok($1-,%i,32) == in) || ($gettok($1-,%i,32) == under) && (%i != 1) {
      var %blah = $instok(%blah,$gettok($1-,%i,32),%i,32)
      inc %i
    }
    else {
      var %done = $+($upper($left($gettok($1-,%i,32),1)),$mid($gettok($1-,%i,32),2))
      var %blah = $instok(%blah,%done,%i,32)
      inc %i
    }
  }
  return %blah
}