-	script	Healer	-1,{

	getinventorylist;
	for(set .@i,0; .@i < @inventorylist_count; set .@i, .@i +1) {
		if ( @inventorylist_identify[.@i] == 1 ) continue;
		delitem2 @inventorylist_id[.@i],1,0,0,0,0,0,0,0;
		getitem @inventorylist_id[.@i],1;
	}

	while (getbrokenid(1)) {
		repair(1);
		set .@r, .@r +1;
	}
	if (.@r) dispbottom .@r + " items repaired.";

	if((#VIPTIME >= gettimetick(2)) || (BaseLevel < 100)) {
		if (BaseLevel < 100) {
			sc_start SC_SAVAGE_STEAK,         300000, 20;
			sc_start SC_COCKTAIL_WARG_BLOOD,  300000, 20;
			sc_start SC_MINOR_BBQ,            300000, 20;
			sc_start SC_SIROMA_ICE_TEA,       300000, 20;
			sc_start SC_DROCERA_HERB_STEAMED, 300000, 20;
			sc_start SC_PUTTI_TAILS_NOODLES,  300000, 20;
		}
		setarray .@dishlv[1], 10, 13, 15, 18, 20;
		setarray .@dishtime[1], 1200, 1800, 2400, 3000, 3600;
		if (#VIPTIME >= gettimetick(2)) {
			sc_start SC_FOOD_STR_CASH, .@dishtime[#VIPLevel] *1000, .@dishlv[#VIPLevel];
			sc_start SC_FOOD_AGI_CASH, .@dishtime[#VIPLevel] *1000, .@dishlv[#VIPLevel];
			sc_start SC_FOOD_INT_CASH, .@dishtime[#VIPLevel] *1000, .@dishlv[#VIPLevel];
			sc_start SC_FOOD_DEX_CASH, .@dishtime[#VIPLevel] *1000, .@dishlv[#VIPLevel];
			sc_start SC_FOOD_LUK_CASH, .@dishtime[#VIPLevel] *1000, .@dishlv[#VIPLevel];
			sc_start SC_FOOD_VIT_CASH, .@dishtime[#VIPLevel] *1000, .@dishlv[#VIPLevel];
			sc_start SC_CP_WEAPON,     600 *1000, 5;
			sc_start SC_CP_SHIELD,     600 *1000, 5;
			sc_start SC_CP_ARMOR,      600 *1000, 5;
			sc_start SC_CP_HELM,       600 *1000, 5;
		}
		switch ( basejob ) {
			case Job_Alchemist:				set .@spirit, 445; break;
			case Job_Monk:					set .@spirit, 447; break;
			case Job_Star_Gladiator:		set .@spirit, 448; break;
			case Job_Sage:					set .@spirit, 449; break;
			case Job_Crusader:				set .@spirit, 450; break;
			case Job_SuperNovice:			set .@spirit, 451; break;
			case Job_Knight:				set .@spirit, 452; break;
			case Job_Wizard:				set .@spirit, 453; break;
			case Job_Priest:				set .@spirit, 454; break;
			case Job_Bard: case Job_Dancer:	set .@spirit, 455; break;
			case Job_Rogue:					set .@spirit, 456; break;
			case Job_Assassin:				set .@spirit, 457; break;
			case Job_Blacksmith:			set .@spirit, 458; break;
			case Job_Hunter:				set .@spirit, 460; break;
			case Job_Soul_Linker:			set .@spirit, 461; break;
			default: 						if ( baselevel < 70 ) set .@spirit, 494;
		}
		set .@time, 350*1000;
		if ( .@spirit ) {
			sc_start4 sc_spirit, .@time, 5, .@spirit,0,0;
			skilleffect .@spirit, 5;
		}
		setarray .@sklv[1],1,2,2,3,3;
		skilleffect 465,0; sc_start SC_KAITE,            360000, 7;
		skilleffect 464,0; sc_start SC_KAUPE,            360000, .@sklv[#VIPLevel];
		skilleffect 463,0; sc_start SC_KAAHI,            360000, 7;
		skilleffect 361,0; sc_start SC_ASSUMPTIO,        600000, 5;
		skilleffect 113,0; sc_start SC_OVERTHRUST,       360000, 5;
		skilleffect 112,0; sc_start SC_WEAPONPERFECTION, 360000, 5;
	}
	skilleffect 383,0; sc_start SC_WINDWALK,600000,5;
	skilleffect 74,0; sc_start SC_MAGNIFICAT,600000,5;
	skilleffect 75,0; sc_start SC_GLORIA,600000,5;
	skilleffect 66,0; sc_start SC_IMPOSITIO,600000,5;
	skilleffect 67,0; sc_start SC_SUFFRAGIUM,600000,3;
	skilleffect 34,0; sc_start SC_BLESSING,600000,10;
	skilleffect 29,0; sc_start SC_INCREASEAGI,600000,10;
	percentheal 100,100;
	end;

}

gonryun,156,121,5	duplicate(Healer)	Healer#01	936