Car Crusher

#define     FILTERSCRIPT
#include    <a_samp>
#include    <streamer>
#define     MOVE_SPEED      (0.01)

new
    ContainerObject,
    ContainerDoors[2],
    ContainerCheckpoint,
    Text3D: StatusLabel,
    CrusherStage,
    CrusherVehID = INVALID_VEHICLE_ID;

new
    WantedModels[] = {470, 468, 409, 533, 534, 402, 405, 411, 483, 445, 535, 496, 580, 475, 521, 415, 489, 439, 514, 480, 536, 463, 500, 477, 587, 429, 506, 508, 579, 424};

stock IsVehicleWanted(vehicleid)
{
    new model = GetVehicleModel(vehicleid);
    for(new i; i < sizeof(WantedModels); ++i)
    {
        if(WantedModels[i] == model) return 1;
    }

    return 0;
}

public OnFilterScriptInit()
{
    ContainerObject = CreateDynamicObject(19321, 2098.69946, -1988.17786, 14.01000, 0.00000, 0.00000, 136.00000);
    ContainerDoors[0] = CreateDynamicObject(3062, 2102.26611, -1986.72510, 13.94830, 0.00000, 0.00000, 0.00000);
    ContainerDoors[1] = CreateDynamicObject(3062, 2100.02051, -1984.51746, 13.94830, 0.00000, 0.00000, -260.5230);
    StatusLabel = CreateDynamic3DTextLabel("Crusher Status:\n{2ECC71}Available", 0xFFFFFFFF, 2102.6682, -1983.9194, 13.5463, 25.0, .testlos = 1);
    ContainerCheckpoint = CreateDynamicCP(2098.5313, -1988.2269, 12.7, 2.0);
    return 1;
}

public OnFilterScriptExit()
{
    DestroyDynamicObject(ContainerObject);
    DestroyDynamicObject(ContainerDoors[0]);
    DestroyDynamicObject(ContainerDoors[1]);
    DestroyDynamic3DTextLabel(StatusLabel);
    DestroyDynamicCP(ContainerCheckpoint);
    return 1;
}

public OnPlayerConnect(playerid)
{
    RemoveBuildingForPlayer(playerid, 3723, 2100.7031, -1989.3984, 16.8672, 0.25);
    RemoveBuildingForPlayer(playerid, 3722, 2100.7031, -1989.3984, 16.8672, 0.25);
    return 1;
}

public OnPlayerEnterDynamicCP(playerid, checkpointid)
{
    if(checkpointid == ContainerCheckpoint)
    {
        if(GetPVarInt(playerid, "CrusherCooldown")-tickcount() > 110000) return 1;
        if(GetPVarInt(playerid, "CrusherCooldown") > tickcount()) return SendClientMessage(playerid, 0xE74C3CFF, "Please wait to use the crusher again.");
        if(GetPlayerState(playerid) != PLAYER_STATE_DRIVER) return SendClientMessage(playerid, 0xE74C3CFF, "Umm... Where's the vehicle?");
        if(CrusherStage > 0) return SendClientMessage(playerid, 0xE74C3CFF, "Crusher is already in use.");
        if(!IsVehicleWanted(GetPlayerVehicleID(playerid))) return SendClientMessage(playerid, 0xE74C3CFF, "Sorry, I don't want this model.");
        UpdateDynamic3DTextLabelText(StatusLabel, 0xFFFFFFFF, "Crusher Status:\n{E74C3C}Not Available");
        CrusherStage = 1;
        CrusherVehID = GetPlayerVehicleID(playerid);
        SetPlayerPos(playerid, 2102.6682, -1983.9194, 13.5463);
        SetPlayerFacingAngle(playerid, 136.0);
        SetPVarInt(playerid, "CrusherCooldown", tickcount()+120000);
        new money = random(7500), string[64];
        format(string, sizeof(string), "~n~~r~~h~~h~Thanks for doing business!~n~Earned ~g~~h~~h~$%d!", money);
        GameTextForPlayer(playerid, string, 5000, 3);
        GivePlayerMoney(playerid, money);
        MoveDynamicObject(ContainerDoors[0], 2102.26611+0.025, -1986.72510, 13.94830, MOVE_SPEED, 0.00000, 0.00000, 136.00000);
        MoveDynamicObject(ContainerDoors[1], 2100.02051+0.025, -1984.51746, 13.94830, MOVE_SPEED, 0.00000, 0.00000, -43.5523);
    }

    return 1;
}

public OnDynamicObjectMoved(objectid)
{
    if(objectid == ContainerDoors[0])
    {
        switch(CrusherStage)
        {
            case 1:
            {
                CrusherStage = 2;
                SetVehicleToRespawn(CrusherVehID);
                CrusherVehID = INVALID_VEHICLE_ID;
                SetTimer("OpenDoors", 13000, false);
            }

            case 2:
            {
                UpdateDynamic3DTextLabelText(StatusLabel, 0xFFFFFFFF, "Crusher Status:\n{2ECC71}Available");
                CrusherStage = 0;
            }
        }
    }

    return 1;
}

forward OpenDoors();
public OpenDoors()
{
    MoveDynamicObject(ContainerDoors[0], 2102.26611-0.025, -1986.72510, 13.94830, MOVE_SPEED, 0.00000, 0.00000, 0.00000);
    MoveDynamicObject(ContainerDoors[1], 2100.02051-0.025, -1984.51746, 13.94830, MOVE_SPEED, 0.00000, 0.00000, -260.5230);
    return 1;
}