FX Sniper: T3-CCI R2

//@version=3
//
study(title="FX Sniper:  T3-CCI Strategy revision2 by JustUncleL", shorttitle="T3-CCI")
//
////////////////////////////////////////////////////////////
//  Copyright by HPotter v1.0 10/04/2017
// This simple indicator gives you a lot of useful information - when to enter, when to exit
// and how to reduce risks by entering a trade on a double confirmed signal.
// You can use in the xPrice any series: Open, High, Low, Close, HL2, HLC3, OHLC4 and ect...
//
// Added Alerts when signal changes.
// Changed alerts to occur after candle completes: JustUncleL
// Added Option to Wait for Candle Complete or Not.
// Added Spike Alerts.
////////////////////////////////////////////////////////////
//

CCI_Period = input(14, minval=1)
T3_Period = input(5, minval=1)
b = input(0.618)
ofs = input(1,title="Delay Alert Offset (1=wait for candle close, 0=no wait)",minval=0,maxval=1)

// Constants colours that include fully non-transparent option.
green100 = #008000FF
lime100  = #00FF00FF
red100   = #FF0000FF
blue100  = #0000FFFF
aqua100  = #00FFFFFF
darkred100 = #8B0000FF
gray100 = #808080FF

hline(0, color=purple, linestyle=line)
xPrice = close
b2 = b*b
b3 = b2*b
c1 = -b3
c2 = (3*(b2 + b3))
c3 = -3*(2*b2 + b + b3)
c4 = (1 + 3*b + b3 + 3*b2)
nn = iff(T3_Period < 1, 1, T3_Period)
nr = 1 + 0.5*(nn - 1)
w1 = 2 / (nr + 1)
w2 = 1 - w1
xcci = cci(xPrice, CCI_Period)
//Initialise look forward variables (version3 Pinescript)
e1 = 0.0
e2 = 0.0
e3 = 0.0
e4 = 0.0
e5 = 0.0
e6 = 0.0
pos = 0
//
e1 := w1*xcci + w2*nz(e1[1])
e2 := w1*e1 + w2*nz(e2[1])
e3 := w1*e2 + w2*nz(e3[1])
e4 := w1*e3 + w2*nz(e4[1])
e5 := w1*e4 + w2*nz(e5[1])
e6 := w1*e5 + w2*nz(e6[1])
xccir = c1*e6 + c2*e5 + c3*e4 + c4*e3
cciHcolor = iff(xccir >= 0 , green, iff(xccir < 0, red, black))
pos := iff(xccir > 0, 1, iff(xccir < 0, -1, nz(pos[1], 0)))
barcolor(pos == -1 ? red100: pos == 1 ? green100 : blue100 )
buy = pos != pos[1] and pos == 1
sell= pos != pos[1] and pos == -1
//alertcondition(buy[ofs] and barstate.isnew, title='Signal Buy', message="Buy")
//alertcondition(sell[ofs] and barstate.isnew, title='Signal Sell', message="Sell")
plot(buy[ofs]?200:0,color=green,title="Spike Long")
plot(sell[ofs]?-200:0,color=red,title="Spike Short")
//barcolor(pos == -1 ? red: pos == 1 ? green : blue ) // repeated
plot(xccir, color=blue, title="T3-CCI")
plot(xccir, color=cciHcolor, title="CCIH", style = histogram)
//