#include "Zen_FrameworkFunctions\Zen_InitHeader.sqf"

// <Redacted> by Zenophon
// Version = 5/25/14
// Tested with ArmA 3 1.18

#define AI_SKILL "infantry"
#define HELI_HEIGHT 300

#define SET_CHANCE(X) if (random 1 > 0.5) then { \
    X = true; \
} else { \
    X = false; \
}; \

#define ADD_DESTROY_NEAR_EH(X) X addEventHandler ["handleDamage", {{_x setDamage 1;} forEach (nearestObjects [getPosATL (_this select 0), [], 15]); (_this select 0) removeAllEventHandlers "handleDamage";}]; \

titleText [format["Aboard a UH-80\nAltitude: %1m\nInbound for parachute insertion", HELI_HEIGHT], "BLACK FADED", 0.25];
enableSaving [false, false];

player createDiaryRecord ["Diary", ["Execution", "You will insert at low altitude by parachute south of Selakano.  This area in marked in blue on the map.<br/><br/>Optionally, move to Junction 1 on foot and plant a satchel charge there.  No patrols are expected in that rural area.<br/><br/>Recon Selakano in force, eliminating any Opfor silently.  Make contact with any resistance fighters if possible.<br/><br/>Recon the airfield and secure the Mi-48.  It is lightly guarded, but make sure you take out its pilots.<br/><br/>Optionally, plant a satchel charge on the pump at the gas station.<br/><br/>Give Echo the go-code to assault Feres.  This action will be available when you clear Selakano completely.  You can assist Echo and sweep Feres yourself.<br/><br/>Steal the Mi-48 itself.  The pilot has been trained to fly it, so you will be the gunner.  Order the pilot to fly the helicopter, and use its cannon and missiles to destroy both junctions and any Opfor you find.<br/><br/>The pilot will land the Mi-48 near extraction once you are done.  Plant another satchel charge on the Mi-48 itself, then extract by submarine at the small beach."]];
player createDiaryRecord ["Diary", ["Mission", "Your primary objective is simple: destroy two power line junctions that lead from the turbine generators to the main power lines leading north.  Unfortunately, it is not matter of just walking up to them and planting explosives.  In order to have any chance of a safe infiltration and escape, you need to clear the two towns in the south of the AO, Feres and Selakano.  UAV intel and resistance communications indicate a small Opfor presence in Feres; nothing that Echo can't handle.  We're not too sure about Selakano though, as most of the town was destroyed by artillery fire.  You need to recon Selakano once you get on the ground.  There might be resistance or Opfor there; even both if the resistance is disguised as civilians.  Panagia to the north is an entirely different story.  There are at least several Opfor squads and MRAP's in Panagia itself, and it is backed up by armor and a mechanized infantry platoon to the north.<br/><br/>Resistance reports have confirmed an excellent opportunity.  A lightly guarded Opfor Mi-48 Kajman is being stationed at the small airfield between Feres and Selakano.  This is were the pilot comes in: you need to steal that Mi-48 and use it against the Opfor.  With the element of surprise and its massive firepower, you can decimate the garrison at Panagia and any reinforcements.  The power line junctions will also be easy to destroy from the air.  Once you are finished with the Mi-48, you will land and sabotage it, then proceed to extraction.<br/><br/>You also have some secondary objects to deal with.  First, you can destroy the first junction, west of Selakano using a satchel charge before or after you secure Selakano and Feres; this will help us keep the initiative when you steal the Mi-48.  Second, destroy the gas station south of the airfield.  It is a minor target, but the more chaos the better.  Third, you can assist Echo in their assault on Feres.  A search of the town may yield some extra chances for intel or sabotage.  Finally, you can use the Mi-48 to destroy the Opfor at Panagia itself.  This will cripple their response even more and help Echo escape."]];
player createDiaryRecord ["Diary", ["Forces", "Your part of the operation will be conducted by two teams.  Your team, lieutenant, will consist of only one more man, a pilot loaned to us from 160th SOAR.  We'll go over why you need a pilot soon; however, your main role is recon and protecting the pilot.  Your callsign is Sierra, and, as the senior officer on the ground, you will be in direct contact with HQ for your part of the operation.<br/><br/>The other team, callsign Echo, is one our assault teams; they will be assisting you in dealing with infantry threats in the AO.  They will be acting at their own discretion for most of the operation, until you give them the order to assault.  We will go over the details and go-codes later."]];
player createDiaryRecord ["Diary", ["Situation", "<Redacted>"]];

if (!isServer) exitWith {};

