Happy Hour EXP

/*
        Happy Hour EXP

    Idea:
        Nokia: http://rathena.org/board/topic/57978-happy-hour-exp-event-timer/

    Ver: 26.01.2012 ( without %% )

    By:
        Lilith

    Contacts:
        Gmail: amurov.ro@gmail.com
        ICQ: 450327002
*/
prontera,150,180,5  script  Happy Hour EXP  100,{
mes "[Happy Hour EXP]";
if(getgmlevel()>=.Access){
mes "Hello! What would you like to do?";
    switch(select("Start the Floating Rates:Nothing")){
        case 1:
            mes " ";
            if(.Event == 1) { mes "Event already started"; close; }
            mes "Cerrent Base Rate: "+getbattleflag("base_exp_rate")/100;
            mes "Input new base rate";
            input .@BaseExp;
            next;
            mes "[Happy Hour EXP]";
            mes "Cerrent Job Rate: "+getbattleflag("job_exp_rate")/100;
            mes "Input new job rate";
            input .@JobExp;
            next;
            mes "[Happy Hour EXP]";
            mes "New rates:";
            mes "Base: "+.@BaseExp;
            mes "Job: "+.@JobExp;
            switch(select("Start:Close")){
                case 1:
                    setbattleflag "base_exp_rate",.@BaseExp*100;
                    setbattleflag "job_exp_rate",.@JobExp*100;
                    initnpctimer;
                    set .Event,1;
                    mes "Event started";
                    announce "Happy Hour EXP: Floating rates event started. New rates: Base - "+.@BaseExp+"x, Job - "+.@JobExp+"x",0;
                    close;
                break;

                default:
                    close;
            }
        break;

        default:
            close;
    }
} else {
    mes "You aren't a GM.";
    close;
}
end;

OnTimer3600000: // After 1 hour
set .Event,0;
setbattleflag "base_exp_rate",.DefaultBaseRates*100;
setbattleflag "job_exp_rate",.DefaultJobRates*100;
announce "Happy Hour EXP: The floating rates event have been ended. Rates back to the normal.",0;
end;

OnInit:
set .DefaultBaseRates,50; // Default Base Rate ( Like 50x )
set .DefaultJobRates,50; // Default Job Rate ( Like 50x )
set .Access,80;
end;
}