PKGBUILD Handbrake 0.10.5

# $Id$
# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Sebastien Piccand <sebcactus gmail com>

pkgname=handbrake
_pkgname=HandBrake
pkgver=0.10.5
pkgrel=1
arch=('x86_64')
url="http://handbrake.fr/"
license=('GPL')
pkgdesc="Multithreaded video transcoder"
screenshot="https://handbrake.fr/img/slides/slide1_lin.jpg"
depends=('bzip2' 'gcc-libs' 'gst-plugins-base' 'libnotify' 'dbus-glib'
           'fribidi' 'libass' 'lame' 'gtk3' 'fontconfig' 'freetype2' 'libxml2'
           'libogg' 'libvorbis' 'libtheora' 'libsamplerate' 'libbluray'
           'libdvdnav' 'librsvg' 'desktop-file-utils'
           'hicolor-icon-theme')
optdepends=('gst-plugins-good: for video previews'
            'gst-libav: for video previews')
makedepends=('intltool' 'python2' 'yasm' 'wget' 'bzip2' 'gcc-libs' 'libnotify'
             'gst-plugins-base' 'gtk3' 'dbus-glib' 'fribidi' 'libass' 'lame'
             'fontconfig' 'freetype2' 'libxml2' 'libogg' 'libvorbis' 'cmake'
             'libtheora' 'libsamplerate' 'libbluray' 'x264' 'libx264' 'libdvdnav' 'librsvg')
install=$pkgname.install
source=(https://handbrake.fr/mirror/$_pkgname-$pkgver.tar.bz2)
sha256sums=('fb9230dd121b456f6829d1d25ac8bbf76e503b51c4efc70f0a7fd2bb8607e2f0')

prepare() {
  cd $_pkgname-$pkgver

  # Use more system libs
  # We had ffmpeg here as well but it broke PGS subtitle processing
  # https://forum.handbrake.fr/viewtopic.php?f=13&t=27581
  sed -i \
    -e '/MODULES += contrib\/libbluray/d' \
    -e '/MODULES += contrib\/libdvdnav/d' \
    -e '/MODULES += contrib\/libdvdread/d' \
    make/include/main.defs
}

build() {
  cd $_pkgname-$pkgver

  ./configure \
    --prefix=/usr \
    --force \
    --disable-gtk-update-checks
  cd build
  make
}

package() {

  cd $_pkgname-$pkgver/build

  make DESTDIR=$pkgdir install
  rm "$pkgdir/usr/bin/HandBrakeCLI"
}