PKGBUILD

_pkgname=cogl
pkgname=$_pkgname-amdgpu-pro
pkgver=1.22.2
pkgrel=1
pkgdesc="cogl with support for amdgpu-pro"
arch=('i686' 'x86_64')
url="http://www.clutter-project.org/"
license=('GPL2')
depends=('mesa' 'libdrm' 'libxext' 'libxdamage' 'libxcomposite' 'gdk-pixbuf2'
'pango' 'libxrandr')
makedepends=('gobject-introspection' 'git' 'gtk-doc')
optdepends=('amdgpu-pro: hybrid driver for AMDGPU cards')
options=(!emptydirs)
provides=("${_pkgname}")
conflicts=("${_pkgname}")
replaces=("${_pkgname}")
source=("https://git.gnome.org/browse/cogl/snapshot/$_pkgname-$pkgver.tar.xz"
        '~/cogl/cogl-patch.patch')
sha256sums=('SKIP'
            'ce339c5075ffa759cd6fa0a6914665ac6cbaef12ce4fa582b6deed6aa34801c6')

prepare() {
  cd "$_pkgname-$pkgver"

  # Apply shader fix (thanks @ashleysommer)
  patch -p1 -i "${srcdir}/cogl-patch.patch"

  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd "$_pkgname-$pkgver"
  ./configure --prefix=/usr \
    --enable-gles{1,2} \
    --enable-{kms,wayland}-egl-platform \
    --enable-wayland-egl-server

  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

package() {
  cd "$_pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: