box2.sqf

/*
Script by HALV
*/
//Building Stuff content 2 of each tool/weapon 5 of each magazine item
_toolcontent1 = [
'ItemToolbox'
];
_magcontent1 = [
'ItemAntibiotic'
];
//Building Stuff content 5 of each tool/weapon 25 of each magazine item
_toolcontent2 = [
'ItemHatchet_DZE','ItemEtool','ItemToolbox','ItemCrowbar'
];
_magcontent2 = [
'PartGeneric','HandRoadFlare','ItemWire','PartWoodPile','ItemTankTrap','ItemSandbag','ItemTrashToiletpaper','ItemTrashRazor',
'ItemCorrugated','PartWoodPlywood','PartWoodLumber','ItemCanvas','ItemPole','ItemTentDomed','ItemTentDomed2','30m_plot_kit',
'ItemTentOld','ItemVault','ItemGenerator','ItemBurlap','ItemLightBulb'
];
//Repair Stuff content 2 of each tool/weapon 5 of each magazine item
_toolcontent3 = [
'ItemKnife','ItemHatchet_DZE','ItemMatchbox_DZE','ItemEtool','ItemToolbox','ItemCrowbar'
];
_magcontent3 = [
'PartVRotor','PartGlass','PartFueltank','PartWheel','PartEngine','PartGeneric','ItemJerrycan','HandRoadFlare','HandChemGreen',
'HandChemBlue','HandChemRed'
];

//add extra keykits to allitembox
_addkeykit = true;
//backpack in allitembox
_backpack = "DZ_Backpack_EP1";

