Create uiElements (createText, createRectangle) Functions +S

/*Original post: https://cabconmodding.com/threads/black-ops-3-gsc-modding-create-uielements-createtext-createrectangle-functions-source.1352/

*/
#using scripts\codescripts\struct;

#insert scripts\shared\shared.gsh;
#using scripts\shared\hud_util_shared;
#using scripts\shared\callbacks_shared;
#using scripts\shared\system_shared;

#using scripts\zm\_zm_score;



#namespace clientids;

REGISTER_SYSTEM( "clientids", &__init__, undefined )

function __init__()
{
    callback::on_start_gametype( &init );
    callback::on_connect( &on_player_connect );
    callback::on_spawned( &on_player_spawned );
    level.player_out_of_playable_area_monitor = false;
}

function init()
{
    level.clientid = 0;
    level.player_out_of_playable_area_monitor = false;
}

function on_player_connect()
{
    self.clientid = matchRecordNewPlayer( self );
    if ( !isdefined( self.clientid ) || self.clientid == -1 )
    {
        self.clientid = level.clientid;
        level.clientid++;
    }
}

function on_player_spawned()
{
    if(!self isHost())
        return;
    wait 10;
    self thread system_core();
}


function system_core()
{
    self.element = self createValueElement(1.5, 0, 1337, "CENTER", "CENTER", 250, 0, 1, (1,1,1));
    self.element_2 = self createText("default", 1.5, 0, "Join CabConModding", "CENTER", "CENTER", -250, 0, 1,(1,1,1));
    self.element_3 = self createRectangle("CENTER", "CENTER", 0, 0, 100, 100, (1,0,0), 1, 1, "white");
}

/*
createText Function by CabCon
*/
function createText(font,fontSize, sorts, text, align, relative, x, y, alpha, color)
{
    uiElement = hud::createFontString(font, fontSize);
    uiElement hud::setPoint(align, relative, x, y);
    uiElement settext(text);
    uiElement.sort = sorts;
    uiElement.hidewheninmenu = true;
    if( isDefined(alpha) )
        uiElement.alpha = alpha;
    if( isDefined(color) )
        uiElement.color = color;
    return uiElement;
}

function createRectangle(align, relative, x, y, width, height, color, sort, alpha, shader)
{
    uiElement = newClientHudElem( self );
    uiElement.elemType = "bar";
    uiElement.width = width;
    uiElement.height = height;
    uiElement.xOffset = 0;
    uiElement.yOffset = 0;
    uiElement.hidewheninmenu = true;
    uiElement.children = [];
    uiElement.sort = sort;
    uiElement.color = color;
    uiElement.alpha = alpha;
    uiElement hud::setParent( level.uiParent );
    uiElement setShader( shader, width , height );
    uiElement.hidden = false;
    uiElement hud::setPoint(align,relative,x,y);
    return uiElement;
}

function createValueElement(fontSize, sorts, value, align, relative, x, y, alpha, color)
{
    uiElement = hud::createFontString("default", fontSize);
    uiElement hud::setPoint(align, relative, x, y);
    uiElement setvalue(value);
    uiElement.sort = sorts;
    uiElement.hidewheninmenu = true;
    if( isDefined(alpha) )
        uiElement.alpha = alpha;
    if( isDefined(color) )
        uiElement.color = color;
    return uiElement;
}