{_x setMarkerAlpha 0;} forEach ["mkReinfSpawn", "mkJ1Patrol", "mkAirFieldPatrol", "mkFieldPatrol"];
private ["_resistanceGroup", "_ammoBox", "_officerGroup", "_selakanoOpfor", "_selakanoResistance", "_feresStash", "_feresOfficer"];

Event_Arguments_Array = [];
Event_Queue_Array = [["f_EventAction_PilotDead", false]];

f_HandleEventQueue = {
    while {true} do {
        sleep 5;
        {
            if (_x select 1) then {
                _eventName = (_x select 0);
                _qualifier = [_eventName, "@$"] call Zen_StringGetDelimitedPart;
                _functionName = _eventName;
                if (count toArray _qualifier > 0) then {
                    _functionName = [_eventName, "@" + _qualifier + "$", ""] call Zen_StringFindReplace;
                };

                _argsIndex = [Event_Arguments_Array, _eventName, 0] call Zen_ArrayGetNestedIndex;
                _args = (Event_Arguments_Array select _argsIndex) select 1;
                0 = _args spawn (missionNamespace getVariable _functionName);
                0 = [Event_Arguments_Array, _argsIndex] call Zen_ArrayRemoveIndex;
                Event_Queue_Array set [_forEachIndex, 0];
            };
        } forEach Event_Queue_Array;
        Event_Queue_Array = Event_Queue_Array - [0];
    };
};

f_EventTrigger_Generic = {
    _nestedArray = [Event_Queue_Array, _this, 0] call Zen_ArrayGetNestedValue;
    if (count _nestedArray > 0) then {
        _nestedArray set [1, true];
    };
};

f_RemoveEvent = {
    {
        _index = [_x, _this, 0] call Zen_ArrayGetNestedIndex;
        if (_index != -1) then {
            0 = [_x, _index] call Zen_ArrayRemoveIndex;
        };
    } forEach [Event_Arguments_Array, Event_Queue_Array];
};

f_EventIsQueued = {
    (([Event_Queue_Array, _this, 0] call Zen_ArrayGetNestedIndex) > -1)
};

// params: "task"
f_EventTrigger_PilotDead = {
    waitUntil {
        sleep 10;
        !(alive pilot)
    };

    if (alive X) then {
        0 = [Event_Arguments_Array, ["f_EventAction_PilotDead", _this]] call Zen_ArrayAppend;
        0 = "f_EventAction_PilotDead" call f_EventTrigger_Generic;
    };
};

// params: addAction args
f_EventTrigger_Action = {
    0 = [Event_Arguments_Array, ["f_EventAction_Action", _this]] call Zen_ArrayAppend;
    0 = [Event_Queue_Array, ["f_EventAction_Action", true]] call Zen_ArrayAppend;
};

// params: addAction args, (3) == ["task", "message"]
f_EventAction_Action = {
    (_this select 0) removeAction (_this select 2);
    hint ((_this select 3) select 1);
    0 = [((_this select 3) select 0), "succeeded"] call Zen_UpdateTask;
};

// params: "task"
f_EventAction_PilotDead = {
    0 = [_this, "failed"] call Zen_UpdateTask;
    sleep 5;
    0 = "endLose" call BIS_fnc_EndMission;
};

f_EventAction_SpawnFeres = {
    _feresGarrison = [];
    for "_i" from 1 to (round (2 + random 1)) do {
        _spawnPos = ["mkFeres", 0, [], 1, [1, 100]] call Zen_FindGroundPosition;
        _opforGroup = [_spawnPos, east, AI_SKILL, [2, 4]] call Zen_SpawnInfantry;
        0 = [_opforGroup] call Zen_GiveLoadoutOpfor;
        0 = [_feresGarrison, _opforGroup] call Zen_ArrayAppend;
    };

    0 = [_feresGarrison, "mkFeres"] spawn Zen_OrderInfantryPatrol;
};

f_EventAction_SpawnPanagai = {
    _panagiaInfantry = [];
    for "_i" from 1 to 3 do {
        _spawnPos = ["mkPanagia", 0, [], 1, [1, 100]] call Zen_FindGroundPosition;
        _opforGroup = [_spawnPos, east, AI_SKILL, [4, 8]] call Zen_SpawnInfantry;
        0 = [_opforGroup] call Zen_GiveLoadoutOpfor;
        0 = [_panagiaInfantry, _opforGroup] call Zen_ArrayAppend;
    };

    for "_i" from 1 to 2 do {
        _spawnPos = ["mkPanagia", 0, [], 1, [1, 100]] call Zen_FindGroundPosition;
        _opforCar = [_spawnPos, ["o_mrap_02_f", "o_mrap_02_gmg_f", "o_mrap_02_hmg_f"]] call Zen_SpawnGroundVehicle;
    };

    0 = [_panagiaInfantry, "mkPanagia"] spawn Zen_OrderInfantryPatrol;
};