hint "Select Boxtype:";
BoxSelected=false;
ContentSelected=false;
defaultweaps=false;
DelaySelected=false;
Boxtype =
[
    ["",true],
    ["Select Boxtype:", [-1], "", -5, [["expression", ""]], "1", "0"],
    ["", [-1], "", -5, [["expression", ""]], "1", "0"],
    ["MedBox0", [2], "", -5, [["expression", "SelectetBox=1;BoxSelected=true;"]], "1", "1"],
    ["FoodBox0", [3], "", -5, [["expression", "SelectetBox=2;BoxSelected=true;"]], "1", "1"],
    ["BAF_BasicWeapons", [4], "", -5, [["expression", "SelectetBox=3;BoxSelected=true;"]], "1", "1"],
    ["USSpecialWeaponsBox", [5], "", -5, [["expression", "SelectetBox=4;BoxSelected=true;"]], "1", "1"],
    ["USSpecialWeapons_EP1", [6], "", -5, [["expression", "SelectetBox=5;BoxSelected=true;"]], "1", "1"],
    ["USVehicleBox", [7], "", -5, [["expression", "SelectetBox=6;BoxSelected=true;"]], "1", "1"],
    ["RUSpecialWeaponsBox", [8], "", -5, [["expression", "SelectetBox=7;BoxSelected=true;"]], "1", "1"],
    ["RUVehicleBox", [9], "", -5, [["expression", "SelectetBox=8;BoxSelected=true;"]], "1", "1"],
    ["Random", [10], "", -5, [["expression", "SelectetBox=9;BoxSelected=true;"]], "1", "1"],
    ["", [-1], "", -5, [["expression", ""]], "1", "0"],
    ["Exit", [-1], "", -5, [["expression", "BoxSelected=false;"]], "1", "1"]
];
contentmenu =
[
    ["",true],
    ["Select Content:", [-1], "", -5, [["expression", ""]], "1", "0"],
    ["", [-1], "", -5, [["expression", ""]], "1", "0"],
    ["MedBox0+", [2], "", -5, [["expression", "SelectetContent=1;ContentSelected=true;"]], "1", "1"],
    ["Building Stuff", [3], "", -5, [["expression", "SelectetContent=2;ContentSelected=true;"]], "1", "1"],
    ["Repair Stuff", [4], "", -5, [["expression", "SelectetContent=3;ContentSelected=true;"]], "1", "1"],
    ["""Small"" AllInABox (For All Eyes)", [5], "", -5, [["expression", "SelectetContent=5;ContentSelected=true;Admin_Box_Selected=true;"]], "1", "1"],
    ["Large AllInABox (Only You See Cont.)", [6], "", -5, [["expression", "SelectetContent=6;ContentSelected=true;Admin_Box_Selected=true;"]], "1", "1"],
    ["NoContent", [7], "", -5, [["expression", "SelectetContent=4;ContentSelected=true;"]], "1", "1"],
    ["", [-1], "", -5, [["expression", ""]], "1", "0"],
    ["Exit", [-1], "", -5, [["expression", "ContentSelected=false;"]], "1", "1"]
];
nodefault =
[
    ["",true],
    ["Delete default stuff?", [-1], "", -5, [["expression", ""]], "1", "0"],
    ["", [-1], "", -5, [["expression", ""]], "1", "0"],
    ["Leave Default Stuff", [2], "", -5, [["expression", "nodefaultweaps=1;defaultweaps=true;"]], "1", "1"],
    ["Delete Default Stuff", [3], "", -5, [["expression", "nodefaultweaps=2;defaultweaps=true;"]], "1", "1"],
    ["", [-1], "", -5, [["expression", ""]], "1", "0"],
    ["Exit", [-1], "", -5, [["expression", "defaultweaps=false;"]], "1", "1"]
];
delaymenu =
[
    ["",true],
    ["Select delete delay:", [-1], "", -5, [["expression", ""]], "1", "0"],
    ["", [-1], "", -5, [["expression", ""]], "1", "0"],
    ["5 min", [2], "", -5, [["expression", "Select_Delay=true;SelectDelay=300;DelaySelected=true;"]], "1", "1"],
    ["10 min", [3], "", -5, [["expression", "Select_Delay=true;SelectDelay=600;DelaySelected=true;"]], "1", "1"],
    ["15 min", [4], "", -5, [["expression", "Select_Delay=true;SelectDelay=900;DelaySelected=true;"]], "1", "1"],
    ["20 min", [5], "", -5, [["expression", "Select_Delay=true;SelectDelay=1200;DelaySelected=true;"]], "1", "1"],
    ["25 min", [6], "", -5, [["expression", "Select_Delay=true;SelectDelay=1500;DelaySelected=true;"]], "1", "1"],
    ["30 min", [7], "", -5, [["expression", "Select_Delay=true;SelectDelay=1800;DelaySelected=true;"]], "1", "1"],
    ["", [-1], "", -5, [["expression", ""]], "1", "0"],
    ["Never Delete", [11], "", -5, [["expression", "Select_Delay=false;DelaySelected=true;"]], "1", "1"],
    ["", [-1], "", -5, [["expression", ""]], "1", "0"],
    ["Exit", [-1], "", -3, [["expression", ""]], "1", "1"]
];
showCommandingMenu '#USER:Boxtype';
waituntil{CommandingMenu != "#User:Boxtype"};
if !(BoxSelected) exitwith {titleText ["Nothing selected","PLAIN DOWN"];titlefadeout 3;};
BoxSelected=false;
hint "Select Content:";

showCommandingMenu '#USER:contentmenu';
waituntil{CommandingMenu != "#User:contentmenu"};
if !(ContentSelected) exitwith {titleText ["Nothing selected","PLAIN DOWN"];titlefadeout 3;};
ContentSelected=false;
hint "Delete default stuff?";

showCommandingMenu '#USER:nodefault';
waituntil{CommandingMenu != "#User:nodefault"};
if !(defaultweaps) exitwith {titleText ["Nothing selected","PLAIN DOWN"];titlefadeout 3;};
defaultweaps=false;
hint "Select Delete Delay ...";

showCommandingMenu '#USER:delaymenu';
waituntil{CommandingMenu != "#User:delaymenu"};
if !(DelaySelected) exitwith {titleText ["Nothing selected","PLAIN DOWN"];titlefadeout 3;};
DelaySelected=false;

if (Admin_Box_Selected) then {
    Admin_Box_Selected=false;
    if (isNil "GET_wepslist") then {
        GET_wepslist = [];
        _cfgweps = configFile >> "cfgWeapons";
        diag_log format["%1",_cfgweps];
        for "_i" from 0 to (count _cfgweps)-1 do {
            _weapon = _cfgweps select _i;
            if (isClass _weapon) then {
                _wpn_type = configName(_weapon);
                _plx = toArray _wpn_type;
                _plx resize 7;
                _plx;
                _plx = toString _plx;
                if (_plx != "ItemKey") then {
                    if (((getNumber (_weapon >> "scope") == 0) or (getNumber (_weapon >> "scope") == 2)) && (getText (_weapon >> "picture") != "") && !(_wpn_type == "MineE") && !(_wpn_type == "ItemCore") && !(_wpn_type == "MeleeBaseBallBat")) then {
                        GET_wepslist = GET_wepslist + [_wpn_type];
                    };
                };
            };
        };
        sleep 2;
    };
    if (isNil "GET_maglist") then {
        GET_maglist = [];
        _cfgweps = configFile >> "cfgmagazines";
        for "_i" from 0 to (count _cfgweps)-1 do {
            _weapon = _cfgweps select _i;
            if (isClass _weapon) then {
                _wpn_type = configName(_weapon);
                if (((getNumber (_weapon >> "scope") == 0) or (getNumber (_weapon >> "scope") == 2)) && (getText (_weapon >> "picture") != "") && !(_wpn_type == "AngelCookies") && !(_wpn_type == "SkinBase") && !(_wpn_type == "ItemBriefcase_Base")) then {
                    GET_maglist = GET_maglist + [_wpn_type];
                };
            };
        };
        sleep 2;
    };
};
_TheBoX="";
switch (SelectetBox) do {
    case 1:{_TheBoX = "MedBox0"};
    case 2:{_TheBoX = "FoodBox0"};
    case 3:{_TheBoX = "BAF_BasicWeapons"};
    case 4:{_TheBoX = "USSpecialWeaponsBox"};
    case 5:{_TheBoX = "USSpecialWeapons_EP1"};
    case 6:{_TheBoX = "USVehicleBox"};
    case 7:{_TheBoX = "RUSpecialWeaponsBox"};
    case 8:{_TheBoX = "RUVehicleBox"};
    case 9:{_TheBoX = ["USSpecialWeaponsBox","BAF_BasicWeapons","USVehicleBox","RUVehicleBox","RUSpecialWeaponsBox","USSpecialWeapons_EP1","USSpecialWeapons_EP1","FoodBox0","MedBox0"] call BIS_fnc_selectRandom;};
};

_pos = getPos player;
_dir = getDir player;
_spwnpos = [((_pos) select 0)+5*sin(_dir), ((_pos) select 1)+5*cos(_dir), 0];
_spwnveh = createVehicle [_TheBoX,_spwnpos,[],0,"CAN_COLLIDE"];
_spwnveh setVariable ["Sarge",1,true];
_spwnveh setVariable ["permaLoot",true,true];

if (nodefaultweaps == 1) then {
    hint "Leaving default Stuff in the box ...";
} else {
    hint "Deleting default Stuff from the box ...";
    clearWeaponCargoGlobal _spwnveh;
    clearMagazineCargoGlobal _spwnveh;
    clearBackpackCargoGlobal _spwnveh;
};
switch (SelectetContent) do {
    case 1: {
        {_spwnveh addWeaponCargoGlobal [_x, 5];} forEach _toolcontent1;
        {_spwnveh addmagazineCargoGlobal [_x, 5];} forEach _magcontent1;
    };
    case 2: {
        {_spwnveh addWeaponCargoGlobal [_x, 5];} forEach _toolcontent2;
        {_spwnveh addmagazineCargoGlobal [_x, 25];} forEach _magcontent2;
    };
    case 3: {
        {_spwnveh addWeaponCargoGlobal [_x, 2];} forEach _toolcontent3;
        {_spwnveh addmagazineCargoGlobal [_x, 5];} forEach _magcontent3;
    };
    case 4: {hint "No Content selected ..."};
    case 5: {clearWeaponCargoGlobal _spwnveh;clearMagazineCargoGlobal _spwnveh;
        {_spwnveh addWeaponCargoGlobal [_x, 3];} forEach GET_wepslist;
        {_spwnveh addMagazineCargoGlobal [_x, 25];} forEach GET_maglist;
        if(_addkeykit)then{_spwnveh addWeaponCargoGlobal ["ItemKeyKit", 5];};
        _spwnveh addBackpackCargoGlobal [_backpack, 1];
    };
    case 6: {clearWeaponCargoGlobal _spwnveh;clearMagazineCargoGlobal _spwnveh;
        {_spwnveh addWeaponCargo [_x, 5];} forEach GET_wepslist;
        {_spwnveh addMagazineCargo [_x, 50];} forEach GET_maglist;
        if(_addkeykit)then{_spwnveh addWeaponCargoGlobal ["ItemKeyKit", 5];};
        _spwnveh addBackpackCargo [_backpack, 1];
    };
};

_WCargo1 = getWeaponCargo _spwnveh;
_MCargo1 = getMagazineCargo _spwnveh;
diag_log format ["BoxSpawn: BoxType: %1 Createt At: %2 Weapons: %3 Magazines: %4",_TheBoX,_spwnpos,_WCargo1,_MCargo1];
sleep 0.1;
if (Select_Delay) then {
    Select_Delay=false;
    hint format["The box will be deleted in \n %1 Minutes.",(round(SelectDelay/60))];
    sleep SelectDelay;
    clearWeaponCargoGlobal _spwnveh;
    clearMagazineCargoGlobal _spwnveh;
    clearBackpackCargoGlobal _spwnveh;
    deletevehicle _spwnveh;
    hint "The box is now deleted ...";
};