COMMAND:passgun(playerid, params[])
{
	new recipient;
	if(sscanf(params, "u", recipient))
		SendClientMessage(playerid, 0xFF0000FF, "Usage: /passgun <name/id>");
	else if(recipient == INVALID_PLAYER_ID)
		SendClientMessage(playerid, 0xFF0000FF, "Invalid player name/ID");
	else
	{
		new Float:playerx, Float:playery, Float:playerz;
		GetPlayerPos(playerid, playerx, playery, playerz);
		if(GetPlayerDistanceFromPoint(recipient, playerx, playery, playerz) < 10)
		{
			new gift = GetPlayerWeapon(playerid), giftammo, giftname[12];
			GetWeaponName(gift, giftname, sizeof(giftname));
			if(gift != 0)
			{
				new rweapon, rweaponammo;
				for(new i = 0; i < 13; i++)
				{
					GetPlayerWeaponData(recipient, i, rweapon, rweaponammo);
					if(rweapon == GetPlayerWeapon(playerid))
						return SendClientMessage(playerid, 0xFF0000FF, "That player already has your current weapon!");
				}
				new pweapons[13][2];
				for(new i = 0; i < 13; i++)
				{
					GetPlayerWeaponData(playerid, i, pweapons[i][0], pweapons[i][1]);
					if(pweapons[i][0] == gift)
						giftammo = pweapons[i][1];
				}
				GivePlayerWeapon(recipient, gift, giftammo);
				ResetPlayerWeapons(playerid);
				SetPlayerArmedWeapon(recipient, gift);
				for(new i = 0; i < 13; i++)
				{
					if(pweapons[i][0] != gift)
						GivePlayerWeapon(playerid, pweapons[i][0], pweapons[i][1]);
				}
				new msg[128], rname[24];
				GetPlayerName(recipient, rname, sizeof(rname));
				format(msg, sizeof(msg), "You have given your %s to %s(%d) with %d ammo", giftname, rname, recipient, giftammo);
				SendClientMessage(playerid, 0x0099FFFF, msg);
				GetPlayerName(playerid, rname, sizeof(rname));
				format(msg, sizeof(msg), "You have received a %s with %d ammo from %s(%d)", giftname, giftammo, rname, playerid);
				SendClientMessage(recipient, 0x0099FFFF, msg);
			}
			else
				SendClientMessage(playerid, 0xFF0000FF, "You cannot gift your hands to another player!");
		}
		else
			SendClientMessage(playerid, 0xFF0000FF, "You must be closer to that player to give them your weapon!");
	}
	return 1;
}