f_EventAction_SpawnReinf = {
    _stopReinf = [X, "The Opfor have mobilized heavy armor and mechanized infantry to respond to your attack.  Cripple and destroy as many vehicles as possible.", "Stop Reinforcements", "mkReinfRoute", false, "", "Task_Stop_Reinf"] call Zen_InvokeTask;

    _spawnPos = ["mkReinfSpawn", 0, [], 1, [1, 200]] call Zen_FindGroundPosition;
    _tank = [_spawnPos, "O_MBT_02_cannon_F"] call Zen_SpawnGroundVehicle;
    _reinfVehs = [_tank];

    for "_i" from 1 to 2 do {
        _spawnPos = ["mkReinfSpawn", 0, [], 1, [1, 200]] call Zen_FindGroundPosition;
        _opforApc = [_spawnPos, ["O_APC_Tracked_02_cannon_F", "O_APC_Wheeled_02_rcws_F"]] call Zen_SpawnGroundVehicle;
        _opforGroup = [_spawnPos, east, AI_SKILL, [5,7]] call Zen_SpawnInfantry;

        0 = [_reinfVehs, _opforApc] call Zen_ArrayAppendNested;

        0 = [_opforGroup, _opforApc] call Zen_MoveInVehicle;
        0 = [_opforApc, "mkFeres", _opforGroup] spawn Zen_OrderInsertion;
    };

    0 = [_tank, "mkFeres"] spawn Zen_OrderVehicleMove;
    0 = [_reinfVehs, _stopReinf, "succeeded"] spawn Zen_TriggerAreDead;
};

// ["selakanoTask", "feresTask", "stealTask"] // "pass" == not clear
f_EventAction_StoleMI_48 = {
    0 = [(_this select 2), "succeeded"] call Zen_UpdateTask;

    if (((_this select 1) == "pass") || {!([(_this select 0), (_this select 1)] call Zen_AreTasksComplete)}) then {
        0 = "f_EventAction_SpawnReinf" call f_EventTrigger_Generic;

        [west, "HQ"] sideChat "Sierra, HQ, Opfor in Feres are alerted to the Mi-48 taking off.";
        sleep 10;
        [west, "HQ"] sideChat "Once they figure out that their boys aren't piloting it, Opfor heavy armor is going to show up, over.";
        sleep 14;
        X sideChat "HQ, Sierra, roger that, we'll be ready for them, out."; \
        sleep 6;
    };
};

f_AssaultFeres = {
    (_this select 0) removeAction (_this select 2);
    _echo = group Y;
    _assaultPos = [(getMarkerPos "mkFeres"), [400, 500], [], 1, 0, [135, 160]] call Zen_FindGroundPosition;
    0 = [_echo, _assaultPos] call Zen_MoveAsSet;
    0 = [_echo, "mkFeres", [], 0, "full"] spawn Zen_OrderInfantryPatrol;

    X sideChat "Echo, Sierra, begin your assault now, over.";
    sleep 7;
    (leader _echo) sideChat "Sierra, Echo, wilco, out.";
};

// Debug
f_KillOpforFeres = {
    {
      _x setDamage 1;
    } forEach (["mkFeres", [], east] call Zen_GetAllInArea);
};

_idArray = [];
_cfgIds = configFile >> "CfgIdentities";
for "_i" from 0 to ((count _cfgIds) - 1) do {
    _configPath = _cfgIds select _i;
    _identity = configName _configPath;
    _name = getText (_configPath >> "name");
    _nameSound = getText (_configPath >> "nameSound");
    if ((_name == _nameSound) && !(_identity in _idArray)) then {
        _idArray set [(count _idArray), _identity];
    };
};

_idArray = [_idArray] call Zen_ArrayRemoveDuplicates;
_idArray = [_idArray] call Zen_ArraySortRandom;

{
    _name = _idArray select _forEachIndex;
    _x setIdentity _name;
} forEach ([pilot] + units group Y);

_gasStation = ([0,0,0] nearestObject 417717);
_J1Obj = ([0,0,0] nearestObject 1603022);
_J2Obj = ([0,0,0] nearestObject 1603184);

sleep 1;

