Tuning System v1.0 by Captive

/*
________________________________________________________________________________

                             Tuning System 1.0
                                by Captive

                               * Crediti:

                      - Drake1994 per dFile
                      - Zeex per ZCMD
--------------------------------------------------------------------------------
Si prega agli utilizzatori di questo FS di inserire gli appositi crediti,
grazie.

ATTENZIONE: è altamente importate avere dfile.inc e zcmd nella cartella
pawno ---> include e avere FileManager nella cartella plugins e sulla voce
plugins nel server.cfg .

Descizione:
Questo Filterscript salva automaticamente all'uscita del Mod Shop tutti le
modifiche apportate sul veicolo, compreso colore e verniciatura; e le cariche
allo spawn/respawn.
Non c'è alcun bisogno creare cartelle in scriptfiles, grazie alle funzioni dfile
se inesistente la cartella (Tuning) verrà creata automaticamente.

Comandi:
/resetveicolo: Resetta ogni componente del veicolo escluso il colore e la
verniciatura, e quindi cancella anche il file ormai inutile.
N.B. Il colore e la verniciatura non verranno resettati ma al respawn, il
veicolo spawnerà con il colore originale del codice della GM.
________________________________________________________________________________
*/

#include <a_samp>
#define USE_PLUGIN_FUNCTIONS
#include <dfile>
#include <zcmd>

#define MAX_VEHICLE_COMPONENTS 14

public OnFilterScriptInit()
{
    print("TuningSystem by Captive Loaded");
    if(!dfile_DirectoryExists("/Tuning/"))dfile_CreateDirectory("/Tuning/");
    return 1;
}

public OnFilterScriptExit()
{
    return 1;
}

public OnEnterExitModShop(playerid, enterexit, interiorid)
{
    if(enterexit == 1)
    {
        if(GetPlayerState(playerid) != PLAYER_STATE_DRIVER)return 0;
        new vehicleid = GetPlayerVehicleID(vehicleid);
        if(!dfile_FileExists(TuningFile(vehicleid)))dfile_Create(TuningFile(vehicleid));
        new str[32];
        dfile_Open(TuningFile(vehicleid));
        for(new i; i < MAX_VEHICLE_COMPONENTS; i++)
        {
            format(str, sizeof(str), "Componente_%d", i);
            dfile_WriteInt(str, GetVehicleComponentInSlot(vehicleid, i));
        }
        dfile_SaveFile();
        dfile_CloseFile();
    }
    return 1;
}

public OnVehicleRespray(playerid, vehicleid, color1, color2)
{
    if(!dfile_FileExists(TuningFile(vehicleid)))dfile_Create(TuningFile(vehicleid));
    dfile_Open(TuningFile(vehicleid));
    dfile_WriteInt("Colore_1", color1);
    dfile_WriteInt("Colore_2", color2);
    dfile_SaveFile();
    dfile_CloseFile();
    return 1;
}

public OnVehiclePaintjob(playerid, vehicleid, paintjobid)
{
    if(!dfile_FileExists(TuningFile(vehicleid)))dfile_Create(TuningFile(vehicleid));
    dfile_Open(TuningFile(vehicleid));
    dfile_WriteInt("Verniciatura", paintjobid);
    dfile_SaveFile();
    dfile_CloseFile();
    return 1;
}

public OnVehicleSpawn(vehicleid)
{
    if(!dfile_FileExists(TuningFile(vehicleid)))return 1;
    new str[32];
    dfile_Open(TuningFile(vehicleid));
    for(new i; i < MAX_VEHICLE_COMPONENTS; i++)
    {
        format(str, sizeof(str), "Componente_%d", i);
        AddVehicleComponent(vehicleid, dfile_ReadInt(str));
    }
    ChangeVehicleColor(vehicleid, dfile_ReadInt("Colore_1"), dfile_ReadInt("Colore_2"));
    ChangeVehiclePaintjob(vehicleid, dfile_ReadInt("Verniciatura"));
    dfile_CloseFile();
    return 1;
}

CMD:resetveicolo(playerid, params[])
{
    if(GetPlayerState(playerid) != PLAYER_STATE_DRIVER)return SendClientMessage(playerid, -1, "Errore: non stai guidando un veicolo");
    new vehicleid = GetPlayerVehicleID(playerid);
    for(new i; i < MAX_VEHICLE_COMPONENTS; i++)RemoveVehicleComponent(vehicleid, GetVehicleComponentInSlot(vehicleid, i));
    if(dfile_FileExists(TuningFile(vehicleid)))dfile_Delete(TuningFile(vehicleid));
    return 1;
}

stock TuningFile(vehicleid)
{
    new sfile[64];
    format(sfile, sizeof(sfile), "/Tuning/Veicolo_%d.ini", vehicleid);
    return sfile;
}