T3MA Ribbon

//@version=2

study(title="T3MA Ribbon by JustUncleL", shorttitle="T3RIBBON", overlay = true)

//
////////////////////////////////////////////////////////////
//  Copyright by HPotter v1.0 21/05/2014
// This indicator plots the moving average described in the January, 1998 issue
// of S&C, p.57, "Smoothing Techniques for More Accurate Signals", by Tim Tillson.
// This indicator plots T3 moving average presented in Figure 4 in the article.
// T3 indicator is a moving average which is calculated according to formula:
//     T3(n) = GD(GD(GD(n))),
// where GD - generalized DEMA (Double EMA) and calculating according to this:
//     GD(n,v) = EMA(n) * (1+v)-EMA(EMA(n)) * v,
// where "v" is volume factor, which determines how hot the moving average’s response
// to linear trends will be. The author advises to use v=0.7.
// When v = 0, GD = EMA, and when v = 1, GD = DEMA. In between, GD is a less aggressive
// version of DEMA. By using a value for v less than1, trader cure the multiple DEMA
// overshoot problem but at the cost of accepting some additional phase delay.
// In filter theory terminology, T3 is a six-pole nonlinear Kalman filter. Kalman
// filters are ones that use the error — in this case, (time series - EMA(n)) —
// to correct themselves. In the realm of technical analysis, these are called adaptive
// moving averages; they track the time series more aggres-sively when it is making large
// moves. Tim Tillson is a software project manager at Hewlett-Packard, with degrees in
// mathematics and computer science. He has privately traded options and equities for 15 years.
//
// Reference:
// - T3 Average by HPotter
//
////////////////////////////////////////////////////////////

Length1 = input(5, minval=1)
VolFactor1 = input(1.0,minval=0.0,maxval=1.0)
Length2_ = input(21, minval=13)
VolFactor2 = input(0.4,minval=0.0,maxval=1.0)
Length2  = (Length2_-Length1)<8?Length1+2:Length2_
//
T3MA(src, Length, VolFactor) =>
    xe1 = ema(src, Length)
    xe2 = ema(xe1, Length)
    xe3 = ema(xe2, Length)
    xe4 = ema(xe3, Length)
    xe5 = ema(xe4, Length)
    xe6 = ema(xe5, Length)
    b = VolFactor
    c1 = -b*b*b
    c2 = 3*b*b+3*b*b*b
    c3 = -6*b*b-3*b-3*b*b*b
    c4 = 1+3*b+b*b*b+3*b*b
    c1 * xe6 + c2 * xe5 + c3 * xe4 + c4 * xe3


t3ma1 = T3MA(close, Length1, VolFactor1)
t3ma2 = T3MA(close, Length2, VolFactor2)

ma1=plot( t3ma1,color=green,linewidth=2,transp=20,title="t3ma1")
ma2=plot( t3ma2,color=rising(t3ma2,2)?green:red,linewidth=2,transp=20,title="t3ma2")
fcolor = t3ma1>t3ma2?green:red
fill(ma1,ma2,color=fcolor,transp=80)
//eof