MI_48 lock 3;
MI_48 addAction ["Get in Mi-48 as gunner", {(_this select 1) action ["GetInGunner", (_this select 0)];}, 0, 2, false, true, "", "!(_this in _target) && {(_target distance _this) < 9}"];

SET_CHANCE(_selakanoOpfor)
SET_CHANCE(_selakanoResistance)
SET_CHANCE(_feresStash)
SET_CHANCE(_feresOfficer)

#include "Loadouts.sqf"

_groupPlayer = group X;
_groupEcho = group Y;

_groupPlayer setGroupID ["Sierra"];
_groupEcho setGroupID ["Echo"];

0 = [["date", random 60, 21 + random 3], ["fog", 0.3 + random 0.4, 0.1, 60*30], ["overcast", random 0.3, random 1, 60*70]] spawn Zen_SetWeather;

_heliSpawn = [getMarkerPos "mkInsertion", [2000, 2500], [], 0, 0, [135, 225]] call Zen_FindGroundPosition;
_insertionHeli = [_heliSpawn, "b_heli_transport_01_f", HELI_HEIGHT] call Zen_SpawnHelicopter;
0 = [_groupPlayer, _insertionHeli] call Zen_MoveInVehicle;

_insertionHeli lock 2;

0 = [X] call Zen_AddRepackMagazines;
0 = [X] call Zen_AddGiveMagazine;
0 = [[_groupPlayer, _groupEcho], 1] call Zen_SetAISkill;
0 = [X, "SOF Marksman"] call Zen_GiveLoadoutCustom;
0 = [Pilot, "SOF Rifleman"] call Zen_GiveLoadoutCustom;
0 = [_groupEcho, ["SOF TL", "SOF Rifleman", "SOF AR", "SOF Marksman", "SOF Medic"]] call Zen_GiveLoadoutCustom;

_flyOverPos = [_insertionHeli, "mkInsertion", 1000] call Zen_ExtendRay;
_h_flyOver = [_insertionHeli, _flyOverPos, "full", HELI_HEIGHT] spawn Zen_OrderVehicleMove;

_protectPilot = [X, "Protect the pilot at all costs.  You need him to steal the Opfor Mi-48.", "Protect Pilot"] call Zen_InvokeTask;
_h_pilot = [_protectPilot] spawn f_EventTrigger_PilotDead;

_destroyWindPower = [X, "Eliminate energy flow from all wind power sources on the peninsula.", "Cripple Wind Power"] call Zen_InvokeTask;

_destroyJunc1 = [X, "Eliminate the secondary junction near Selakano.  You can use the Mi-48 or plant satchel charges on foot.  The latter is significantly quieter.", "Destroy Junction 1", "mkJ1", false, _destroyWindPower] call Zen_InvokeTask;

_destroyJunc2 = [X, "Eliminate the primary power line junction near Panagia.  You will have to use the Mi-48 for this one.  The Opfor garrison at Panagia is too strong.", "Destroy Junction 2", "mkJ2", false, _destroyWindPower] call Zen_InvokeTask;

_stealMi_48 = [X, "Have the pilot steal it to use against the Opfor.  Do not steal it until Feres is secure, or the Opfor will call for reinforcements.  As the gunner, you need to destroy the junctions and any Opfor targets you encounter.", "Steal the Mi-48", MI_48] call Zen_InvokeTask;

_secureMi_48 = [X, "Eliminate any guards or crew near the Mi-48.  If you do not kill the crew and you are detected, they may take off and attack you in the Mi-48.", "Secure the Mi-48", 0, false, _stealMi_48] call Zen_InvokeTask;

_tempSupport = ["sh_155mm_amos", 20, 1, 1, 1, "mkDestroySelakano", 1] call Zen_CreateFireSupport;
0 = ["mkDestroySelakano", _tempSupport] spawn Zen_InvokeFireSupport;

for "_i" from 1 to 100 do {
    _spawnPos = ["mkDestroySelakano"] call Zen_FindGroundPosition;
    {
        _x setDamage 1;
    } forEach (nearestObjects [_spawnPos, [], 20]);
};

0 = [_tempSupport] call Zen_RemoveFireSupport;

sleep 5;
Pilot groupChat "I hope HQ knows what they're doing.  I didn't sign up to be a black ops superhero.";
sleep 10;
X groupChat "Desperate times, huh?  Just stick behind me until we get to the helicopter.";
sleep 8;
Pilot groupChat "That I can do.";

waitUntil {
    sleep 0.25;
    ([X, "mkInsertion"] call Zen_AreInArea)
};

_insertionHeli animateDoor ["door_r", 1];
sleep 2;
pilot allowDamage false;
_insertionHeli lock 0;

{
    removeBackpack _x;
    _x addBackpack "b_parachute";
    _x action ["eject", _insertionHeli];
    _x leaveVehicle _insertionHeli;
    unassignVehicle _x;
    sleep 1;
} forEach (units _groupPlayer);

terminate _h_flyOver;
_flyOverPos = [_insertionHeli, _heliSpawn, 1000] call Zen_ExtendRay;
_h_flyOver = [_insertionHeli, _flyOverPos, "full", HELI_HEIGHT] spawn Zen_OrderVehicleMove;

waitUntil {
    sleep 2;
    (isTouchingGround X)
};

_rendezvous = [X, "Rendezvous with the pilot so you can begin the mission.", "Regroup", 0, true] call Zen_InvokeTask;

waitUntil {
    sleep 2;
    ((Pilot distance X) < 10)
};

terminate _h_flyOver;
{
    deleteVehicle _x;
} forEach (crew _insertionHeli + [_insertionHeli]);

Pilot allowDamage true;
0 = [_rendezvous, "succeeded"] call Zen_UpdateTask;

sleep 2;
_clearSelakano = [X, "Observe the town of Selakano for signs of Opfor patrols or resistance presence.  Once your recon is complete, move in and eliminate any threats.", "Secure Selakano", "mkSelakano", true] call Zen_InvokeTask;

sleep 2;
_meetResistance = [X, "There might be some resistance fighters in Selakano.  Try to find them after you secure the area.  They might have important intel.", "Find Resistance", 0, false, _clearSelakano] call Zen_InvokeTask;

sleep 2;
_destroyGasStation = [X, "Plant a satchel charge on the pump at the gas station.  More chaos will only help our operation succeed.", "Destroy Gas Station (opt.)", "mkGasStation"] call Zen_InvokeTask;

_gasStation addAction ["Plant Time-Delayed Demolitions Charge", f_EventTrigger_Action, [_destroyGasStation, "Explosives Armed"]];
_J1Obj addAction ["Plant Time-Delayed Demolitions Charge", f_EventTrigger_Action, [_destroyJunc1, "Explosives Armed"]];

_h_J1 = [_J1Obj, _destroyJunc1, "succeeded"] spawn Zen_TriggerAreDead;
_h_J2 = [_J2Obj, _destroyJunc2, "succeeded"] spawn Zen_TriggerAreDead;

_J1ProxyObj = ["mkJ1", "Land_Loudspeakers_F"] call Zen_SpawnVehicle;
_J2ProxyObj = ["mkJ2", "Land_Loudspeakers_F"] call Zen_SpawnVehicle;

_J1ProxyObj hideObject true;
_J2ProxyObj hideObject true;

ADD_DESTROY_NEAR_EH(_J1ProxyObj)
ADD_DESTROY_NEAR_EH(_J2ProxyObj)

{
    _spawnPos = [_x] call Zen_FindGroundPosition;
    _guardGroup = [_spawnPos, east, AI_SKILL, [2,4]] call Zen_SpawnInfantry;
    0 = [_guardGroup, _x] spawn Zen_OrderInfantryPatrol;
} forEach ["mkJ1Patrol", "mkAirFieldPatrol", "mkFieldPatrol"];

_spawnPos = [MI_48, 7 + random 10, random 360] call Zen_ExtendPosition;
_MI_48_guard = [_spawnPos, east, AI_SKILL, 1] call Zen_SpawnInfantry;

_spawnPos = [MI_48, 7 + random 10, random 360] call Zen_ExtendPosition;
_MI_48_pilots = [_spawnPos, east, AI_SKILL, 2] call Zen_SpawnInfantry;

0 = [_MI_48_guard] call Zen_GiveLoadoutOpfor;
0 = [_MI_48_pilots, "Helicopter Pilot"] call Zen_GiveLoadoutOpfor;

0 = [_MI_48_guard, MI_48, [15, 35]] spawn Zen_OrderInfantryPatrol;
_h_MI_48_guards = [[_MI_48_guard, _MI_48_pilots], _secureMi_48, "succeeded"] spawn Zen_TriggerAreDead;

_selakanoGroups = [];
if (_selakanoOpfor) then {
    for "_i" from 1 to 1 do {
        _spawnPos = ["mkSelakano", 0, [], 1, [1, 100]] call Zen_FindGroundPosition;
        _guardGroup = [_spawnPos, east, AI_SKILL, [2, 3]] call Zen_SpawnInfantry;
        0 = [_selakanoGroups, _guardGroup] call Zen_ArrayAppend;
    };

    0 = [_selakanoGroups, "mkSelakano"] spawn Zen_OrderInfantryPatrol;
};

if (_selakanoResistance) then {
    _spawnPos = ["mkSelakano", 0, [], 1, [1, 100]] call Zen_FindGroundPosition;
    _resistanceGroup = [_spawnPos, west, AI_SKILL, 1, "men", "blu_g_f"] call Zen_SpawnInfantry;
    {_x setCaptive true; _x allowDamage false;} forEach units _resistanceGroup;
    0 = [_resistanceGroup, "civilian"] call Zen_GiveLoadoutBlufor;
    _resistanceGroup setGroupId ["Resistance"];
};

0 = [Event_Arguments_Array, ["f_EventAction_SpawnPanagai", []], ["f_EventAction_SpawnReinf", []], ["f_EventAction_StoleMI_48", [_clearSelakano, "pass", _stealMi_48]], ["f_EventAction_SpawnFeres", []]] call Zen_ArrayAppend;
0 = [Event_Queue_Array, ["f_EventAction_SpawnPanagai", false], ["f_EventAction_SpawnReinf", false], ["f_EventAction_StoleMI_48", false], ["f_EventAction_SpawnFeres", false]] call Zen_ArrayAppend;

0 = [] spawn f_HandleEventQueue;

0 = [] spawn {
    while {true} do {
        sleep 10;
        if ((X in MI_48) && (((getPosATL MI_48) select 2) > 5)) exitWith {
            0 = "f_EventAction_StoleMI_48" call f_EventTrigger_Generic;
        };
    };
};

_selakanoGroups = [_selakanoGroups] call Zen_ConvertToObjectArray;

waitUntil {
    sleep 5;

    if (([X, "mkFeres"] call Zen_Find2dDistance) < 600) then {
        0 = "f_EventAction_SpawnFeres" call f_EventTrigger_Generic;
    };

    if (([X, "mkPanagia"] call Zen_Find2dDistance) < 1000) then {
        0 = "f_EventAction_SpawnPanagai" call f_EventTrigger_Generic;
    };

    (if (_selakanoOpfor) then {
        ((({alive _x} count _selakanoGroups) == 0) && ([X, "mkSelakano"] call Zen_AreInArea))
    } else {
        ([X, "mkSelakano"] call Zen_AreInArea)
    })
};

"mkSelakano" setMarkerColor "colorBlack";
0 = [_clearSelakano, "succeeded"] call Zen_UpdateTask;

sleep 10;
if !(_selakanoResistance) then {
    player groupChat "There's no signs of the resistance here.  They must have moved on.";
    sleep 10;
    if (_selakanoOpfor) then {
        Pilot groupChat "Let's get out of here before reinforcements show up.";
        sleep  7;
    };

    0 = [_meetResistance, "canceled"] call Zen_UpdateTask;
} else {
    _h_meetResist = [_resistanceGroup, X, "full"] spawn Zen_OrderInfantryMove;
    Pilot groupChat "I thought I saw some civilian wandering around.  Maybe that's the guy you're supposed to meet.";

    waitUntil {
        sleep 2;
        ((scriptDone _h_meetResist) && (([_resistanceGroup, X] call Zen_Find2dDistance) < 5))
    };

    (leader _resistanceGroup) sideChat "I am glad I have found you, Americans.  I have important documents and a message from our cell leader.";
    sleep 12;
    X sideChat "What's the message?";
    sleep 4;
    (leader _resistanceGroup) sideChat "Here, take these papers first.  <Redacted>";
    sleep 10;
    X sideChat "Thanks, this will be very useful.  You resistance guys don't get enough credit for your work.";
    sleep 10;
    (leader _resistanceGroup) sideChat "<Redacted>";
    sleep 12;
    X sideChat "<Redacted>";
    sleep 11;
    (leader _resistanceGroup) sideChat "<Redacted>";
    sleep 16;
    (leader _resistanceGroup) sideChat "<Redacted>";
    sleep 11;
    X sideChat "<Redacted>";
    sleep 10;
    X sideChat "<Redacted>";
    sleep 9;
    (leader _resistanceGroup) sideChat "I must leave now, I can smell those CSAT bastards from here.  Good luck, Americans.";
    sleep 11;

    0 = [_meetResistance, "succeeded"] call Zen_UpdateTask;
    0 = [_resistanceGroup, "mkInsertion", "full"] spawn Zen_OrderInfantryMove;
};

0 = "f_EventAction_SpawnFeres" call f_EventTrigger_Generic;

