-	script	recolor_headgear	-1,{
	function recolor_list;

	OnInit:
		bindatcmd "hgcolor",strnpcinfo(3)+"::OnRecolor";

		setarray .loc,
			EQI_HEAD_TOP,
			EQI_HEAD_MID,
			EQI_HEAD_LOW;
		.loc_size = getarraysize( .loc );

		// Recolor( <original>,<color1>,...,<colorX> );
		recolor_list( 5172,30057,30074,30134 );
		end;


	function	recolor_list	{
		.@arg_count = getargcount();

		if ( .@arg_count >= 2 ) {
			for ( .@i = 0; .@i < .@arg_count; .@i++ )
				.@array[.@i] = getarg( .@i );

			copyarray getd( ".recolor_"+.@array[0] ),.@array,.@arg_count;
		}
		return;
	}

	OnRecolor:
		for ( .@i = 0; .@i < .loc_size; .@i++ ) {
			.@item_id = getequipid( .loc[.@i] );
			if ( .@item_id != - 1 ) {
				.@array_size = getarraysize( getd( ".recolor_"+.@item_id ) );
				.@menu$ = .@menu$ + ( ( .@array_size )? "^00FF00":"^FF0000" );
				.@menu$ = .@menu$ + getitemname( .@item_id );
				.@count++;
			}
			.@menu$ = .@menu$ + ":";
		}
		if ( !.@count ) {
			mes "You doesnt wear any Recolor-able Headgear.";
		}
		else {
			.@loc = select ( .@menu$ ) - 1;
			.@item_id = getequipid( .loc[.@loc] );
			.@array_size = getarraysize( getd( ".recolor_"+.@item_id ) );
			if ( !.@array_size ) {
				mes "This headgear doesnt have Recolor option.";
			}
			else {
				copyarray .@array,getd( ".recolor_"+.@item_id ),.@array_size;
				for ( .@i = 0; .@i < .@array_size; .@i++ ) {
					if ( .@item_id != .@array[.@i] ) {
						.@color_menu$ = .@color_menu$ + getitemname( .@array[.@i] );
					}
					.@color_menu$ = .@color_menu$ + ":";
				}
				.@color = select( .@color_menu$ ) - 1;
				.@refine = getequiprefinerycnt( .loc[.@loc] );
				for ( .@i = 0; .@i < 4; .@i++ )
					.@card[.@i] = getequipcardid( .loc[.@loc],.@i );
				delequip .loc[.@loc];
				getitem2 .@array[.@color],1,1,.@refine,0,.@card[0],.@card[1],.@card[2],.@card[3];
				equip .@array[.@color];
			}
		}
		close;
}