apply plugin: 'java'
apply plugin: 'eclipse'
apply plugin: 'maven'
apply plugin: 'jacoco'

// Jenkins can override these values
sourceCompatibility = 1.7
version = '0.1.0'
projectName = 'jutils'

group = 'eu.matthiasbraun'

jar {
    manifest {
        attributes 'Implementation-Title': projectName, 'Implementation-Version': version
    }
}
tasks.withType(Compile) {
    options.encoding = "UTF-8"
}

// Update site for the Eclipse plugin: http://dist.springsource.com/release/TOOLS/gradle
eclipse.project {
    // Make sure the project can be run as a Gradle build in Eclipse
    natures 'org.springsource.ide.eclipse.gradle.core.nature'
}
repositories {
    mavenCentral()
}

dependencies {
    compile 'org.slf4j:slf4j-api:1.7.5'
    compile 'org.slf4j:slf4j-jdk14:1.7.5'
    compile 'com.google.guava:guava:16.0'
    compile 'com.google.code.gson:gson:2.2.4'
    compile 'joda-time:joda-time:2.3'
    compile 'net.sourceforge.cssparser:cssparser:0.9.11'
    compile 'org.eclipse.swt.win32.win32:x86:3.3.0-v3346'

    // Some Jars are not in maven central -> use the Jars in this local folder as well
    compile fileTree('libs')

    // These Jars are needed for testing; the Jars from 'compile' are available for testing as well
    testCompile group: 'junit', name: 'junit', version: '4.+'
}

task wrapper(type: Wrapper) {
    gradleVersion = '1.10'
}

jacocoTestReport {
    description = 'Get the unit test code coverage.'

    reports {
        html.destination "${buildDir}/reports/jacoco"
    }
}

test {
    // Call 'gradle test jacocoTestReport' to get the code coverage
    jacoco {
        destinationFile = file("$buildDir/test-results/jacocoTest.exec")
    }
}