if (_feresStash) then {
    _spawnPos = ["mkFeres", 0, [], 1, [1, 100]] call Zen_FindGroundPosition;
    _ammoBox = [_spawnPos, east] call Zen_SpawnAmmoBox;
};

if (_feresOfficer) then {
    _spawnPos = ["mkFeres", 0, [], 1, [1, 100]] call Zen_FindGroundPosition;
    _officerGroup = [_spawnPos, east, "officer", 1] call Zen_SpawnInfantry;
    0 = [_officerGroup, "Officer"] call Zen_GiveLoadoutOpfor;
};

sleep 2;
_secureFeres = [X, "Wait until Echo secures Feres.  You can also help them or do it all yourself.", "Secure Feres", "mkFeres", true] call Zen_InvokeTask;

sleep 2;
_assistEcho = [X, "Help Echo clear Feres of Opfor patrols.  There might also be some objectives of opportunity there.", "Assist Echo", 0, false, _secureFeres] call Zen_InvokeTask;

sleep 2;
_assaultAction = player addAction ["Give Go-Code to Assault Feres", f_AssaultFeres];

sleep 5;
_h_feresClear = [(["mkFeres", [], east] call Zen_GetAllInArea), [_groupEcho, _groupPlayer], _secureFeres, "succeeded", "mkFeres"] spawn Zen_TriggerAreaSecure;
_secondaryFeres = "";

_stealMi_48_Event_Data = [Event_Arguments_Array, "f_EventAction_StoleMI_48", 0] call Zen_ArrayGetNestedValue;
_stealMi_48_Event_Data set [2, _secureFeres];

waitUntil {
    sleep 5;

    if (([X, "mkFeres"] call Zen_AreInArea) && (_secondaryFeres == "")) then {
        0 = [_assistEcho, "succeeded"] call Zen_UpdateTask;
        _secondaryFeres = [X, "Search Feres briefly for any secondary objectives, such as weapons caches or intel.  Move on to your main objectives if you do not find anything.", "Search Feres", 0, false, _secureFeres] call Zen_InvokeTask;

        if (_feresStash) then {
            _ammoBox addAction ["Plant Time-Delayed Demolitions Charge", f_EventTrigger_Action, [_secondaryFeres, "Explosives Armed"]];
        };

        if (_feresOfficer) then {
            (leader _officerGroup) addAction ["Search for Intel", f_EventTrigger_Action, [_secondaryFeres, "Intel Retrieved"]];
        };

        if (!_feresStash && !_feresOfficer) then {
            0 = _secondaryFeres spawn {
                sleep 180;
                0 = [_this, "canceled"] call Zen_UpdateTask;
            };
        };
    };

    if (([X, "mkPanagia"] call Zen_Find2dDistance) < 1000) then {
        0 = "f_EventAction_SpawnPanagai" call f_EventTrigger_Generic;
    };

    (scriptDone _h_feresClear)
};

"mkFeres" setMarkerColor "colorBlufor";
if !([_assistEcho] call Zen_AreTasksComplete) then {
    0 = [_assistEcho, "canceled"] call Zen_UpdateTask;
};

0 = [] spawn {
    _startPos = ["mkPanagia", 100, [], 1, [1, 100], [45, 135]] call Zen_FindGroundPosition;
    _endPos = ["mkFeres", 100, [], 1, [1, 100], [-45, 45]] call Zen_FindGroundPosition;

    _opforCar = [_startPos, "o_mrap_02_f"] call Zen_SpawnVehicle;
    _opforReinfGroup = [_opforCar, east, AI_SKILL, 4] call Zen_SpawnInfantry;
    0 = [_opforReinfGroup, _opforCar, "all"] call Zen_MoveInVehicle;
    _h_insertion = [_opforCar, _endPos, "all"] spawn Zen_OrderVehicleMove;

    waitUntil {
        sleep 2;
        (scriptDone _h_insertion)
    };

    {unassignVehicle _x;} forEach units _opforReinfGroup;
    sleep 5;
    0 = [_opforReinfGroup, "mkFeres"] spawn Zen_OrderInfantryPatrol;
};

if !(scriptDone _h_MI_48_guards) then {
    0 = [_MI_48_pilots, MI_48, "all"] call Zen_MoveInVehicle;
    0 = [MI_48, (getMarkerPos "mkFeres"), 600] spawn Zen_OrderAircraftPatrol;
    MI_48 disableTIEquipment true;

    [west, "HQ"] sideChat "Sierra, HQ, Opfor are alerted to your presence.  They are scrambling the MI-48.  Get to extraction now!";
    sleep 12;
    X sideChat "HQ, Sierra, negative, we can still complete.  There might be AA weapons in Feres.";
    sleep 11;
    [west, "HQ"] sideChat "Dammit Sierra, a whole armored platoon is mobilizing to your north.  Get the hell out of there!";
    sleep 11;
    X sideChat "Roger HQ, Sierra moving to extraction.";
    sleep 8;
    (leader _groupEcho) sideChat "HQ, Echo, we're oscar mike to extraction, out.";
    0 = [_groupEcho, "mkInsertEcho", "full"] spawn Zen_OrderInfantryMove;

    sleep 5;
    _killMI_48 = [X, "The Opfor pilots have taken off in their Mi-48.  Eliminate it if you can, but your main goal is to escape to extraction.", "Destroy the Mi-48 (opt.)"] call Zen_InvokeTask;

    sleep 2;
    0 = "f_EventAction_SpawnReinf" call f_EventTrigger_Generic;

    sleep 2;
    _extract = [X, "Move to the extract point as quickly as possible.  You need to escape from the Mi-48 and Opfor armor.", "Get to Extraction", "mkExtraction", true] call Zen_InvokeTask;

    waitUntil {
        sleep 3;
        (([X, "mkExtraction"] call Zen_Find2dDistance) < 15)
    };

    0 = "endFail" call BIS_fnc_EndMission;
    if (true) exitWith {};
};

0 = "f_EventAction_SpawnPanagai" call f_EventTrigger_Generic;

sleep 2;
_hitPanagia = [X, "Attack and damage the Opfor garrison at Panagia with the Mi-48.  You do not need to eliminate all targets.  Just do enough damage to make them combat ineffective.", "Attack Panagia (opt.)", "mkPanagia"] call Zen_InvokeTask;

_panagiaGarrison = ["mkPanagia", [], east] call Zen_GetAllInArea;
_h_panagiaHit = [_panagiaGarrison, _hitPanagia, "succeeded", round (count _panagiaGarrison / 2)] spawn Zen_TriggerAreDead;

waitUntil {
    sleep 4;
    ((scriptDone _h_panagiaHit) || (scriptDone _h_J2))
};

0 = [_groupEcho, "mkInsertEcho", "full"] spawn Zen_OrderInfantryMove;
0 = "f_EventAction_SpawnReinf" call f_EventTrigger_Generic;

waitUntil {
    sleep 5;
    if (scriptDone _h_panagiaHit) then {
        "mkPanagia" setMarkerColor "colorBlack";
    };

    ((scriptDone _h_J2) && (["Task_Stop_Reinf"] call Zen_AreTasksComplete) && (scriptDone _h_J1))
};

sleep 10;
Pilot groupChat "Okay, Sir, we've destroyed everything we need to.  I'm landing near the extraction point.";

[Pilot] join grpNull;

sleep 2;
_taskLand = [X, "Allow the pilot to land the Mi-48 near extraction.  Then get out and place a satchel charge on it before heading to extraction.", "Destroy Mi-48", 0, true, _stealMi_48] call Zen_InvokeTask;

_landPos = ["mkExtraction", [150, 225], [], 1, 0, [180, 260]] call Zen_FindGroundPosition;
0 = [MI_48, _landPos, "full", 35] spawn Zen_OrderHelicopterLand;

MI_48 addAction ["Plant Time-Delayed Demolitions Charge", f_EventTrigger_Action, [_taskLand, "Explosives Armed"], 2, false, true, "", "!(_target in _this) && {(_target distance _this) < 4}"];

waitUntil {
    sleep 2;
    (isTouchingGround MI_48)
};

MI_48 lock 0;
player action ["Eject", MI_48];
Pilot action ["Eject", MI_48];

sleep 2;
MI_48 lock 2;

[Pilot] joinSilent X;
terminate _h_pilot;
0 = [_protectPilot, "succeeded"] call Zen_UpdateTask;

sleep 2;
_extract = [X, "You have successfully completed all your primary objectives.  Move to the extraction point to finish the mission.", "Move to Extraction", "mkExtraction", true] call Zen_InvokeTask;

_h_extract = [_groupPlayer, _extract, "succeeded", "mkExtraction", "all"] spawn Zen_TriggerAreNear;

waitUntil {
    sleep 5;
    (scriptDone _h_extract)
};

{
    if !([_x] call Zen_AreTasksComplete) then {
        sleep 1;
        0 = [_x, "canceled"] call Zen_UpdateTask;
    };
} forEach ([X] call Zen_GetUnitTasks);

sleep 6;

0 = "endWin" call BIS_fnc_EndMission;